sysdeps/powerpc/powerpc64/fpu/s_nearbyint.S

   1 /* Round to int floating-point values.  PowerPC64 version.
   2    Copyright (C) 2011-2016 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Adhemerval Zanella <azanella@br.ibm.com>, 2011
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 /* This has been coded in assembler because GCC makes such a mess of it
  21    when it's coded in C.  */
  22
  23 #include <sysdep.h>
  24 #include <math_ldbl_opt.h>
  25
  26
  27 /* double [fp1] nearbyint(double [fp1] x) */
  28
  29         .section        ".toc","aw"
  30 .LC0:   /* 2**52 */
  31         .tc FD_43300000_0[TC],0x4330000000000000
  32         .section        ".text"
  33
  34 EALIGN (__nearbyint, 4, 0)
  35         CALL_MCOUNT 0
  36         fabs    fp0,fp1
  37         lfd     fp13,.LC0@toc(2)
  38         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO52)  */
  39         bge     cr7,.L10
  40         fsub    fp12,fp13,fp13  /* generate 0.0 */
  41         fcmpu   cr7,fp1,fp12    /* if (x > 0.0) */
  42         ble     cr7, L(lessthanzero)
  43         mffs    fp11
  44         mtfsb0  4*cr7+lt        /* Disable FE_INEXACT exception */
  45         fadd    fp1,fp1,fp13    /* x+= TWO52 */
  46         fsub    fp1,fp1,fp13    /* x-= TWO52 */
  47         fabs    fp1,fp1         /* if (x == 0.0) */
  48         mtfsf   0xff,fp11       /* Restore FE_INEXACT state.  */
  49         blr                     /* x = 0.0; */
  50 L(lessthanzero):
  51         bgelr   cr7             /* if (x < 0.0) */
  52         mffs    fp11
  53         mtfsb0  4*cr7+lt
  54         fsub    fp1,fp1,fp13    /* x -= TWO52 */
  55         fadd    fp1,fp1,fp13    /* x += TWO52 */
  56         fnabs   fp1,fp1         /* if (x == 0.0) */
  57         mtfsf   0xff,fp11       /* Restore FE_INEXACT state.  */
  58         blr                     /* x = -0.0; */
  59 .L10:
  60         /* Ensure sNaN input is converted to qNaN.  */
  61         fcmpu   cr7,fp1,fp1
  62         beqlr   cr7
  63         fadd    fp1,fp1,fp1
  64         blr
  65 END (__nearbyint)
  66
  67 weak_alias (__nearbyint, nearbyint)
  68
  69 #ifdef NO_LONG_DOUBLE
  70 weak_alias (__nearbyint, nearbyint)
  71 strong_alias (__nearbyint, __nearbyintl)
  72 #endif
  73 #if LONG_DOUBLE_COMPAT(libm, GLIBC_2_1)
  74 compat_symbol (libm, __nearbyint, nearbyintl, GLIBC_2_1)
  75 #endif