configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Note we do not use AC_PREREQ here!  See aclocal.m4 for what we use instead.
   3 AC_INIT([GNU C Library], [(see version.h)], [http://sourceware.org/bugzilla/], [glibc])
   4 AC_CONFIG_SRCDIR([include/features.h])
   5 AC_CONFIG_HEADERS([config.h])
   6 AC_CONFIG_AUX_DIR([scripts])
   7
   8 ACX_PKGVERSION([GNU libc])
   9 ACX_BUGURL([http://www.gnu.org/software/libc/bugs.html])
  10 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"],
  11                    [Package description])
  12 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"],
  13                    [Bug reporting address])
  14
  15 # Glibc should not depend on any header files
  16 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
  17   [m4_divert_text([DEFAULTS],
  18     [ac_includes_default='/* none */'])])
  19
  20 # We require GCC, and by default use its preprocessor.  Override AC_PROG_CPP
  21 # here to work around the Autoconf issue discussed in
  22 # <http://sourceware.org/ml/libc-alpha/2013-01/msg00721.html>.
  23 AC_DEFUN([AC_PROG_CPP],
  24 [AC_REQUIRE([AC_PROG_CC])dnl
  25 AC_ARG_VAR([CPP],      [C preprocessor])dnl
  26 _AC_ARG_VAR_CPPFLAGS()dnl
  27 # On Suns, sometimes $CPP names a directory.
  28 if test -n "$CPP" && test -d "$CPP"; then
  29   CPP=
  30 fi
  31 if test -z "$CPP"; then
  32   CPP="$CC -E"
  33 fi
  34 AC_SUBST(CPP)dnl
  35 ])# AC_PROG_CPP
  36
  37 # We require GCC.  Override _AC_PROG_CC_C89 here to work around the Autoconf
  38 # issue discussed in
  39 # <http://sourceware.org/ml/libc-alpha/2013-01/msg00757.html>.
  40 AC_DEFUN([_AC_PROG_CC_C89], [[$1]])
  41
  42 dnl This is here so we can set $subdirs directly based on configure fragments.
  43 AC_CONFIG_SUBDIRS()
  44
  45 AC_CANONICAL_HOST
  46
  47 AC_PROG_CC
  48 if test $host != $build; then
  49   AC_CHECK_PROGS(BUILD_CC, gcc cc)
  50 fi
  51 AC_SUBST(cross_compiling)
  52 AC_PROG_CPP
  53 AC_CHECK_TOOL(READELF, readelf, false)
  54
  55 # We need the C++ compiler only for testing.
  56 AC_PROG_CXX
  57 # It's useless to us if it can't link programs (e.g. missing -lstdc++).
  58 AC_CACHE_CHECK([whether $CXX can link programs], libc_cv_cxx_link_ok, [dnl
  59 AC_LANG_PUSH([C++])
  60 # Default, dynamic case.
  61 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
  62                [libc_cv_cxx_link_ok=yes],
  63                [libc_cv_cxx_link_ok=no])
  64 # Static case.
  65 old_LDFLAGS="$LDFLAGS"
  66 LDFLAGS="$LDFLAGS -static"
  67 AC_LINK_IFELSE([AC_LANG_SOURCE([
  68 #include <iostream>
  69
  70 int
  71 main()
  72 {
  73   std::cout << "Hello, world!";
  74   return 0;
  75 }
  76 ])],
  77                [],
  78                [libc_cv_cxx_link_ok=no])
  79 LDFLAGS="$old_LDFLAGS"
  80 AC_LANG_POP([C++])])
  81 AS_IF([test $libc_cv_cxx_link_ok != yes], [CXX=])
  82
  83 if test "`cd $srcdir; /bin/pwd`" = "`/bin/pwd`"; then
  84   AC_MSG_ERROR([you must configure in a separate build directory])
  85 fi
  86
  87 # This will get text that should go into config.make.
  88 config_vars=
  89
  90 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
  91 AC_ARG_WITH([gd],
  92             AC_HELP_STRING([--with-gd=DIR],
  93                            [find libgd include dir and library with prefix DIR]),
  94             [dnl
  95 case "$with_gd" in
  96 yes|''|no) ;;
  97 *) libgd_include="-I$withval/include"
  98    libgd_ldflags="-L$withval/lib" ;;
  99 esac
 100 ])
 101 AC_ARG_WITH([gd-include],
 102             AC_HELP_STRING([--with-gd-include=DIR],
 103                            [find libgd include files in DIR]),
 104             [dnl
 105 case "$with_gd_include" in
 106 ''|no) ;;
 107 *) libgd_include="-I$withval" ;;
 108 esac
 109 ])
 110 AC_ARG_WITH([gd-lib],
 111             AC_HELP_STRING([--with-gd-lib=DIR],
 112                            [find libgd library files in DIR]),
 113             [dnl
 114 case "$with_gd_lib" in
 115 ''|no) ;;
 116 *) libgd_ldflags="-L$withval" ;;
 117 esac
 118 ])
 119
 120 if test -n "$libgd_include"; then
 121   config_vars="$config_vars
 122 CFLAGS-memusagestat.c = $libgd_include"
 123 fi
 124 if test -n "$libgd_ldflags"; then
 125   config_vars="$config_vars
 126 libgd-LDFLAGS = $libgd_ldflags"
 127 fi
 128
 129 dnl Arguments to specify presence of other packages/features.
 130 AC_ARG_WITH([fp],
 131             AC_HELP_STRING([--with-fp],
 132                            [if using floating-point hardware @<:@default=yes@:>@]),
 133             [with_fp=$withval],
 134             [with_fp=yes])
 135 AC_SUBST(with_fp)
 136 AC_ARG_WITH([binutils],
 137             AC_HELP_STRING([--with-binutils=PATH],
 138                            [specify location of binutils (as and ld)]),
 139             [path_binutils=$withval],
 140             [path_binutils=''])
 141 AC_ARG_WITH([selinux],
 142             AC_HELP_STRING([--with-selinux],
 143                            [if building with SELinux support]),
 144             [with_selinux=$withval],
 145             [with_selinux=auto])
 146
 147 AC_ARG_WITH([headers],
 148             AC_HELP_STRING([--with-headers=PATH],
 149                            [location of system headers to use
 150                             (for example /usr/src/linux/include)
 151                             @<:@default=compiler default@:>@]),
 152             [sysheaders=$withval],
 153             [sysheaders=''])
 154 AC_SUBST(sysheaders)
 155
 156 AC_SUBST(use_default_link)
 157 AC_ARG_WITH([default-link],
 158             AC_HELP_STRING([--with-default-link],
 159                            [do not use explicit linker scripts]),
 160             [use_default_link=$withval],
 161             [use_default_link=default])
 162
 163 AC_ARG_ENABLE([sanity-checks],
 164               AC_HELP_STRING([--disable-sanity-checks],
 165                              [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
 166               [enable_sanity=$enableval],
 167               [enable_sanity=yes])
 168
 169 AC_ARG_ENABLE([shared],
 170               AC_HELP_STRING([--enable-shared],
 171                              [build shared library @<:@default=yes if GNU ld@:>@]),
 172               [shared=$enableval],
 173               [shared=yes])
 174 AC_ARG_ENABLE([profile],
 175               AC_HELP_STRING([--enable-profile],
 176                              [build profiled library @<:@default=no@:>@]),
 177               [profile=$enableval],
 178               [profile=no])
 179 AC_ARG_ENABLE([timezone-tools],
 180               AC_HELP_STRING([--disable-timezone-tools],
 181                              [do not install timezone tools @<:@default=install@:>@]),
 182               [enable_timezone_tools=$enableval],
 183               [enable_timezone_tools=yes])
 184 AC_SUBST(enable_timezone_tools)
 185
 186 AC_ARG_ENABLE([hardcoded-path-in-tests],
 187               AC_HELP_STRING([--enable-hardcoded-path-in-tests],
 188                              [hardcode newly built glibc path in tests @<:@default=no@:>@]),
 189               [hardcoded_path_in_tests=$enableval],
 190               [hardcoded_path_in_tests=no])
 191 AC_SUBST(hardcoded_path_in_tests)
 192
 193 AC_ARG_ENABLE([stackguard-randomization],
 194               AC_HELP_STRING([--enable-stackguard-randomization],
 195                              [initialize __stack_chk_guard canary with a random number at program start]),
 196               [enable_stackguard_randomize=$enableval],
 197               [enable_stackguard_randomize=no])
 198 if test "$enable_stackguard_randomize" = yes; then
 199   AC_DEFINE(ENABLE_STACKGUARD_RANDOMIZE)
 200 fi
 201
 202 AC_ARG_ENABLE([lock-elision],
 203               AC_HELP_STRING([--enable-lock-elision[=yes/no]],
 204                              [Enable lock elision for pthread mutexes by default]),
 205               [enable_lock_elision=$enableval],
 206               [enable_lock_elision=no])
 207 AC_SUBST(enable_lock_elision)
 208 if test "$enable_lock_elision" = yes ; then
 209   AC_DEFINE(ENABLE_LOCK_ELISION)
 210 fi
 211
 212 dnl Generic infrastructure for drop-in additions to libc.
 213 AC_ARG_ENABLE([add-ons],
 214               AC_HELP_STRING([--enable-add-ons@<:@=DIRS...@:>@],
 215                              [configure and build add-ons in DIR1,DIR2,...
 216                               search for add-ons if no parameter given]),
 217                              , [enable_add_ons=yes])
 218
 219 AC_ARG_ENABLE([hidden-plt],
 220               AC_HELP_STRING([--disable-hidden-plt],
 221                              [do not hide internal function calls to avoid PLT]),
 222               [hidden=$enableval],
 223               [hidden=yes])
 224 if test "x$hidden" = xno; then
 225   AC_DEFINE(NO_HIDDEN)
 226 fi
 227
 228 AC_ARG_ENABLE([bind-now],
 229               AC_HELP_STRING([--enable-bind-now],
 230                              [disable lazy relocations in DSOs]),
 231               [bindnow=$enableval],
 232               [bindnow=no])
 233 AC_SUBST(bindnow)
 234
 235 dnl On some platforms we cannot use dynamic loading.  We must provide
 236 dnl static NSS modules.
 237 AC_ARG_ENABLE([static-nss],
 238               AC_HELP_STRING([--enable-static-nss],
 239                              [build static NSS modules @<:@default=no@:>@]),
 240               [static_nss=$enableval],
 241               [static_nss=no])
 242 dnl Enable static NSS also if we build no shared objects.
 243 if test x"$static_nss" = xyes || test x"$shared" = xno; then
 244   static_nss=yes
 245   AC_DEFINE(DO_STATIC_NSS)
 246 fi
 247
 248 AC_ARG_ENABLE([force-install],
 249               AC_HELP_STRING([--disable-force-install],
 250                              [don't force installation of files from this package, even if they are older than the installed files]),
 251               [force_install=$enableval],
 252               [force_install=yes])
 253 AC_SUBST(force_install)
 254
 255 AC_ARG_ENABLE([maintainer-mode],
 256               AC_HELP_STRING([--enable-maintainer-mode],
 257                              [enable make rules and dependencies not useful (and sometimes confusing) to the casual installer]),
 258               [maintainer=$enableval],
 259               [maintainer=no])
 260
 261 dnl On some platforms we allow dropping compatibility with all kernel
 262 dnl versions.
 263 AC_ARG_ENABLE([kernel],
 264               AC_HELP_STRING([--enable-kernel=VERSION],
 265                              [compile for compatibility with kernel not older than VERSION]),
 266               [minimum_kernel=$enableval],
 267               [])
 268 dnl Prevent unreasonable values.
 269 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
 270   # Better nothing than this.
 271   minimum_kernel=""
 272 else
 273   if test "$minimum_kernel" = current; then
 274     minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
 275   fi
 276 fi
 277
 278 dnl For the development we sometimes want gcc to issue even more warnings.
 279 dnl This is not the default since many of the extra warnings are not
 280 dnl appropriate.
 281 AC_ARG_ENABLE([all-warnings],
 282               AC_HELP_STRING([--enable-all-warnings],
 283                              [enable all useful warnings gcc can issue]),
 284               [all_warnings=$enableval],
 285               [])
 286 AC_SUBST(all_warnings)
 287
 288 AC_ARG_ENABLE([werror],
 289               AC_HELP_STRING([--disable-werror],
 290                              [do not build with -Werror]),
 291               [enable_werror=$enableval],
 292               [enable_werror=yes])
 293 AC_SUBST(enable_werror)
 294
 295 AC_ARG_ENABLE([multi-arch],
 296               AC_HELP_STRING([--enable-multi-arch],
 297                              [enable single DSO with optimizations for multiple architectures]),
 298               [multi_arch=$enableval],
 299               [multi_arch=default])
 300
 301 AC_ARG_ENABLE([nss-crypt],
 302               AC_HELP_STRING([--enable-nss-crypt],
 303                              [enable libcrypt to use nss]),
 304               [nss_crypt=$enableval],
 305               [nss_crypt=no])
 306 if test x$nss_crypt = xyes; then
 307   nss_includes=-I$(nss-config --includedir 2>/dev/null)
 308   if test $? -ne 0; then
 309     AC_MSG_ERROR([cannot find include directory with nss-config])
 310   fi
 311   old_CFLAGS="$CFLAGS"
 312   CFLAGS="$CFLAGS $nss_includes"
 313   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 314 #include <hasht.h>
 315 #include <nsslowhash.h>
 316 void f (void) { NSSLOW_Init (); }])],
 317              libc_cv_nss_crypt=yes,
 318              AC_MSG_ERROR([
 319 cannot find NSS headers with lowlevel hash function interfaces]))
 320   old_LIBS="$LIBS"
 321   LIBS="$LIBS -lfreebl3"
 322   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 323 #include <hasht.h>
 324 #include <nsslowhash.h>],
 325                                   [NSSLOW_Init();])],
 326                  libc_cv_nss_crypt=yes,
 327                  AC_MSG_ERROR([
 328 cannot link program using lowlevel NSS hash functions]))
 329   CFLAGS="$old_CFLAGS"
 330   LIBS="$old_LIBS"
 331 else
 332   libc_cv_nss_crypt=no
 333 fi
 334 AC_SUBST(libc_cv_nss_crypt)
 335
 336
 337 AC_ARG_ENABLE([obsolete-rpc],
 338               AC_HELP_STRING([--enable-obsolete-rpc],
 339                              [build and install the obsolete RPC code for link-time usage]),
 340               [link_obsolete_rpc=$enableval],
 341               [link_obsolete_rpc=no])
 342 AC_SUBST(link_obsolete_rpc)
 343
 344 if test "$link_obsolete_rpc" = yes; then
 345   AC_DEFINE(LINK_OBSOLETE_RPC)
 346 fi
 347
 348 AC_ARG_ENABLE([systemtap],
 349               [AS_HELP_STRING([--enable-systemtap],
 350                [enable systemtap static probe points @<:@default=no@:>@])],
 351               [systemtap=$enableval],
 352               [systemtap=no])
 353 if test "x$systemtap" != xno; then
 354   AC_CACHE_CHECK([for systemtap static probe support], libc_cv_sdt, [dnl
 355   old_CFLAGS="$CFLAGS"
 356   CFLAGS="-std=gnu11 $CFLAGS"
 357   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#include <sys/sdt.h>
 358 void foo (int i, void *p)
 359 {
 360   asm ("" STAP_PROBE_ASM (foo, bar, STAP_PROBE_ASM_TEMPLATE (2)) ""
 361        :: STAP_PROBE_ASM_OPERANDS (2, i, p));
 362 }]])], [libc_cv_sdt=yes], [libc_cv_sdt=no])
 363   CFLAGS="$old_CFLAGS"])
 364   if test $libc_cv_sdt = yes; then
 365     AC_DEFINE([USE_STAP_PROBE])
 366   elif test "x$systemtap" != xauto; then
 367     AC_MSG_FAILURE([systemtap support needs sys/sdt.h with asm support])
 368   fi
 369 fi
 370
 371 AC_ARG_ENABLE([build-nscd],
 372               [AS_HELP_STRING([--disable-build-nscd],
 373                [disable building and installing the nscd daemon])],
 374               [build_nscd=$enableval],
 375               [build_nscd=default])
 376 AC_SUBST(build_nscd)
 377
 378 # Note the use of $use_nscd is near the bottom of the file.
 379 AC_ARG_ENABLE([nscd],
 380               [AS_HELP_STRING([--disable-nscd],
 381                [library functions will not contact the nscd daemon])],
 382               [use_nscd=$enableval],
 383               [use_nscd=yes])
 384
 385 AC_ARG_ENABLE([pt_chown],
 386               [AS_HELP_STRING([--enable-pt_chown],
 387                [Enable building and installing pt_chown])],
 388               [build_pt_chown=$enableval],
 389               [build_pt_chown=no])
 390 AC_SUBST(build_pt_chown)
 391 if test "$build_pt_chown" = yes; then
 392   AC_DEFINE(HAVE_PT_CHOWN)
 393 fi
 394
 395 # The abi-tags file uses a fairly simplistic model for name recognition that
 396 # can't distinguish i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a
 397 # $host_os of `gnu*' here to be `gnu-gnu*' just so that it can tell.
 398 # This doesn't get used much beyond that, so it's fairly safe.
 399 case "$host_os" in
 400 linux*)
 401   ;;
 402 gnu*)
 403   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 404   ;;
 405 esac
 406
 407 AC_ARG_ENABLE([mathvec],
 408               [AS_HELP_STRING([--enable-mathvec],
 409               [Enable building and installing mathvec @<:@default depends on architecture@:>@])],
 410               [build_mathvec=$enableval],
 411               [build_mathvec=notset])
 412
 413 # We keep the original values in `$config_*' and never modify them, so we
 414 # can write them unchanged into config.make.  Everything else uses
 415 # $machine, $vendor, and $os, and changes them whenever convenient.
 416 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 417
 418 # Don't allow vendor == "unknown"
 419 test "$config_vendor" = unknown && config_vendor=
 420 config_os="`echo $config_os | sed 's/^unknown-//'`"
 421
 422 # Some configurations imply other options.
 423 elf=yes
 424
 425 # The configure fragment of an add-on port can modify these to supplement
 426 # or override the table in the case statement below.  No fragment should
 427 # ever change the config_* variables, however.
 428 machine=$config_machine
 429 vendor=$config_vendor
 430 os=$config_os
 431 base_os=''
 432
 433 submachine=
 434 AC_ARG_WITH([cpu],
 435             AS_HELP_STRING([--with-cpu=CPU], [select code for CPU variant]),
 436             [dnl
 437   case "$withval" in
 438   yes|'') AC_MSG_ERROR([--with-cpu requires an argument]) ;;
 439   no) ;;
 440   *) submachine="$withval" ;;
 441   esac
 442 ])
 443
 444 # An preconfigure script can set this when it wants to disable the sanity
 445 # check below.
 446 libc_config_ok=no
 447
 448 dnl Let sysdeps/*/preconfigure act here, like they can in add-ons.
 449 LIBC_PRECONFIGURE([$srcdir], [for sysdeps])
 450
 451 dnl Having this here, though empty, makes sure that if add-ons' fragments
 452 dnl do AC_CONFIG_SUBDIRS([some-dir]), which just sets $subdirs, then
 453 dnl our AC_OUTPUT will actually use it.
 454 AC_CONFIG_SUBDIRS()
 455
 456 case "$enable_add_ons" in
 457 ''|no) add_ons= ;;
 458 yes|'*')
 459  add_ons=`cd $srcdir && ls -d 2> /dev/null */configure */sysdeps |
 460           sed 's@/[[^/]]*$@@' | sort | uniq`
 461          add_ons_automatic=yes
 462          ;;
 463 *) add_ons=`echo "$enable_add_ons" | sed 's/,/ /g'`
 464        add_ons_automatic=no ;;
 465 esac
 466
 467 configured_add_ons=
 468 add_ons_sfx=
 469 add_ons_pfx=
 470 if test x"$add_ons" != x; then
 471   for f in $add_ons; do
 472     # Some sanity checks
 473     case "$f" in
 474     crypt)
 475       AC_MSG_ERROR([
 476 *** It seems that you're using an old \`crypt' add-on.  crypt is now
 477 *** part of glibc and using the old add-on will not work with this
 478 *** release.  Start again with fresh sources and without the old
 479 *** \`crypt' add-on.])
 480     ;;
 481     localedata)
 482       AC_MSG_ERROR([
 483 *** It seems that you're using an old \`localedata' add-on.  localedata
 484 *** is now part of glibc and using the old add-on will not work with
 485 *** this release.  Start again with fresh sources and without the old
 486 *** \`localedata' add-on.])
 487     ;;
 488     esac
 489   done
 490
 491   # Now source each add-on's configure fragment.
 492   # The fragments can use $srcdir/$libc_add_on to find themselves,
 493   # and test $add_ons_automatic to see if they were explicitly requested.
 494   # A fragment can clear (or even change) $libc_add_on to affect
 495   # whether it goes into the list to be actually used in the build.
 496   use_add_ons=
 497   for libc_add_on in $add_ons; do
 498     # Test whether such a directory really exists.
 499     # It can be absolute, or relative to $srcdir, or relative to the build dir.
 500     case "$libc_add_on" in
 501     /*)
 502       libc_add_on_srcdir=$libc_add_on
 503       ;;
 504     *)
 505       test -d "$srcdir/$libc_add_on" || {
 506         if test -d "$libc_add_on"; then
 507           libc_add_on="`pwd`/$libc_add_on"
 508         else
 509           AC_MSG_ERROR(add-on directory \"$libc_add_on\" does not exist)
 510         fi
 511       }
 512       libc_add_on_srcdir=$srcdir/$libc_add_on
 513       ;;
 514     esac
 515
 516     libc_add_on_frag=$libc_add_on_srcdir/configure
 517     libc_add_on_canonical=
 518     libc_add_on_config_subdirs=
 519     if test -r "$libc_add_on_frag"; then
 520       AC_MSG_NOTICE(running configure fragment for add-on $libc_add_on)
 521       libc_add_on_canonical=unknown
 522       libc_add_on_subdirs=
 523       . "$libc_add_on_frag"
 524       test -z "$libc_add_on" || {
 525         configured_add_ons="$configured_add_ons $libc_add_on"
 526         if test "x$libc_add_on_canonical" = xunknown; then
 527           AC_MSG_ERROR(fragment must set \$libc_add_on_canonical)
 528         fi
 529         for d in $libc_add_on_subdirs; do
 530           case "$libc_add_on" in
 531           /*) subdir_srcdir="$libc_add_on" ;;
 532           *) subdir_srcdir="\$(..)$libc_add_on" ;;
 533           esac
 534           case "$d" in
 535           .)
 536             d="${libc_add_on_canonical:-$libc_add_on}"
 537             ;;
 538           /*)
 539             subdir_srcdir="$d"
 540             ;;
 541           *)
 542             subdir_srcdir="$subdir_srcdir/$d"
 543             ;;
 544           esac
 545           d=`echo "$d" | sed 's@/*$@@;s@^.*/@@'`
 546           add_on_subdirs="$add_on_subdirs $d"
 547           test "$subdir_srcdir" = "\$(..)$d" || config_vars="$config_vars
 548 $d-srcdir = $subdir_srcdir"
 549         done
 550         for d in $libc_add_on_config_subdirs; do
 551           case "$d" in
 552           /*) AC_MSG_ERROR(dnl
 553 fragment uses absolute path in \$libc_add_on_config_subdirs) ;;
 554           esac
 555           if test ! -d "$libc_add_on_srcdir/$d"; then
 556             AC_MSG_ERROR(fragment wants to configure missing directory $d)
 557           fi
 558           case "$libc_add_on" in
 559           /*) AC_MSG_ERROR(dnl
 560 relative path required for add-on using \$libc_add_on_config_subdirs) ;;
 561           esac
 562           subdirs="$subdirs $libc_add_on/$d"
 563         done
 564       }
 565     fi
 566     if test -n "$libc_add_on"; then
 567       LIBC_PRECONFIGURE([$libc_add_on_srcdir], [add-on $libc_add_on for])
 568       use_add_ons="$use_add_ons $libc_add_on"
 569       add_ons_pfx="$add_ons_pfx $libc_add_on/"
 570       test -z "$libc_add_on_canonical" ||
 571       add_ons_sfx="$add_ons_sfx /$libc_add_on_canonical"
 572     fi
 573   done
 574   # Use echo to strip excess whitespace.
 575   add_ons="`echo $use_add_ons`"
 576 fi
 577 AC_SUBST(add_ons)
 578 AC_SUBST(add_on_subdirs)
 579
 580
 581 ###
 582 ### I put this here to prevent those annoying emails from people who cannot
 583 ### read and try to compile glibc on unsupported platforms.  --drepper
 584 ###
 585 ### By using the undocumented --enable-hacker-mode option for configure
 586 ### one can skip this test to make the configuration not fail for unsupported
 587 ### platforms.
 588 ###
 589 if test -z "$enable_hacker_mode" && test x"$libc_config_ok" != xyes; then
 590   case "$machine-$host_os" in
 591   *-linux* | *-gnu*)
 592     ;;
 593   *)
 594     echo "*** The GNU C library is currently not available for this platform."
 595     echo "*** So far nobody cared to port it and if there is no volunteer it"
 596     echo "*** might never happen.  So, if you have interest to see glibc on"
 597     echo "*** this platform visit"
 598     echo "***   http://www.gnu.org/software/libc/porting.html"
 599     echo "*** and join the group of porters"
 600     exit 1
 601     ;;
 602   esac
 603 fi
 604
 605 # Set base_machine if not set by a preconfigure fragment.
 606 test -n "$base_machine" || base_machine=$machine
 607 AC_SUBST(base_machine)
 608
 609 # For the multi-arch option we need support in the assembler & linker.
 610 AC_CACHE_CHECK([for assembler and linker STT_GNU_IFUNC support],
 611                libc_cv_ld_gnu_indirect_function, [dnl
 612 cat > conftest.S <<EOF
 613 .type foo,%gnu_indirect_function
 614 foo:
 615 .globl _start
 616 _start:
 617 .globl __start
 618 __start:
 619 .data
 620 #ifdef _LP64
 621 .quad foo
 622 #else
 623 .long foo
 624 #endif
 625 EOF
 626 libc_cv_ld_gnu_indirect_function=no
 627 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 628             -nostartfiles -nostdlib \
 629             -o conftest conftest.S 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
 630   # Do a link to see if the backend supports IFUNC relocs.
 631   $READELF -r conftest 1>&AS_MESSAGE_LOG_FD
 632   LC_ALL=C $READELF -r conftest | grep 'no relocations' >/dev/null || {
 633     libc_cv_ld_gnu_indirect_function=yes
 634   }
 635 fi
 636 rm -f conftest*])
 637
 638 if test x"$libc_cv_ld_gnu_indirect_function" != xyes; then
 639   if test x"$multi_arch" = xyes; then
 640     AC_MSG_ERROR([--enable-multi-arch support requires assembler and linker support])
 641   else
 642     multi_arch=no
 643   fi
 644 fi
 645 multi_arch_d=
 646 if test x"$multi_arch" != xno; then
 647   multi_arch_d=/multiarch
 648 fi
 649
 650 # Compute the list of sysdep directories for this configuration.
 651 # This can take a while to compute.
 652 sysdep_dir=$srcdir/sysdeps
 653 AC_MSG_CHECKING(sysdep dirs)
 654 dnl We need to use [ and ] for other purposes for a while now.
 655 changequote(,)dnl
 656 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 657 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 658
 659 test "x$base_os" != x || case "$os" in
 660 gnu*)
 661   base_os=mach/hurd ;;
 662 linux*)
 663   base_os=unix/sysv ;;
 664 esac
 665
 666 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 667 tail=$os
 668 ostry=$os
 669 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 670   ostry="$ostry /$o"
 671   tail=$o
 672 done
 673 o=`echo $tail | sed 's/[0-9]*$//'`
 674 if test $o != $tail; then
 675   ostry="$ostry /$o"
 676 fi
 677 # For linux-gnu, try linux-gnu, then linux.
 678 o=`echo $tail | sed 's/-.*$//'`
 679 if test $o != $tail; then
 680   ostry="$ostry /$o"
 681 fi
 682
 683 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 684 base=
 685 tail=$base_os
 686 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 687   set $b
 688   base="$base /$1"
 689   tail="$2"
 690 done
 691
 692 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 693 mach=
 694 tail=$machine${submachine:+/$submachine}
 695 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 696   set $m
 697   # Prepend the machine's FPU directory unless --without-fp.
 698   if test "$with_fp" = yes; then
 699     maybe_fpu=/fpu
 700   else
 701     maybe_fpu=/nofpu
 702   fi
 703   # For each machine term, try it with and then without /multiarch.
 704   for try_fpu in $maybe_fpu ''; do
 705     for try_multi in $multi_arch_d ''; do
 706       mach="$mach /$1$try_fpu$try_multi"
 707     done
 708   done
 709   tail="$2"
 710 done
 711
 712 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 713 changequote([,])dnl
 714
 715 # Find what sysdep directories exist.
 716 sysnames_add_ons=
 717 sysnames=
 718 for b in $base ''; do
 719   for m0 in $mach ''; do
 720     for v in /$vendor ''; do
 721       test "$v" = / && continue
 722       for o in /$ostry ''; do
 723         test "$o" = / && continue
 724         for m in $mach ''; do
 725           for d in $add_ons_pfx ''; do
 726             for a in $add_ons_sfx ''; do
 727               try_suffix="$m0$b$v$o$m"
 728               if test -n "$try_suffix"; then
 729                 try_srcdir="${srcdir}/"
 730                 case "$d" in
 731                 /*) try_srcdir= ;;
 732                 esac
 733                 try="${d}sysdeps$try_suffix$a"
 734                 test -n "$enable_debug_configure" &&
 735                 echo "$0 [DEBUG]: try $try" >&2
 736                 if test -d "$try_srcdir$try"; then
 737                   sysnames="$sysnames $try"
 738                   { test -n "$o" || test -n "$b"; } && os_used=t
 739                   { test -n "$m" || test -n "$m0"; } && machine_used=t
 740                   case x${m0:-$m} in
 741                   x*/$submachine) submachine_used=t ;;
 742                   esac
 743                   if test -n "$d"; then
 744                     case "$sysnames_add_ons" in
 745                     *" $d "*) ;;
 746                     *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
 747                     esac
 748                   fi
 749                 fi
 750               fi
 751             done
 752           done
 753         done
 754       done
 755     done
 756   done
 757 done
 758
 759 # If the assembler supports gnu_indirect_function symbol type and the
 760 # architecture supports multi-arch, we enable multi-arch by default.
 761 case $sysnames_add_ons$sysnames in
 762 *"$multi_arch_d"*)
 763   ;;
 764 *)
 765   test x"$multi_arch" = xdefault && multi_arch=no
 766   ;;
 767 esac
 768 if test x"$multi_arch" != xno; then
 769   AC_DEFINE(USE_MULTIARCH)
 770 fi
 771 AC_SUBST(multi_arch)
 772
 773 if test -z "$os_used" && test "$os" != none; then
 774   AC_MSG_ERROR(Operating system $os is not supported.)
 775 fi
 776 if test -z "$machine_used" && test "$machine" != none; then
 777   AC_MSG_ERROR(The $machine is not supported.)
 778 fi
 779 if test -z "$submachine_used" && test -n "$submachine"; then
 780   AC_MSG_ERROR(The $submachine subspecies of $host_cpu is not supported.)
 781 fi
 782 AC_SUBST(submachine)
 783
 784 # We have now validated the configuration.
 785
 786 # Expand the list of system names into a full list of directories
 787 # from each element's parent name and Implies file (if present).
 788 set $sysnames
 789 names=
 790 while test $# -gt 0; do
 791   name=$1
 792   shift
 793
 794   case " $names " in *" $name "*)
 795     # Already in the list.
 796     continue
 797   esac
 798
 799   # Report each name as we discover it, so there is no long pause in output.
 800   echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
 801
 802   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 803
 804   case $name in
 805     /*) xsrcdir= ;;
 806     *)  xsrcdir=$srcdir/ ;;
 807   esac
 808   test -n "$enable_debug_configure" &&
 809   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 810
 811   for implies_file in Implies Implies-before Implies-after; do
 812     implies_type=`echo $implies_file | sed s/-/_/`
 813     eval ${implies_type}=
 814     if test -f $xsrcdir$name/$implies_file; then
 815       # Collect more names from the `Implies' file (removing comments).
 816       implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/$implies_file`"
 817       for x in $implied_candidate; do
 818         found=no
 819         if test -d $xsrcdir$name_base/$x; then
 820           eval "${implies_type}=\"\$${implies_type} \$name_base/\$x\""
 821           found=yes
 822         fi
 823         for d in $add_ons_pfx ''; do
 824           try="${d}sysdeps/$x"
 825           case $d in
 826            /*) try_srcdir= ;;
 827            *) try_srcdir=$srcdir/ ;;
 828           esac
 829           test -n "$enable_debug_configure" &&
 830            echo "[DEBUG]: $name $implies_file $x try($d) {$try_srcdir}$try" >&2
 831           if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
 832           then
 833             eval "${implies_type}=\"\$${implies_type} \$try\""
 834             found=yes
 835             case "$sysnames_add_ons" in
 836             *" $d "*) ;;
 837             *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
 838             esac
 839           fi
 840         done
 841         if test $found = no; then
 842           AC_MSG_WARN($name/$implies_file specifies nonexistent $x)
 843         fi
 844       done
 845     fi
 846   done
 847
 848   # Add NAME to the list of names.
 849   names="$names $name"
 850
 851   # Find the parent of NAME, using the empty string if it has none.
 852 changequote(,)dnl
 853   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 854 changequote([,])dnl
 855
 856   test -n "$enable_debug_configure" &&
 857     echo "[DEBUG]: $name Implies='$Implies' rest='$*' parent='$parent' \
 858 Implies_before='$Implies_before' Implies_after='$Implies_after'" >&2
 859
 860   # Add the names implied by NAME, and NAME's parent (if it has one), to
 861   # the list of names to be processed (the argument list).  We prepend the
 862   # implied names to the list and append the parent.  We want implied
 863   # directories to come before further directories inferred from the
 864   # configuration components; this ensures that for sysv4, unix/common
 865   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 866   # after sysv4).
 867   sysnames="`echo $Implies $* $Implies_before $parent $Implies_after`"
 868   test -n "$sysnames" && set $sysnames
 869 done
 870
 871 # Add the default directories.
 872 default_sysnames="sysdeps/generic"
 873 sysnames="$names $default_sysnames"
 874 AC_SUBST(sysnames)
 875 # The other names were emitted during the scan.
 876 AC_MSG_RESULT($default_sysnames)
 877
 878 # Collect the list of add-ons that supply partial sysdeps trees.
 879 sysdeps_add_ons=
 880 for add_on in $add_ons; do
 881   case "$add_on" in
 882   /*) xsrcdir= ;;
 883   *) xsrcdir="$srcdir/" ;;
 884   esac
 885
 886   test -d "$xsrcdir$add_on/sysdeps" || {
 887     case "$configured_add_ons " in
 888     *" $add_on "*) ;;
 889     *|'')
 890       AC_MSG_ERROR(add-on $add_on has no configure fragment or sysdeps tree)
 891       ;;
 892     esac
 893     continue
 894   }
 895
 896   sysdeps_add_ons="$sysdeps_add_ons $add_on"
 897   case "$sysnames_add_ons" in
 898   *" $add_on/ "*) ;;
 899   *|'')
 900     AC_MSG_WARN(add-on $add_on contributed no sysdeps directories)
 901     continue ;;
 902   esac
 903
 904   found=no
 905   for d in $sysnames; do
 906     case "$d" in
 907     $add_on/sysdeps/*) ;;
 908     *) continue ;;
 909     esac
 910     (cd "$xsrcdir$d" && for f in *[[!~]]; do
 911        case "$f" in
 912        sys|bits)
 913          for ff in $f/*.h; do
 914            test -d "$ff" || { test -e "$ff" && exit 88; }
 915          done
 916          ;;
 917        *)
 918          test -d "$f" || { test -e "$f" && exit 88; }
 919          ;;
 920        esac
 921      done)
 922     if test $? -eq 88; then
 923       found=yes
 924       break
 925     fi
 926   done
 927   if test $found = no; then
 928     AC_MSG_WARN(add-on $add_on contributed no useful sysdeps directories)
 929   fi
 930 done
 931 AC_SUBST(sysdeps_add_ons)
 932
 933
 934 ### Locate tools.
 935
 936 AC_PROG_INSTALL
 937 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
 938   # The makefiles need to use a different form to find it in $srcdir.
 939   INSTALL='\$(..)./scripts/install-sh -c'
 940 fi
 941 AC_PROG_LN_S
 942
 943 LIBC_PROG_BINUTILS
 944
 945 # Accept binutils 2.22 or newer.
 946 AC_CHECK_PROG_VER(AS, $AS, --version,
 947                   [GNU assembler.* \([0-9]*\.[0-9.]*\)],
 948                   [2.1[0-9][0-9]*|2.2[2-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
 949                   AS=: critic_missing="$critic_missing as")
 950 AC_CHECK_PROG_VER(LD, $LD, --version,
 951                   [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
 952                   [2.1[0-9][0-9]*|2.2[2-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
 953                   LD=: critic_missing="$critic_missing ld")
 954
 955 # These programs are version sensitive.
 956 AC_CHECK_TOOL_PREFIX
 957 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
 958   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
 959   [3.79* | 3.[89]* | [4-9].* | [1-9][0-9]*], critic_missing="$critic_missing make")
 960
 961 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
 962   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
 963   [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
 964   MSGFMT=: aux_missing="$aux_missing msgfmt")
 965 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 966   [GNU texinfo.* \([0-9][0-9.]*\)],
 967   [4.[7-9]*|4.[1-9][0-9]*|[5-9].*],
 968   MAKEINFO=: aux_missing="$aux_missing makeinfo")
 969 AC_CHECK_PROG_VER(SED, sed, --version,
 970   [GNU sed[^0-9]* \([0-9]*\.[0-9.]*\)],
 971   [3.0[2-9]*|3.[1-9]*|[4-9]*],
 972   SED=: aux_missing="$aux_missing sed")
 973 AC_CHECK_PROG_VER(AWK, gawk, --version,
 974   [GNU Awk[^0-9]*\([0-9][0-9.]*\)],
 975   [3.1.[2-9]*|3.[2-9]*|[4-9]*], critic_missing="$critic_missing gawk")
 976
 977 AC_CACHE_CHECK([if $CC is sufficient to build libc], libc_cv_compiler_ok, [
 978 AC_TRY_COMPILE([], [
 979 #if !defined __GNUC__ || __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 7)
 980 #error insufficient compiler
 981 #endif],
 982                [libc_cv_compiler_ok=yes],
 983                [libc_cv_compiler_ok=no])])
 984 AS_IF([test $libc_cv_compiler_ok != yes],
 985       [critic_missing="$critic_missing compiler"])
 986
 987 AC_CHECK_TOOL(NM, nm, false)
 988
 989 if test "x$maintainer" = "xyes"; then
 990   AC_CHECK_PROGS(AUTOCONF, autoconf, no)
 991   case "x$AUTOCONF" in
 992   xno|x|x:) AUTOCONF=no ;;
 993   *)
 994     AC_CACHE_CHECK(dnl
 995   whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
 996     if (cd $srcdir; $AUTOCONF $ACFLAGS configure.ac > /dev/null 2>&1); then
 997       libc_cv_autoconf_works=yes
 998     else
 999       libc_cv_autoconf_works=no
1000     fi])
1001     test $libc_cv_autoconf_works = yes || AUTOCONF=no
1002     ;;
1003   esac
1004   if test "x$AUTOCONF" = xno; then
1005     aux_missing="$aux_missing autoconf"
1006   fi
1007 else
1008   AUTOCONF=no
1009 fi
1010
1011 test -n "$critic_missing" && AC_MSG_ERROR([
1012 *** These critical programs are missing or too old:$critic_missing
1013 *** Check the INSTALL file for required versions.])
1014
1015 test -n "$aux_missing" && AC_MSG_WARN([
1016 *** These auxiliary programs are missing or incompatible versions:$aux_missing
1017 *** some features will be disabled.
1018 *** Check the INSTALL file for required versions.])
1019
1020 # if using special system headers, find out the compiler's sekrit
1021 # header directory and add that to the list.  NOTE: Only does the right
1022 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
1023 if test -n "$sysheaders"; then
1024   SYSINCLUDES=-nostdinc
1025   for d in include include-fixed; do
1026     i=`$CC -print-file-name="$d"` && test "x$i" != x && test "x$i" != "x$d" &&
1027     SYSINCLUDES="$SYSINCLUDES -isystem $i"
1028   done
1029   SYSINCLUDES="$SYSINCLUDES \
1030 -isystem `echo $sysheaders | sed 's/:/ -isystem /g'`"
1031   if test -n "$CXX"; then
1032     CXX_SYSINCLUDES=
1033     for cxxheaders in `$CXX -v -S -x c++ /dev/null -o /dev/null 2>&1 \
1034     | sed -n -e '1,/#include/d' -e 's/^ \(\/.*\/[cg]++\)/\1/p'`; do
1035       test "x$cxxheaders" != x &&
1036       CXX_SYSINCLUDES="$CXX_SYSINCLUDES -isystem $cxxheaders"
1037     done
1038   fi
1039 fi
1040 AC_SUBST(SYSINCLUDES)
1041 AC_SUBST(CXX_SYSINCLUDES)
1042
1043 # Test if LD_LIBRARY_PATH contains the notation for the current directory
1044 # since this would lead to problems installing/building glibc.
1045 # LD_LIBRARY_PATH contains the current directory if one of the following
1046 # is true:
1047 # - one of the terminals (":" and ";") is the first or last sign
1048 # - two terminals occur directly after each other
1049 # - the path contains an element with a dot in it
1050 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
1051 changequote(,)dnl
1052 case ${LD_LIBRARY_PATH} in
1053   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
1054     ld_library_path_setting="contains current directory"
1055     ;;
1056   *)
1057     ld_library_path_setting="ok"
1058     ;;
1059 esac
1060 changequote([,])dnl
1061 AC_MSG_RESULT($ld_library_path_setting)
1062 if test "$ld_library_path_setting" != "ok"; then
1063 AC_MSG_ERROR([
1064 *** LD_LIBRARY_PATH shouldn't contain the current directory when
1065 *** building glibc. Please change the environment variable
1066 *** and run configure again.])
1067 fi
1068
1069 AC_PATH_PROG(BASH_SHELL, bash, no)
1070
1071 AC_PATH_PROG(PERL, perl, no)
1072 if test "$PERL" != no &&
1073    (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
1074   PERL=no
1075 fi
1076 AC_PATH_PROG(INSTALL_INFO, install-info, no,
1077              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
1078 AC_CHECK_PROG_VER(BISON, bison, --version,
1079                   [bison (GNU Bison) \([0-9]*\.[0-9.]*\)],
1080                   [2.7*|[3-9].*|[1-9][0-9]*],
1081                   BISON=no)
1082
1083 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
1084 cat > conftest.s <<EOF
1085 .text
1086 foo:
1087 .set glibc_conftest_frobozz,foo
1088 .globl glibc_conftest_frobozz
1089 EOF
1090 # The alpha-dec-osf1 assembler gives only a warning for `.set'
1091 # (but it doesn't work), so we must do a linking check to be sure.
1092 cat > conftest1.c <<\EOF
1093 extern int glibc_conftest_frobozz;
1094 void _start() { glibc_conftest_frobozz = 1; }
1095 EOF
1096 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1097             -nostartfiles -nostdlib \
1098             -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1099   libc_cv_asm_set_directive=yes
1100 else
1101   libc_cv_asm_set_directive=no
1102 fi
1103 rm -f conftest*])
1104 if test $libc_cv_asm_set_directive = yes; then
1105   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
1106 fi
1107
1108 AC_CACHE_CHECK(linker support for protected data symbol,
1109                libc_cv_protected_data,
1110                [cat > conftest.c <<EOF
1111                 int bar __attribute__ ((visibility ("protected"))) = 1;
1112 EOF
1113                 libc_cv_protected_data=no
1114                 if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles -fPIC -shared conftest.c -o conftest.so); then
1115                   cat > conftest.c <<EOF
1116                   extern int bar;
1117                   int main (void) { return bar; }
1118 EOF
1119                   if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles conftest.c -o conftest conftest.so); then
1120                     libc_cv_protected_data=yes
1121                   fi
1122                 fi
1123                 rm -f conftest.*
1124                ])
1125 AC_SUBST(libc_cv_protected_data)
1126
1127 AC_CACHE_CHECK(for broken __attribute__((alias())),
1128                libc_cv_broken_alias_attribute,
1129                [cat > conftest.c <<EOF
1130                extern int foo (int x) __asm ("xyzzy");
1131                int bar (int x) { return x; }
1132                extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1133                extern int dfoo;
1134                extern __typeof (dfoo) dfoo __asm ("abccb");
1135                int dfoo = 1;
1136 EOF
1137                libc_cv_broken_alias_attribute=yes
1138                if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1139                  if grep 'xyzzy' conftest.s >/dev/null &&
1140                     grep 'abccb' conftest.s >/dev/null; then
1141                    libc_cv_broken_alias_attribute=no
1142                  fi
1143                fi
1144                rm -f conftest.c conftest.s
1145                ])
1146 if test $libc_cv_broken_alias_attribute = yes; then
1147   AC_MSG_ERROR(working alias attribute support required)
1148 fi
1149
1150 AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1151                libc_cv_have_sdata_section,
1152                [echo "int i;" > conftest.c
1153                 libc_cv_have_sdata_section=no
1154                 if ${CC-cc} $LDFLAGS -fPIC -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1155                    | grep '\.sdata' >/dev/null; then
1156                   libc_cv_have_sdata_section=yes
1157                 fi
1158                 rm -f conftest.c conftest.so
1159                ])
1160 if test $libc_cv_have_sdata_section = yes; then
1161   AC_DEFINE(HAVE_SDATA_SECTION)
1162 fi
1163
1164 AC_CACHE_CHECK(whether to use .ctors/.dtors header and trailer,
1165                libc_cv_ctors_header, [dnl
1166   libc_cv_ctors_header=yes
1167   LIBC_TRY_LINK_STATIC([
1168 __attribute__ ((constructor)) void ctor (void) { asm (""); }
1169 __attribute__ ((destructor))  void dtor (void) { asm (""); }
1170 ],
1171               [dnl
1172       AS_IF([$READELF -WS conftest$ac_exeext | $AWK '
1173         { gsub(/\@<:@ */, "@<:@") }
1174         $2 == ".ctors" || $2 == ".dtors" {
1175           size = strtonum("0x" $6)
1176           align = strtonum("0x" $NF)
1177           seen@<:@$2@:>@ = 1
1178           stub@<:@$2@:>@ = size == align * 2
1179         }
1180         END {
1181           ctors_ok = !seen@<:@".ctors"@:>@ || stub@<:@".ctors"@:>@
1182           dtors_ok = !seen@<:@".dtors"@:>@ || stub@<:@".dtors"@:>@
1183           exit ((ctors_ok && dtors_ok) ? 0 : 1)
1184         }
1185       '], [libc_cv_ctors_header=no])
1186     ], [dnl
1187       AC_MSG_ERROR([missing __attribute__ ((constructor)) support??])
1188     ])
1189 ])
1190 if test $libc_cv_ctors_header = no; then
1191   AC_DEFINE(NO_CTORS_DTORS_SECTIONS)
1192 fi
1193
1194 AC_CACHE_CHECK(for libunwind-support in compiler,
1195                libc_cv_cc_with_libunwind, [
1196   cat > conftest.c <<EOF
1197 int main (void) { return 0; }
1198 EOF
1199   if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static -o conftest \
1200      conftest.c -v 2>&1 >/dev/null | grep ' -lunwind ' >/dev/null; then
1201     libc_cv_cc_with_libunwind=yes
1202   else
1203     libc_cv_cc_with_libunwind=no
1204   fi
1205   rm -f conftest*])
1206 AC_SUBST(libc_cv_cc_with_libunwind)
1207 if test $libc_cv_cc_with_libunwind = yes; then
1208   AC_DEFINE(HAVE_CC_WITH_LIBUNWIND)
1209 fi
1210
1211 LIBC_LINKER_FEATURE([-z nodelete], [-Wl,--enable-new-dtags,-z,nodelete],
1212                     [libc_cv_z_nodelete=yes],
1213                     [AC_MSG_ERROR(linker with -z nodelete support required)])
1214
1215 LIBC_LINKER_FEATURE([-z nodlopen], [-Wl,--enable-new-dtags,-z,nodlopen],
1216                     [libc_cv_z_nodlopen=yes],
1217                     [AC_MSG_ERROR(linker with -z nodlopen support required)])
1218
1219 LIBC_LINKER_FEATURE([-z initfirst], [-Wl,--enable-new-dtags,-z,initfirst],
1220                     [libc_cv_z_initfirst=yes],
1221                     [AC_MSG_ERROR(linker with -z initfirst support required)])
1222
1223 ASFLAGS_config=
1224 AC_CACHE_CHECK(whether --noexecstack is desirable for .S files,
1225                libc_cv_as_noexecstack, [dnl
1226 cat > conftest.c <<EOF
1227 void foo (void) { }
1228 EOF
1229 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS
1230                    -S -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD]) \
1231    && grep .note.GNU-stack conftest.s >/dev/null \
1232    && AC_TRY_COMMAND([${CC-cc} $ASFLAGS -Wa,--noexecstack
1233                       -c -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
1234 then
1235   libc_cv_as_noexecstack=yes
1236 else
1237   libc_cv_as_noexecstack=no
1238 fi
1239 rm -f conftest*])
1240 if test $libc_cv_as_noexecstack = yes; then
1241   ASFLAGS_config="$ASFLAGS_config -Wa,--noexecstack"
1242 fi
1243 AC_SUBST(ASFLAGS_config)
1244
1245 AC_CACHE_CHECK(for -z combreloc,
1246                libc_cv_z_combreloc, [dnl
1247 cat > conftest.c <<EOF
1248 extern int bar (int);
1249 extern int mumble;
1250 int foo (void) { return bar (mumble); }
1251 EOF
1252 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1253                         -fPIC -shared -o conftest.so conftest.c
1254                         -nostdlib -nostartfiles
1255                         -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1256 then
1257 dnl The following test is a bit weak.  We must use a tool which can test
1258 dnl cross-platform since the gcc used can be a cross compiler.  Without
1259 dnl introducing new options this is not easily doable.  Instead use a tool
1260 dnl which always is cross-platform: readelf.  To detect whether -z combreloc
1261 dnl look for a section named .rel.dyn.
1262   if $READELF -S conftest.so | grep '\.rel\(a\|\)\.dyn' > /dev/null; then
1263     libc_cv_z_combreloc=yes
1264   else
1265     libc_cv_z_combreloc=no
1266   fi
1267 else
1268   libc_cv_z_combreloc=no
1269 fi
1270 rm -f conftest*])
1271 if test "$libc_cv_z_combreloc" = yes; then
1272   AC_DEFINE(HAVE_Z_COMBRELOC)
1273 fi
1274 AC_SUBST(libc_cv_z_combreloc)
1275
1276 LIBC_LINKER_FEATURE([-z execstack], [-Wl,-z,execstack],
1277                     [libc_cv_z_execstack=yes], [libc_cv_z_execstack=no])
1278 AC_SUBST(libc_cv_z_execstack)
1279
1280 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
1281 LIBC_TRY_CC_OPTION([-fpie], [libc_cv_fpie=yes], [libc_cv_fpie=no])
1282 ])
1283
1284 AC_SUBST(libc_cv_fpie)
1285
1286 AC_CACHE_CHECK(for --hash-style option,
1287                libc_cv_hashstyle, [dnl
1288 cat > conftest.c <<EOF
1289 int _start (void) { return 42; }
1290 EOF
1291 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1292                             -fPIC -shared -o conftest.so conftest.c
1293                             -Wl,--hash-style=both -nostdlib 1>&AS_MESSAGE_LOG_FD])
1294 then
1295   libc_cv_hashstyle=yes
1296 else
1297   libc_cv_hashstyle=no
1298 fi
1299 rm -f conftest*])
1300 AC_SUBST(libc_cv_hashstyle)
1301
1302 # The linker's default -shared behavior is good enough if it
1303 # does these things that our custom linker scripts ensure that
1304 # all allocated NOTE sections come first.
1305 if test "$use_default_link" = default; then
1306   AC_CACHE_CHECK([for sufficient default -shared layout],
1307                   libc_cv_use_default_link, [dnl
1308   libc_cv_use_default_link=no
1309   cat > conftest.s <<\EOF
1310           .section .note.a,"a",%note
1311           .balign 4
1312           .long 4,4,9
1313           .string "GNU"
1314           .string "foo"
1315           .section .note.b,"a",%note
1316           .balign 4
1317           .long 4,4,9
1318           .string "GNU"
1319           .string "bar"
1320 EOF
1321   if AC_TRY_COMMAND([dnl
1322   ${CC-cc} $ASFLAGS -shared -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD]) &&
1323        ac_try=`$READELF -S conftest.so | sed -n \
1324          ['${x;p;}
1325           s/^ *\[ *[1-9][0-9]*\]  *\([^ ][^ ]*\)  *\([^ ][^ ]*\) .*$/\2 \1/
1326           t a
1327           b
1328           : a
1329           H']`
1330   then
1331     libc_seen_a=no libc_seen_b=no
1332     set -- $ac_try
1333     while test $# -ge 2 -a "$1" = NOTE; do
1334       case "$2" in
1335       .note.a) libc_seen_a=yes ;;
1336       .note.b) libc_seen_b=yes ;;
1337       esac
1338       shift 2
1339     done
1340     case "$libc_seen_a$libc_seen_b" in
1341     yesyes)
1342       libc_cv_use_default_link=yes
1343       ;;
1344     *)
1345       echo >&AS_MESSAGE_LOG_FD "\
1346 $libc_seen_a$libc_seen_b from:
1347 $ac_try"
1348       ;;
1349     esac
1350   fi
1351   rm -f conftest*])
1352   use_default_link=$libc_cv_use_default_link
1353 fi
1354
1355 AC_CACHE_CHECK(linker output format, libc_cv_output_format, [dnl
1356 if libc_cv_output_format=`
1357 ${CC-cc} -nostartfiles -nostdlib -Wl,--print-output-format 2>&AS_MESSAGE_LOG_FD`
1358 then
1359   :
1360 else
1361   libc_cv_output_format=
1362 fi
1363 test -n "$libc_cv_output_format" || libc_cv_output_format=unknown])
1364 AC_SUBST(libc_cv_output_format)
1365
1366 AC_CACHE_CHECK(for -fno-toplevel-reorder -fno-section-anchors, libc_cv_fno_toplevel_reorder, [dnl
1367 cat > conftest.c <<EOF
1368 int foo;
1369 EOF
1370 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fno-toplevel-reorder -fno-section-anchors
1371                             conftest.c 1>&AS_MESSAGE_LOG_FD])
1372 then
1373   libc_cv_fno_toplevel_reorder=yes
1374 else
1375   libc_cv_fno_toplevel_reorder=no
1376 fi
1377 rm -f conftest*])
1378 if test $libc_cv_fno_toplevel_reorder = yes; then
1379   fno_unit_at_a_time="-fno-toplevel-reorder -fno-section-anchors"
1380 else
1381   fno_unit_at_a_time=-fno-unit-at-a-time
1382 fi
1383 AC_SUBST(fno_unit_at_a_time)
1384
1385 AC_CACHE_CHECK(for -fstack-protector, libc_cv_ssp, [dnl
1386 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector],
1387                    [libc_cv_ssp=yes],
1388                    [libc_cv_ssp=no])
1389 ])
1390
1391 AC_CACHE_CHECK(for -fstack-protector-strong, libc_cv_ssp_strong, [dnl
1392 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector-strong],
1393                    [libc_cv_ssp_strong=yes],
1394                    [libc_cv_ssp_strong=no])
1395 ])
1396
1397 stack_protector=
1398 if test "$libc_cv_ssp_strong" = "yes"; then
1399   stack_protector="-fstack-protector-strong"
1400 elif test "$libc_cv_ssp" = "yes"; then
1401   stack_protector="-fstack-protector"
1402 fi
1403 AC_SUBST(stack_protector)
1404
1405 AC_CACHE_CHECK(whether cc puts quotes around section names,
1406                libc_cv_have_section_quotes,
1407                [cat > conftest.c <<EOF
1408                 static const int foo
1409                 __attribute__ ((section ("bar"))) = 1;
1410 EOF
1411                 if ${CC-cc} -S conftest.c -o conftest.s; then
1412                   if grep '\.section.*"bar"' conftest.s >/dev/null; then
1413                     libc_cv_have_section_quotes=yes
1414                   else
1415                     libc_cv_have_section_quotes=no
1416                   fi
1417                 else
1418                   libc_cv_have_section_quotes=unknown
1419                 fi
1420                 rm -f conftest.{c,s}
1421                 ])
1422 if test $libc_cv_have_section_quotes = yes; then
1423   AC_DEFINE(HAVE_SECTION_QUOTES)
1424 fi
1425
1426 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
1427 cat > conftest.c <<\EOF
1428 void zero (void *x)
1429 {
1430   __builtin_memset (x, 0, 1000);
1431 }
1432 EOF
1433 dnl
1434 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "memset" > /dev/null]);
1435 then
1436   libc_cv_gcc_builtin_memset=no
1437 else
1438   libc_cv_gcc_builtin_memset=yes
1439 fi
1440 rm -f conftest* ])
1441 if test "$libc_cv_gcc_builtin_memset" = yes ; then
1442   AC_DEFINE(HAVE_BUILTIN_MEMSET)
1443 fi
1444
1445 AC_CACHE_CHECK(for redirection of built-in functions, libc_cv_gcc_builtin_redirection, [dnl
1446 cat > conftest.c <<\EOF
1447 extern char *strstr (const char *, const char *) __asm ("my_strstr");
1448 char *foo (const char *a, const char *b)
1449 {
1450   return __builtin_strstr (a, b);
1451 }
1452 EOF
1453 dnl
1454 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "my_strstr" > /dev/null]);
1455 then
1456   libc_cv_gcc_builtin_redirection=yes
1457 else
1458   libc_cv_gcc_builtin_redirection=no
1459 fi
1460 rm -f conftest* ])
1461 if test "$libc_cv_gcc_builtin_redirection" = no; then
1462   AC_MSG_ERROR([support for the symbol redirection needed])
1463 fi
1464
1465 dnl Determine how to disable generation of FMA instructions.
1466 AC_CACHE_CHECK([for compiler option to disable generation of FMA instructions],
1467                libc_cv_cc_nofma, [dnl
1468 libc_cv_cc_nofma=
1469 for opt in -ffp-contract=off -mno-fused-madd; do
1470   LIBC_TRY_CC_OPTION([$opt], [libc_cv_cc_nofma=$opt; break])
1471 done])
1472 AC_SUBST(libc_cv_cc_nofma)
1473
1474 if test -n "$submachine"; then
1475   AC_CACHE_CHECK([for compiler option for CPU variant],
1476                  libc_cv_cc_submachine, [dnl
1477   libc_cv_cc_submachine=no
1478   for opt in "-march=$submachine" "-mcpu=$submachine"; do
1479     LIBC_TRY_CC_OPTION([$opt], [
1480       libc_cv_cc_submachine="$opt"
1481       break], [])
1482   done])
1483   if test "x$libc_cv_cc_submachine" = xno; then
1484     AC_MSG_ERROR([${CC-cc} does not support $submachine])
1485   fi
1486 fi
1487 AC_SUBST(libc_cv_cc_submachine)
1488
1489 AC_CACHE_CHECK(if $CC accepts -fno-tree-loop-distribute-patterns with \
1490 __attribute__ ((__optimize__)), libc_cv_cc_loop_to_function, [dnl
1491 cat > conftest.c <<EOF
1492 void
1493 __attribute__ ((__optimize__ ("-fno-tree-loop-distribute-patterns")))
1494 foo (void) {}
1495 EOF
1496 libc_cv_cc_loop_to_function=no
1497 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c])
1498 then
1499   libc_cv_cc_loop_to_function=yes
1500 fi
1501 rm -f conftest*])
1502 if test $libc_cv_cc_loop_to_function = yes; then
1503   AC_DEFINE(HAVE_CC_INHIBIT_LOOP_TO_LIBCALL)
1504 fi
1505 AC_SUBST(libc_cv_cc_loop_to_function)
1506
1507 dnl Check whether we have the gd library available.
1508 AC_MSG_CHECKING(for libgd)
1509 if test "$with_gd" != "no"; then
1510   old_CFLAGS="$CFLAGS"
1511   CFLAGS="$CFLAGS $libgd_include"
1512   old_LDFLAGS="$LDFLAGS"
1513   LDFLAGS="$LDFLAGS $libgd_ldflags"
1514   old_LIBS="$LIBS"
1515   LIBS="$LIBS -lgd -lpng -lz -lm"
1516   AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1517   CFLAGS="$old_CFLAGS"
1518   LDFLAGS="$old_LDFLAGS"
1519   LIBS="$old_LIBS"
1520 else
1521   LIBGD=no
1522 fi
1523 AC_MSG_RESULT($LIBGD)
1524 AC_SUBST(LIBGD)
1525
1526 # SELinux detection
1527 if test x$with_selinux = xno ; then
1528   have_selinux=no;
1529 else
1530   # See if we have the SELinux library
1531   AC_CHECK_LIB(selinux, is_selinux_enabled,
1532                have_selinux=yes, have_selinux=no)
1533   if test x$with_selinux = xyes ; then
1534     if test x$have_selinux = xno ; then
1535       AC_MSG_ERROR([SELinux explicitly required, but SELinux library not found])
1536     fi
1537   fi
1538 fi
1539 # Check if we're building with SELinux support.
1540 if test "x$have_selinux" = xyes; then
1541   AC_DEFINE(HAVE_SELINUX, 1, [SELinux support])
1542
1543   # See if we have the libaudit library
1544   AC_CHECK_LIB(audit, audit_log_user_avc_message,
1545                have_libaudit=yes, have_libaudit=no)
1546   if test "x$have_libaudit" = xyes; then
1547     AC_DEFINE(HAVE_LIBAUDIT, 1, [SELinux libaudit support])
1548   fi
1549   AC_SUBST(have_libaudit)
1550
1551   # See if we have the libcap library
1552   AC_CHECK_LIB(cap, cap_init, have_libcap=yes, have_libcap=no)
1553   if test "x$have_libcap" = xyes; then
1554     AC_DEFINE(HAVE_LIBCAP, 1, [SELinux libcap support])
1555   fi
1556   AC_SUBST(have_libcap)
1557 fi
1558 AC_SUBST(have_selinux)
1559
1560 CPPUNDEFS=
1561 dnl Check for silly hacked compilers predefining _FORTIFY_SOURCE.
1562 dnl Since we are building the implementations of the fortified functions here,
1563 dnl having the macro defined interacts very badly.
1564 AC_CACHE_CHECK([for _FORTIFY_SOURCE predefine], libc_cv_predef_fortify_source,
1565 [AC_TRY_COMPILE([], [
1566 #ifdef _FORTIFY_SOURCE
1567 # error bogon
1568 #endif],
1569                 [libc_cv_predef_fortify_source=no],
1570                 [libc_cv_predef_fortify_source=yes])])
1571 if test $libc_cv_predef_fortify_source = yes; then
1572   CPPUNDEFS="${CPPUNDEFS:+$CPPUNDEFS }-U_FORTIFY_SOURCE"
1573 fi
1574 AC_SUBST(CPPUNDEFS)
1575
1576 dnl Check for silly hacked compilers inserting -fstack-protector.
1577 dnl This breaks badly for the early startup code we compile, since
1578 dnl the compiled code can refer to a magic machine-dependent location
1579 dnl for the canary value before we have sufficient setup for that to
1580 dnl work.  It's also questionable to build all of libc with this flag
1581 dnl even when you're doing that for most applications you build, since
1582 dnl libc's code is so heavily-used and performance-sensitive.  If we
1583 dnl ever really want to make that work, it should be enabled explicitly
1584 dnl in the libc build, not inherited from implicit compiler settings.
1585 AC_CACHE_CHECK([whether $CC implicitly enables -fstack-protector],
1586                libc_cv_predef_stack_protector, [
1587 AC_TRY_COMPILE([extern void foobar (char *);],
1588                [char large_array[2048]; foobar (large_array);], [
1589 libc_undefs=`$NM -u conftest.o |
1590   LC_ALL=C $AWK '$1 == "U" { print $2 | "sort -u"; next } { exit(1) }' \
1591     2>&AS_MESSAGE_LOG_FD` || {
1592   AC_MSG_ERROR([confusing output from $NM -u])
1593 }
1594 echo >&AS_MESSAGE_LOG_FD "libc_undefs='$libc_undefs'"
1595 # On some architectures, there are architecture-specific undefined
1596 # symbols (resolved by the linker), so filter out unknown symbols.
1597 # This will fail to produce the correct result if the compiler
1598 # defaults to -fstack-protector but this produces an undefined symbol
1599 # other than __stack_chk_fail.  However, compilers like that have not
1600 # been encountered in practice.
1601 libc_undefs=`echo "$libc_undefs" | egrep '^(foobar|__stack_chk_fail)$'`
1602 case "$libc_undefs" in
1603 foobar) libc_cv_predef_stack_protector=no ;;
1604 '__stack_chk_fail
1605 foobar') libc_cv_predef_stack_protector=yes ;;
1606 *) AC_MSG_ERROR([unexpected symbols in test: $libc_undefs]) ;;
1607 esac],
1608                [AC_MSG_ERROR([test compilation failed])])
1609 ])
1610 libc_extra_cflags=
1611 if test $libc_cv_predef_stack_protector = yes; then
1612   libc_extra_cflags="$libc_extra_cflags -fno-stack-protector"
1613 fi
1614 libc_extra_cppflags=
1615
1616 # Some linkers on some architectures support __ehdr_start but with
1617 # bugs.  Make sure usage of it does not create relocations in the
1618 # output (as the linker should resolve them all for us).
1619 AC_CACHE_CHECK([whether the linker provides working __ehdr_start],
1620                libc_cv_ehdr_start, [
1621 old_CFLAGS="$CFLAGS"
1622 old_LDFLAGS="$LDFLAGS"
1623 old_LIBS="$LIBS"
1624 CFLAGS="$CFLAGS -fPIC"
1625 LDFLAGS="$LDFLAGS -nostdlib -nostartfiles -shared"
1626 LIBS=
1627 AC_LINK_IFELSE([AC_LANG_SOURCE([
1628 typedef struct {
1629   char foo;
1630   long val;
1631 } Ehdr;
1632 extern const Ehdr __ehdr_start __attribute__ ((visibility ("hidden")));
1633 long ehdr (void) { return __ehdr_start.val; }
1634 ])],
1635                [if $READELF -r conftest | fgrep __ehdr_start >/dev/null; then
1636                   libc_cv_ehdr_start=broken
1637                 else
1638                   libc_cv_ehdr_start=yes
1639                 fi], [libc_cv_ehdr_start=no])
1640 CFLAGS="$old_CFLAGS"
1641 LDFLAGS="$old_LDFLAGS"
1642 LIBS="$old_LIBS"
1643 ])
1644 if test "$libc_cv_ehdr_start" = yes; then
1645   AC_DEFINE([HAVE_EHDR_START])
1646 elif test "$libc_cv_ehdr_start" = broken; then
1647   AC_MSG_WARN([linker is broken -- you should upgrade])
1648 fi
1649
1650 AC_CACHE_CHECK(for __builtin_trap with no external dependencies,
1651                libc_cv_builtin_trap, [dnl
1652 libc_cv_builtin_trap=no
1653 AC_TRY_COMPILE([], [__builtin_trap ()], [
1654 libc_undefs=`$NM -u conftest.o |
1655   LC_ALL=C $AWK '$1 == "U" { print $2 | "sort -u"; next } { exit(1) }' \
1656     2>&AS_MESSAGE_LOG_FD` || {
1657   AC_MSG_ERROR([confusing output from $NM -u])
1658 }
1659 echo >&AS_MESSAGE_LOG_FD "libc_undefs='$libc_undefs'"
1660 if test -z "$libc_undefs"; then
1661   libc_cv_builtin_trap=yes
1662 fi])])
1663 if test $libc_cv_builtin_trap = yes; then
1664   AC_DEFINE([HAVE_BUILTIN_TRAP])
1665 fi
1666
1667 dnl C++ feature tests.
1668 AC_LANG_PUSH([C++])
1669
1670 AC_CACHE_CHECK([whether the C++ compiler supports thread_local],
1671                libc_cv_cxx_thread_local, [
1672 old_CXXFLAGS="$CXXFLAGS"
1673 CXXFLAGS="$CXXFLAGS -std=gnu++11"
1674 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1675 #include <thread>
1676
1677 // Compiler support.
1678 struct S
1679 {
1680   S ();
1681   ~S ();
1682 };
1683 thread_local S s;
1684 S * get () { return &s; }
1685
1686 // libstdc++ support.
1687 #ifndef _GLIBCXX_HAVE___CXA_THREAD_ATEXIT_IMPL
1688 #error __cxa_thread_atexit_impl not supported
1689 #endif
1690 ])],
1691                [libc_cv_cxx_thread_local=yes],
1692                [libc_cv_cxx_thread_local=no])
1693 CXXFLAGS="$old_CXXFLAGS"
1694 ])
1695 AC_SUBST(libc_cv_cxx_thread_local)
1696
1697 AC_LANG_POP([C++])
1698 dnl End of C++ feature tests.
1699
1700 ### End of automated tests.
1701 ### Now run sysdeps configure fragments.
1702
1703 # They also can set these variables.
1704 use_ldconfig=no
1705 ldd_rewrite_script=no
1706 libc_cv_sysconfdir=$sysconfdir
1707 libc_cv_localstatedir=$localstatedir
1708 libc_cv_gcc_unwind_find_fde=no
1709 libc_cv_idn=no
1710
1711 # Iterate over all the sysdep directories we will use, running their
1712 # configure fragments.
1713 for dir in $sysnames; do
1714   case $dir in
1715     /*) dest=$dir ;;
1716     *)  dest=$srcdir/$dir ;;
1717   esac
1718   if test -r $dest/configure; then
1719     AC_MSG_RESULT(running configure fragment for $dir)
1720     . $dest/configure
1721   fi
1722 done
1723
1724 if test x"$build_mathvec" = xnotset; then
1725   build_mathvec=no
1726 fi
1727 LIBC_CONFIG_VAR([build-mathvec], [$build_mathvec])
1728
1729 AC_SUBST(libc_extra_cflags)
1730 AC_SUBST(libc_extra_cppflags)
1731
1732 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
1733   AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
1734 fi
1735 AC_SUBST(libc_cv_gcc_unwind_find_fde)
1736
1737 # A sysdeps configure fragment can reset this if IFUNC is not actually
1738 # usable even though the assembler knows how to generate the symbol type.
1739 if test x"$libc_cv_ld_gnu_indirect_function" = xyes; then
1740   AC_DEFINE(HAVE_IFUNC)
1741 fi
1742
1743 # This is far from the AC_ARG_ENABLE that sets it so that a sysdeps
1744 # configure fragment can override the value to prevent this AC_DEFINE.
1745 AC_SUBST(use_nscd)
1746 if test "x$use_nscd" != xno; then
1747   AC_DEFINE([USE_NSCD])
1748 fi
1749 if test "x$build_nscd" = xdefault; then
1750   build_nscd=$use_nscd
1751 fi
1752
1753 AC_SUBST(libc_cv_slibdir)
1754 AC_SUBST(libc_cv_rtlddir)
1755 AC_SUBST(libc_cv_localedir)
1756 AC_SUBST(libc_cv_sysconfdir)
1757 AC_SUBST(libc_cv_localstatedir)
1758 AC_SUBST(libc_cv_rootsbindir)
1759
1760 if test x$use_ldconfig = xyes; then
1761   AC_DEFINE(USE_LDCONFIG)
1762 fi
1763 AC_SUBST(use_ldconfig)
1764 AC_SUBST(ldd_rewrite_script)
1765
1766 AC_SUBST(static)
1767 AC_SUBST(shared)
1768
1769 AC_CACHE_CHECK([whether -fPIC is default], libc_cv_pic_default,
1770 [libc_cv_pic_default=yes
1771 cat > conftest.c <<EOF
1772 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1773 # error PIC is default.
1774 #endif
1775 EOF
1776 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1777   libc_cv_pic_default=no
1778 fi
1779 rm -f conftest.*])
1780 AC_SUBST(libc_cv_pic_default)
1781
1782 AC_CACHE_CHECK([whether -fPIE is default], libc_cv_pie_default,
1783 [libc_cv_pie_default=yes
1784 cat > conftest.c <<EOF
1785 #if defined __PIE__ || defined __pie__ || defined PIE || defined pie
1786 # error PIE is default.
1787 #endif
1788 EOF
1789 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1790   libc_cv_pie_default=no
1791 fi
1792 rm -f conftest.*])
1793 AC_SUBST(libc_cv_pie_default)
1794
1795 AC_SUBST(profile)
1796 AC_SUBST(static_nss)
1797
1798 AC_SUBST(DEFINES)
1799
1800 dnl See sysdeps/mach/configure.ac for this variable.
1801 AC_SUBST(mach_interface_list)
1802
1803 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1804 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1805 AC_SUBST(VERSION)
1806 AC_SUBST(RELEASE)
1807
1808 AC_CONFIG_FILES([config.make Makefile])
1809 AC_CONFIG_COMMANDS([default],[[
1810 case $CONFIG_FILES in *config.make*)
1811 echo "$config_vars" >> config.make;;
1812 esac
1813 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
1814 AC_OUTPUT