nptl/sysdeps/unix/sysv/linux/i386/pt-vfork.S

   1 /* Copyright (C) 1999, 2002, 2004 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Contributed by Andreas Schwab <schwab@gnu.org>.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 #include <sysdep.h>
  21 #define _ERRNO_H        1
  22 #include <bits/errno.h>
  23 #include <kernel-features.h>
  24 #include <tcb-offsets.h>
  25
  26 /* Save the PID value.  */
  27 #define SAVE_PID \
  28         movl    %gs:PID, %edx;                                                \
  29         movl    %edx, %eax;                                                   \
  30         negl    %eax;                                                         \
  31         movl    %eax, %gs:PID
  32
  33 /* Restore the old PID value in the parent.  */
  34 #define RESTORE_PID \
  35         testl   %eax, %eax;                                                   \
  36         je      1f;                                                           \
  37         movl    %edx, %gs:PID;                                                \
  38 1:
  39
  40 /* Clone the calling process, but without copying the whole address space.
  41    The calling process is suspended until the new process exits or is
  42    replaced by a call to `execve'.  Return -1 for errors, 0 to the new process,
  43    and the process ID of the new process to the old process.  */
  44
  45 ENTRY (__vfork)
  46         /* Pop the return PC value into ECX.  */
  47         popl    %ecx
  48
  49         SAVE_PID
  50
  51         /* Stuff the syscall number in EAX and enter into the kernel.  */
  52         movl    $SYS_ify (vfork), %eax
  53         int     $0x80
  54
  55         RESTORE_PID
  56
  57         /* Jump to the return PC.  Don't jump directly since this
  58            disturbs the branch target cache.  Instead push the return
  59            address back on the stack.  */
  60         pushl   %ecx
  61
  62         cmpl    $-4095, %eax
  63         jae     SYSCALL_ERROR_LABEL     /* Branch forward if it failed.  */
  64 .Lpseudo_end:
  65         ret
  66 PSEUDO_END (__vfork)
  67
  68 weak_alias (__vfork, vfork)