sysdeps/powerpc/powerpc64/power7/rawmemchr.S

   1 /* Optimized rawmemchr implementation for PowerPC64/POWER7 using cmpb insn.
   2    Copyright (C) 2010 Free Software Foundation, Inc.
   3    Contributed by Luis Machado <luisgpm@br.ibm.com>.
   4    This file is part of the GNU C Library.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, write to the Free
  18    Software Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston MA
  19    02110-1301 USA.  */
  20
  21 #include <sysdep.h>
  22 #include <bp-sym.h>
  23 #include <bp-asm.h>
  24
  25 /* int [r3] rawmemchr (void *s [r3], int c [r4])  */
  26         .machine  power7
  27 ENTRY (BP_SYM(__rawmemchr))
  28         CALL_MCOUNT 2
  29         dcbt    0,r3
  30         clrrdi  r8,r3,3       /* Align the address to doubleword boundary.  */
  31
  32         /* Replicate byte to doubleword.  */
  33         rlwimi  r4,r4,8,16,23
  34         rlwimi  r4,r4,16,0,15
  35         insrdi  r4,r4,32,0
  36
  37         /* Now r4 has a doubleword of c bytes.  */
  38
  39         rlwinm  r6,r3,3,26,28 /* Calculate padding.  */
  40         ld      r12,0(r8)     /* Load doubleword from memory.  */
  41         cmpb    r5,r12,r4     /* Compare each byte against c byte.  */
  42         sld     r5,r5,r6      /* Move left to discard ignored bits.  */
  43         srd     r5,r5,r6      /* Bring the bits back as zeros.  */
  44         cmpdi   cr7,r5,0      /* If r5 == 0, no c bytes have been found.  */
  45         bne     cr7,L(done)
  46
  47         mtcrf   0x01,r8
  48
  49         /* Are we now aligned to a quadword boundary?  If so, skip to
  50            the main loop.  Otherwise, go through the alignment code.  */
  51
  52         bt      28,L(loop)
  53
  54         /* Handle DWORD2 of pair.  */
  55         ldu     r12,8(r8)
  56         cmpb    r5,r12,r4
  57         cmpdi   cr7,r5,0
  58         bne     cr7,L(done)
  59         b       L(loop)       /* We branch here (rather than falling through)
  60                                  to skip the nops due to heavy alignment
  61                                  of the loop below.  */
  62
  63         /* Main loop to look for the end of the string.  Since it's a
  64            small loop (< 8 instructions), align it to 32-bytes.  */
  65         .p2align  5
  66 L(loop):
  67         /* Load two doublewords, compare and merge in a
  68            single register for speed.  This is an attempt
  69            to speed up the byte-checking process for bigger strings.  */
  70         ld      r12,8(r8)
  71         ldu     r11,16(r8)
  72         cmpb    r5,r12,r4
  73         cmpb    r6,r11,r4
  74         or      r7,r5,r6
  75         cmpdi   cr7,r7,0
  76         beq     cr7,L(loop)
  77
  78         /* OK, one (or both) of the doublewords contains a 'c' byte.  Check
  79            the first doubleword and decrement the address in case the first
  80            doubleword really contains a c byte.  */
  81
  82         cmpdi   cr6,r5,0
  83         addi    r8,r8,-8
  84         bne     cr6,L(done)
  85
  86         /* The 'c' byte must be in the second doubleword.  Adjust the address
  87            again and move the result of cmpb to r10 so we can calculate the
  88            pointer.  */
  89         mr      r5,r6
  90         addi    r8,r8,8
  91
  92         /* r5 has the output of the cmpb instruction, that is, it contains
  93            0xff in the same position as the 'c' byte in the original
  94            doubleword from the string.  Use that fact to find out what is
  95            the position of the byte inside the string.  */
  96 L(done):
  97         cntlzd  r0,r5         /* Count leading zeros before the match.  */
  98         srdi    r0,r0,3       /* Convert leading zeroes to bytes.  */
  99         add     r3,r8,r0      /* Return address of the matching char.  */
 100         blr
 101 END (BP_SYM (__rawmemchr))
 102 weak_alias (__rawmemchr,rawmemchr)
 103 libc_hidden_builtin_def (__rawmemchr)