configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Note we do not use AC_PREREQ here!  See aclocal.m4 for what we use instead.
   3 AC_INIT([GNU C Library], [(see version.h)], [https://sourceware.org/bugzilla/], [glibc])
   4 AC_CONFIG_SRCDIR([include/features.h])
   5 AC_CONFIG_HEADERS([config.h])
   6 AC_CONFIG_AUX_DIR([scripts])
   7
   8 ACX_PKGVERSION([GNU libc])
   9 ACX_BUGURL([http://www.gnu.org/software/libc/bugs.html])
  10 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"],
  11                    [Package description])
  12 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"],
  13                    [Bug reporting address])
  14
  15 # Glibc should not depend on any header files
  16 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
  17   [m4_divert_text([DEFAULTS],
  18     [ac_includes_default='/* none */'])])
  19
  20 # We require GCC, and by default use its preprocessor.  Override AC_PROG_CPP
  21 # here to work around the Autoconf issue discussed in
  22 # <https://sourceware.org/ml/libc-alpha/2013-01/msg00721.html>.
  23 AC_DEFUN([AC_PROG_CPP],
  24 [AC_REQUIRE([AC_PROG_CC])dnl
  25 AC_ARG_VAR([CPP],      [C preprocessor])dnl
  26 _AC_ARG_VAR_CPPFLAGS()dnl
  27 # On Suns, sometimes $CPP names a directory.
  28 if test -n "$CPP" && test -d "$CPP"; then
  29   CPP=
  30 fi
  31 if test -z "$CPP"; then
  32   CPP="$CC -E"
  33 fi
  34 AC_SUBST(CPP)dnl
  35 ])# AC_PROG_CPP
  36
  37 # We require GCC.  Override _AC_PROG_CC_C89 here to work around the Autoconf
  38 # issue discussed in
  39 # <https://sourceware.org/ml/libc-alpha/2013-01/msg00757.html>.
  40 AC_DEFUN([_AC_PROG_CC_C89], [[$1]])
  41
  42 dnl This is here so we can set $subdirs directly based on configure fragments.
  43 AC_CONFIG_SUBDIRS()
  44
  45 AC_CANONICAL_HOST
  46
  47 AC_PROG_CC
  48 if test $host != $build; then
  49   AC_CHECK_PROGS(BUILD_CC, gcc cc)
  50 fi
  51 AC_SUBST(cross_compiling)
  52 AC_PROG_CPP
  53 AC_CHECK_TOOL(READELF, readelf, false)
  54
  55 # We need the C++ compiler only for testing.
  56 AC_PROG_CXX
  57 # It's useless to us if it can't link programs (e.g. missing -lstdc++).
  58 AC_CACHE_CHECK([whether $CXX can link programs], libc_cv_cxx_link_ok, [dnl
  59 AC_LANG_PUSH([C++])
  60 # Default, dynamic case.
  61 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
  62                [libc_cv_cxx_link_ok=yes],
  63                [libc_cv_cxx_link_ok=no])
  64 # Static case.
  65 old_LDFLAGS="$LDFLAGS"
  66 LDFLAGS="$LDFLAGS -static"
  67 AC_LINK_IFELSE([AC_LANG_SOURCE([
  68 #include <iostream>
  69
  70 int
  71 main()
  72 {
  73   std::cout << "Hello, world!";
  74   return 0;
  75 }
  76 ])],
  77                [],
  78                [libc_cv_cxx_link_ok=no])
  79 LDFLAGS="$old_LDFLAGS"
  80 AC_LANG_POP([C++])])
  81 AS_IF([test $libc_cv_cxx_link_ok != yes], [CXX=])
  82
  83 if test "`cd $srcdir; pwd -P`" = "`pwd -P`"; then
  84   AC_MSG_ERROR([you must configure in a separate build directory])
  85 fi
  86
  87 # This will get text that should go into config.make.
  88 config_vars=
  89
  90 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
  91 AC_ARG_WITH([gd],
  92             AC_HELP_STRING([--with-gd=DIR],
  93                            [find libgd include dir and library with prefix DIR]),
  94             [dnl
  95 case "$with_gd" in
  96 yes|''|no) ;;
  97 *) libgd_include="-I$withval/include"
  98    libgd_ldflags="-L$withval/lib" ;;
  99 esac
 100 ])
 101 AC_ARG_WITH([gd-include],
 102             AC_HELP_STRING([--with-gd-include=DIR],
 103                            [find libgd include files in DIR]),
 104             [dnl
 105 case "$with_gd_include" in
 106 ''|no) ;;
 107 *) libgd_include="-I$withval" ;;
 108 esac
 109 ])
 110 AC_ARG_WITH([gd-lib],
 111             AC_HELP_STRING([--with-gd-lib=DIR],
 112                            [find libgd library files in DIR]),
 113             [dnl
 114 case "$with_gd_lib" in
 115 ''|no) ;;
 116 *) libgd_ldflags="-L$withval" ;;
 117 esac
 118 ])
 119
 120 if test -n "$libgd_include"; then
 121   config_vars="$config_vars
 122 CFLAGS-memusagestat.c = $libgd_include"
 123 fi
 124 if test -n "$libgd_ldflags"; then
 125   config_vars="$config_vars
 126 libgd-LDFLAGS = $libgd_ldflags"
 127 fi
 128
 129 dnl Arguments to specify presence of other packages/features.
 130 AC_ARG_WITH([fp],
 131             AC_HELP_STRING([--with-fp],
 132                            [if using floating-point hardware @<:@default=yes@:>@]),
 133             [with_fp=$withval],
 134             [with_fp=yes])
 135 AC_SUBST(with_fp)
 136 AC_ARG_WITH([binutils],
 137             AC_HELP_STRING([--with-binutils=PATH],
 138                            [specify location of binutils (as and ld)]),
 139             [path_binutils=$withval],
 140             [path_binutils=''])
 141 AC_ARG_WITH([selinux],
 142             AC_HELP_STRING([--with-selinux],
 143                            [if building with SELinux support]),
 144             [with_selinux=$withval],
 145             [with_selinux=auto])
 146
 147 AC_ARG_WITH([headers],
 148             AC_HELP_STRING([--with-headers=PATH],
 149                            [location of system headers to use
 150                             (for example /usr/src/linux/include)
 151                             @<:@default=compiler default@:>@]),
 152             [sysheaders=$withval],
 153             [sysheaders=''])
 154 AC_SUBST(sysheaders)
 155
 156 AC_SUBST(use_default_link)
 157 AC_ARG_WITH([default-link],
 158             AC_HELP_STRING([--with-default-link],
 159                            [do not use explicit linker scripts]),
 160             [use_default_link=$withval],
 161             [use_default_link=default])
 162
 163 AC_ARG_ENABLE([sanity-checks],
 164               AC_HELP_STRING([--disable-sanity-checks],
 165                              [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
 166               [enable_sanity=$enableval],
 167               [enable_sanity=yes])
 168
 169 AC_ARG_ENABLE([shared],
 170               AC_HELP_STRING([--enable-shared],
 171                              [build shared library @<:@default=yes if GNU ld@:>@]),
 172               [shared=$enableval],
 173               [shared=yes])
 174 AC_ARG_ENABLE([profile],
 175               AC_HELP_STRING([--enable-profile],
 176                              [build profiled library @<:@default=no@:>@]),
 177               [profile=$enableval],
 178               [profile=no])
 179 AC_ARG_ENABLE([timezone-tools],
 180               AC_HELP_STRING([--disable-timezone-tools],
 181                              [do not install timezone tools @<:@default=install@:>@]),
 182               [enable_timezone_tools=$enableval],
 183               [enable_timezone_tools=yes])
 184 AC_SUBST(enable_timezone_tools)
 185
 186 AC_ARG_ENABLE([hardcoded-path-in-tests],
 187               AC_HELP_STRING([--enable-hardcoded-path-in-tests],
 188                              [hardcode newly built glibc path in tests @<:@default=no@:>@]),
 189               [hardcoded_path_in_tests=$enableval],
 190               [hardcoded_path_in_tests=no])
 191 AC_SUBST(hardcoded_path_in_tests)
 192
 193 AC_ARG_ENABLE([stackguard-randomization],
 194               AC_HELP_STRING([--enable-stackguard-randomization],
 195                              [initialize __stack_chk_guard canary with a random number at program start]),
 196               [enable_stackguard_randomize=$enableval],
 197               [enable_stackguard_randomize=no])
 198 if test "$enable_stackguard_randomize" = yes; then
 199   AC_DEFINE(ENABLE_STACKGUARD_RANDOMIZE)
 200 fi
 201
 202 AC_ARG_ENABLE([hidden-plt],
 203               AC_HELP_STRING([--disable-hidden-plt],
 204                              [do not hide internal function calls to avoid PLT]),
 205               [hidden=$enableval],
 206               [hidden=yes])
 207 if test "x$hidden" = xno; then
 208   AC_DEFINE(NO_HIDDEN)
 209 fi
 210
 211 AC_ARG_ENABLE([bind-now],
 212               AC_HELP_STRING([--enable-bind-now],
 213                              [disable lazy relocations in DSOs]),
 214               [bindnow=$enableval],
 215               [bindnow=no])
 216 AC_SUBST(bindnow)
 217 if test "x$bindnow" = xyes; then
 218   AC_DEFINE(BIND_NOW)
 219 fi
 220
 221 dnl Build glibc with -fstack-protector, -fstack-protector-all, or
 222 dnl -fstack-protector-strong.
 223 AC_ARG_ENABLE([stack-protector],
 224               AC_HELP_STRING([--enable-stack-protector=@<:@yes|no|all|strong@:>@],
 225                              [Use -fstack-protector[-all|-strong] to detect glibc buffer overflows]),
 226               [enable_stack_protector=$enableval],
 227               [enable_stack_protector=no])
 228 case "$enable_stack_protector" in
 229 all|yes|no|strong) ;;
 230 *) AC_MSG_ERROR([Not a valid argument for --enable-stack-protector: \"$enable_stack_protector\"]);;
 231 esac
 232
 233 dnl On some platforms we cannot use dynamic loading.  We must provide
 234 dnl static NSS modules.
 235 AC_ARG_ENABLE([static-nss],
 236               AC_HELP_STRING([--enable-static-nss],
 237                              [build static NSS modules @<:@default=no@:>@]),
 238               [static_nss=$enableval],
 239               [static_nss=no])
 240 dnl Enable static NSS also if we build no shared objects.
 241 if test x"$static_nss" = xyes || test x"$shared" = xno; then
 242   static_nss=yes
 243   AC_DEFINE(DO_STATIC_NSS)
 244 fi
 245
 246 AC_ARG_ENABLE([force-install],
 247               AC_HELP_STRING([--disable-force-install],
 248                              [don't force installation of files from this package, even if they are older than the installed files]),
 249               [force_install=$enableval],
 250               [force_install=yes])
 251 AC_SUBST(force_install)
 252
 253 AC_ARG_ENABLE([maintainer-mode],
 254               AC_HELP_STRING([--enable-maintainer-mode],
 255                              [enable make rules and dependencies not useful (and sometimes confusing) to the casual installer]),
 256               [maintainer=$enableval],
 257               [maintainer=no])
 258
 259 dnl On some platforms we allow dropping compatibility with all kernel
 260 dnl versions.
 261 AC_ARG_ENABLE([kernel],
 262               AC_HELP_STRING([--enable-kernel=VERSION],
 263                              [compile for compatibility with kernel not older than VERSION]),
 264               [minimum_kernel=$enableval],
 265               [])
 266 dnl Prevent unreasonable values.
 267 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
 268   # Better nothing than this.
 269   minimum_kernel=""
 270 else
 271   if test "$minimum_kernel" = current; then
 272     minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
 273   fi
 274 fi
 275
 276 dnl For the development we sometimes want gcc to issue even more warnings.
 277 dnl This is not the default since many of the extra warnings are not
 278 dnl appropriate.
 279 AC_ARG_ENABLE([all-warnings],
 280               AC_HELP_STRING([--enable-all-warnings],
 281                              [enable all useful warnings gcc can issue]),
 282               [all_warnings=$enableval],
 283               [])
 284 AC_SUBST(all_warnings)
 285
 286 AC_ARG_ENABLE([werror],
 287               AC_HELP_STRING([--disable-werror],
 288                              [do not build with -Werror]),
 289               [enable_werror=$enableval],
 290               [enable_werror=yes])
 291 AC_SUBST(enable_werror)
 292
 293 AC_ARG_ENABLE([multi-arch],
 294               AC_HELP_STRING([--enable-multi-arch],
 295                              [enable single DSO with optimizations for multiple architectures]),
 296               [multi_arch=$enableval],
 297               [multi_arch=default])
 298
 299 AC_ARG_ENABLE([experimental-malloc],
 300               AC_HELP_STRING([--disable-experimental-malloc],
 301                              [disable experimental malloc features]),
 302               [experimental_malloc=$enableval],
 303               [experimental_malloc=yes])
 304 AC_SUBST(experimental_malloc)
 305
 306 AC_ARG_ENABLE([nss-crypt],
 307               AC_HELP_STRING([--enable-nss-crypt],
 308                              [enable libcrypt to use nss]),
 309               [nss_crypt=$enableval],
 310               [nss_crypt=no])
 311 if test x$nss_crypt = xyes; then
 312   nss_includes=-I$(nss-config --includedir 2>/dev/null)
 313   if test $? -ne 0; then
 314     AC_MSG_ERROR([cannot find include directory with nss-config])
 315   fi
 316   nspr_includes=-I$(nspr-config --includedir 2>/dev/null)
 317   if test $? -ne 0; then
 318     AC_MSG_ERROR([cannot find include directory with nspr-config])
 319   fi
 320   old_CFLAGS="$CFLAGS"
 321   CFLAGS="$CFLAGS $nss_includes $nspr_includes"
 322   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 323 #include <hasht.h>
 324 #include <nsslowhash.h>
 325 void f (void) { NSSLOW_Init (); }])],
 326              libc_cv_nss_crypt=yes,
 327              AC_MSG_ERROR([
 328 cannot find NSS headers with lowlevel hash function interfaces]))
 329   old_LIBS="$LIBS"
 330   old_LDFLAGS="$LDFLAGS"
 331   LIBS="$LIBS -lfreebl3"
 332   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 333 #include <hasht.h>
 334 #include <nsslowhash.h>],
 335                                   [NSSLOW_Init();])],
 336                  libc_cv_nss_crypt=yes,
 337                  AC_MSG_ERROR([
 338 cannot link program using lowlevel NSS hash functions]))
 339   # Check to see if there is a static NSS cryptographic library.
 340   # If there isn't then we can't link anything with libcrypt.a,
 341   # and that might mean disabling some static tests.
 342   LDFLAGS="$LDFLAGS -static"
 343   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 344 #include <hasht.h>
 345 #include <nsslowhash.h>],
 346                                   [NSSLOW_Init();])],
 347                  libc_cv_static_nss_crypt=yes,
 348                  libc_cv_static_nss_crypt=no)
 349   LDFLAGS="$old_LDFLAGS"
 350   CFLAGS="$old_CFLAGS"
 351   LIBS="$old_LIBS"
 352 else
 353   libc_cv_nss_crypt=no
 354   libc_cv_static_nss_crypt=no
 355 fi
 356 AC_SUBST(libc_cv_nss_crypt)
 357 AC_SUBST(libc_cv_static_nss_crypt)
 358
 359
 360 AC_ARG_ENABLE([obsolete-rpc],
 361               AC_HELP_STRING([--enable-obsolete-rpc],
 362                              [build and install the obsolete RPC code for link-time usage]),
 363               [link_obsolete_rpc=$enableval],
 364               [link_obsolete_rpc=no])
 365 AC_SUBST(link_obsolete_rpc)
 366
 367 if test "$link_obsolete_rpc" = yes; then
 368   AC_DEFINE(LINK_OBSOLETE_RPC)
 369 fi
 370
 371 AC_ARG_ENABLE([obsolete-nsl],
 372               AC_HELP_STRING([--enable-obsolete-nsl],
 373                              [build and install the obsolete libnsl library and depending NSS modules]),
 374               [build_obsolete_nsl=$enableval],
 375               [build_obsolete_nsl=no])
 376 AC_SUBST(build_obsolete_nsl)
 377
 378 if test "$build_obsolete_nsl" = yes; then
 379   AC_DEFINE(LINK_OBSOLETE_NSL)
 380 fi
 381
 382 AC_ARG_ENABLE([systemtap],
 383               [AS_HELP_STRING([--enable-systemtap],
 384                [enable systemtap static probe points @<:@default=no@:>@])],
 385               [systemtap=$enableval],
 386               [systemtap=no])
 387 if test "x$systemtap" != xno; then
 388   AC_CACHE_CHECK([for systemtap static probe support], libc_cv_sdt, [dnl
 389   old_CFLAGS="$CFLAGS"
 390   CFLAGS="-std=gnu11 $CFLAGS"
 391   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#include <sys/sdt.h>
 392 void foo (int i, void *p)
 393 {
 394   asm ("" STAP_PROBE_ASM (foo, bar, STAP_PROBE_ASM_TEMPLATE (2)) ""
 395        :: STAP_PROBE_ASM_OPERANDS (2, i, p));
 396 }]])], [libc_cv_sdt=yes], [libc_cv_sdt=no])
 397   CFLAGS="$old_CFLAGS"])
 398   if test $libc_cv_sdt = yes; then
 399     AC_DEFINE([USE_STAP_PROBE])
 400   elif test "x$systemtap" != xauto; then
 401     AC_MSG_FAILURE([systemtap support needs sys/sdt.h with asm support])
 402   fi
 403 fi
 404
 405 AC_ARG_ENABLE([build-nscd],
 406               [AS_HELP_STRING([--disable-build-nscd],
 407                [disable building and installing the nscd daemon])],
 408               [build_nscd=$enableval],
 409               [build_nscd=default])
 410 AC_SUBST(build_nscd)
 411
 412 # Note the use of $use_nscd is near the bottom of the file.
 413 AC_ARG_ENABLE([nscd],
 414               [AS_HELP_STRING([--disable-nscd],
 415                [library functions will not contact the nscd daemon])],
 416               [use_nscd=$enableval],
 417               [use_nscd=yes])
 418
 419 AC_ARG_ENABLE([pt_chown],
 420               [AS_HELP_STRING([--enable-pt_chown],
 421                [Enable building and installing pt_chown])],
 422               [build_pt_chown=$enableval],
 423               [build_pt_chown=no])
 424 AC_SUBST(build_pt_chown)
 425 if test "$build_pt_chown" = yes; then
 426   AC_DEFINE(HAVE_PT_CHOWN)
 427 fi
 428
 429 AC_ARG_ENABLE([tunables],
 430               [AS_HELP_STRING([--enable-tunables],
 431                [Enable tunables support. Known values are 'yes', 'no' and 'valstring'])],
 432               [have_tunables=$enableval],
 433               [have_tunables=yes])
 434 AC_SUBST(have_tunables)
 435 if test "$have_tunables" = yes; then
 436   AC_DEFINE(HAVE_TUNABLES)
 437 fi
 438
 439 # The abi-tags file uses a fairly simplistic model for name recognition that
 440 # can't distinguish i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a
 441 # $host_os of `gnu*' here to be `gnu-gnu*' just so that it can tell.
 442 # This doesn't get used much beyond that, so it's fairly safe.
 443 case "$host_os" in
 444 linux*)
 445   ;;
 446 gnu*)
 447   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 448   ;;
 449 esac
 450
 451 AC_ARG_ENABLE([mathvec],
 452               [AS_HELP_STRING([--enable-mathvec],
 453               [Enable building and installing mathvec @<:@default depends on architecture@:>@])],
 454               [build_mathvec=$enableval],
 455               [build_mathvec=notset])
 456
 457 # We keep the original values in `$config_*' and never modify them, so we
 458 # can write them unchanged into config.make.  Everything else uses
 459 # $machine, $vendor, and $os, and changes them whenever convenient.
 460 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 461
 462 # Don't allow vendor == "unknown"
 463 test "$config_vendor" = unknown && config_vendor=
 464 config_os="`echo $config_os | sed 's/^unknown-//'`"
 465
 466 # Some configurations imply other options.
 467 elf=yes
 468
 469 # The configure fragment of a port can modify these to supplement
 470 # or override the table in the case statement below.  No fragment should
 471 # ever change the config_* variables, however.
 472 machine=$config_machine
 473 vendor=$config_vendor
 474 os=$config_os
 475 base_os=''
 476
 477 submachine=
 478 AC_ARG_WITH([cpu],
 479             AS_HELP_STRING([--with-cpu=CPU], [select code for CPU variant]),
 480             [dnl
 481   case "$withval" in
 482   yes|'') AC_MSG_ERROR([--with-cpu requires an argument]) ;;
 483   no) ;;
 484   *) submachine="$withval" ;;
 485   esac
 486 ])
 487
 488 # An preconfigure script can set this when it wants to disable the sanity
 489 # check below.
 490 libc_config_ok=no
 491
 492 dnl Let sysdeps/*/preconfigure act here.
 493 LIBC_PRECONFIGURE([$srcdir], [for sysdeps])
 494
 495
 496 ###
 497 ### By using the undocumented --enable-hacker-mode option for configure
 498 ### one can skip this test to make the configuration not fail for unsupported
 499 ### platforms.
 500 ###
 501 if test -z "$enable_hacker_mode" && test x"$libc_config_ok" != xyes; then
 502   case "$machine-$host_os" in
 503   *-linux* | *-gnu*)
 504     ;;
 505   *)
 506     AC_MSG_ERROR([
 507 *** The GNU C library is currently unavailable for this platform.
 508 *** If you are interested in seeing glibc on this platform visit
 509 *** the "How to submit a new port" in the wiki:
 510 ***   https://sourceware.org/glibc/wiki/#Development
 511 *** and join the community!])
 512     ;;
 513   esac
 514 fi
 515
 516 # Set base_machine if not set by a preconfigure fragment.
 517 test -n "$base_machine" || base_machine=$machine
 518 AC_SUBST(base_machine)
 519
 520 AC_CACHE_CHECK(for -fstack-protector, libc_cv_ssp, [dnl
 521 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector],
 522                    [libc_cv_ssp=yes],
 523                    [libc_cv_ssp=no])
 524 ])
 525
 526 AC_CACHE_CHECK(for -fstack-protector-strong, libc_cv_ssp_strong, [dnl
 527 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector-strong],
 528                    [libc_cv_ssp_strong=yes],
 529                    [libc_cv_ssp_strong=no])
 530 ])
 531
 532 AC_CACHE_CHECK(for -fstack-protector-all, libc_cv_ssp_all, [dnl
 533 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector-all],
 534                    [libc_cv_ssp_all=yes],
 535                    [libc_cv_ssp_all=no])
 536 ])
 537
 538 stack_protector=
 539 no_stack_protector=
 540 if test "$libc_cv_ssp" = yes; then
 541   no_stack_protector="-fno-stack-protector -DSTACK_PROTECTOR_LEVEL=0"
 542   AC_DEFINE(HAVE_CC_NO_STACK_PROTECTOR)
 543 fi
 544
 545 if test "$enable_stack_protector" = yes && test "$libc_cv_ssp" = yes; then
 546   stack_protector="-fstack-protector"
 547   AC_DEFINE(STACK_PROTECTOR_LEVEL, 1)
 548 elif test "$enable_stack_protector" = all && test "$libc_cv_ssp_all" = yes; then
 549   stack_protector="-fstack-protector-all"
 550   AC_DEFINE(STACK_PROTECTOR_LEVEL, 2)
 551 elif test "$enable_stack_protector" = strong && test "$libc_cv_ssp_strong" = yes; then
 552   stack_protector="-fstack-protector-strong"
 553   AC_DEFINE(STACK_PROTECTOR_LEVEL, 3)
 554 else
 555   stack_protector="-fno-stack-protector"
 556   AC_DEFINE(STACK_PROTECTOR_LEVEL, 0)
 557 fi
 558 AC_SUBST(libc_cv_ssp)
 559 AC_SUBST(stack_protector)
 560 AC_SUBST(no_stack_protector)
 561
 562 if test -n "$stack_protector"; then
 563   dnl Don't run configure tests with stack-protection on, to avoid problems with
 564   dnl bootstrapping.
 565   no_ssp=-fno-stack-protector
 566 else
 567   no_ssp=
 568
 569   if test "$enable_stack_protector" != no; then
 570     AC_MSG_ERROR([--enable-stack-protector=$enable_stack_protector specified, but specified level of stack protection is not supported by the compiler.])
 571   fi
 572 fi
 573
 574 # For the multi-arch option we need support in the assembler & linker.
 575 AC_CACHE_CHECK([for assembler and linker STT_GNU_IFUNC support],
 576                libc_cv_ld_gnu_indirect_function, [dnl
 577 cat > conftest.S <<EOF
 578 .type foo,%gnu_indirect_function
 579 foo:
 580 .globl _start
 581 _start:
 582 .globl __start
 583 __start:
 584 .data
 585 #ifdef _LP64
 586 .quad foo
 587 #else
 588 .long foo
 589 #endif
 590 EOF
 591 libc_cv_ld_gnu_indirect_function=no
 592 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 593             -nostartfiles -nostdlib $no_ssp \
 594             -o conftest conftest.S 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
 595   # Do a link to see if the backend supports IFUNC relocs.
 596   $READELF -r conftest 1>&AS_MESSAGE_LOG_FD
 597   LC_ALL=C $READELF -r conftest | grep 'no relocations' >/dev/null || {
 598     libc_cv_ld_gnu_indirect_function=yes
 599   }
 600 fi
 601 rm -f conftest*])
 602
 603 # Check if gcc supports attribute ifunc as it is used in libc_ifunc macro.
 604 AC_CACHE_CHECK([for gcc attribute ifunc support],
 605                libc_cv_gcc_indirect_function, [dnl
 606 cat > conftest.c <<EOF
 607 extern int func (int);
 608 int used_func (int a)
 609 {
 610   return a;
 611 }
 612 static void *resolver ()
 613 {
 614   return &used_func;
 615 }
 616 extern __typeof (func) func __attribute__ ((ifunc ("resolver")));
 617 EOF
 618 libc_cv_gcc_indirect_function=no
 619 if ${CC-cc} -c conftest.c -o conftest.o 1>&AS_MESSAGE_LOG_FD \
 620    2>&AS_MESSAGE_LOG_FD ; then
 621   if $READELF -s conftest.o | grep IFUNC >/dev/null 2>&AS_MESSAGE_LOG_FD; then
 622     libc_cv_gcc_indirect_function=yes
 623   fi
 624 fi
 625 rm -f conftest*])
 626
 627 # Check if gcc warns about alias for function with incompatible types.
 628 AC_CACHE_CHECK([if compiler warns about alias for function with incompatible types],
 629                libc_cv_gcc_incompatible_alias, [dnl
 630 cat > conftest.c <<EOF
 631 int __redirect_foo (const void *s, int c);
 632
 633 __typeof (__redirect_foo) *foo_impl (void) __asm__ ("foo");
 634 __typeof (__redirect_foo) *foo_impl (void)
 635 {
 636   return 0;
 637 }
 638
 639 extern __typeof (__redirect_foo) foo_alias __attribute__ ((alias ("foo")));
 640 EOF
 641 libc_cv_gcc_incompatible_alias=yes
 642 if ${CC-cc} -Werror -c conftest.c -o conftest.o 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD ; then
 643   libc_cv_gcc_incompatible_alias=no
 644 fi
 645 rm -f conftest*])
 646
 647 if test x"$libc_cv_ld_gnu_indirect_function" != xyes; then
 648   if test x"$multi_arch" = xyes; then
 649     AC_MSG_ERROR([--enable-multi-arch support requires assembler and linker support])
 650   else
 651     multi_arch=no
 652   fi
 653 fi
 654 if test x"$libc_cv_gcc_indirect_function" != xyes; then
 655   # GCC 8+ emits a warning for alias with incompatible types and it might
 656   # fail to build ifunc resolvers aliases to either weak or internal
 657   # symbols.  Disables multiarch build in this case.
 658   if test x"$libc_cv_gcc_incompatible_alias" == xyes; then
 659     AC_MSG_WARN([gcc emits a warning for alias between functions of incompatible types])
 660     if test x"$multi_arch" = xyes; then
 661       AC_MSG_ERROR([--enable-multi-arch support requires a gcc with gnu-indirect-function support])
 662     fi
 663     AC_MSG_WARN([Multi-arch is disabled.])
 664     multi_arch=no
 665   elif test x"$multi_arch" = xyes; then
 666     AC_MSG_WARN([--enable-multi-arch support recommends a gcc with gnu-indirect-function support.
 667 Please use a gcc which supports it by default or configure gcc with --enable-gnu-indirect-function])
 668   fi
 669 fi
 670 multi_arch_d=
 671 if test x"$multi_arch" != xno; then
 672   multi_arch_d=/multiarch
 673 fi
 674
 675 # Compute the list of sysdep directories for this configuration.
 676 # This can take a while to compute.
 677 sysdep_dir=$srcdir/sysdeps
 678 AC_MSG_CHECKING(sysdep dirs)
 679 dnl We need to use [ and ] for other purposes for a while now.
 680 changequote(,)dnl
 681 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 682 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 683
 684 test "x$base_os" != x || case "$os" in
 685 gnu*)
 686   base_os=mach/hurd ;;
 687 linux*)
 688   base_os=unix/sysv ;;
 689 esac
 690
 691 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 692 tail=$os
 693 ostry=$os
 694 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 695   ostry="$ostry /$o"
 696   tail=$o
 697 done
 698 o=`echo $tail | sed 's/[0-9]*$//'`
 699 if test $o != $tail; then
 700   ostry="$ostry /$o"
 701 fi
 702 # For linux-gnu, try linux-gnu, then linux.
 703 o=`echo $tail | sed 's/-.*$//'`
 704 if test $o != $tail; then
 705   ostry="$ostry /$o"
 706 fi
 707
 708 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 709 base=
 710 tail=$base_os
 711 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 712   set $b
 713   base="$base /$1"
 714   tail="$2"
 715 done
 716
 717 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 718 mach=
 719 tail=$machine${submachine:+/$submachine}
 720 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 721   set $m
 722   # Prepend the machine's FPU directory unless --without-fp.
 723   if test "$with_fp" = yes; then
 724     maybe_fpu=/fpu
 725   else
 726     maybe_fpu=/nofpu
 727   fi
 728   # For each machine term, try it with and then without /multiarch.
 729   for try_fpu in $maybe_fpu ''; do
 730     for try_multi in $multi_arch_d ''; do
 731       mach="$mach /$1$try_fpu$try_multi"
 732     done
 733   done
 734   tail="$2"
 735 done
 736
 737 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 738 changequote([,])dnl
 739
 740 # Find what sysdep directories exist.
 741 sysnames=
 742 for b in $base ''; do
 743   for m0 in $mach ''; do
 744     for v in /$vendor ''; do
 745       test "$v" = / && continue
 746       for o in /$ostry ''; do
 747         test "$o" = / && continue
 748         for m in $mach ''; do
 749           try_suffix="$m0$b$v$o$m"
 750           if test -n "$try_suffix"; then
 751             try_srcdir="${srcdir}/"
 752             try="sysdeps$try_suffix"
 753             test -n "$enable_debug_configure" &&
 754             echo "$0 [DEBUG]: try $try" >&2
 755             if test -d "$try_srcdir$try"; then
 756               sysnames="$sysnames $try"
 757               { test -n "$o" || test -n "$b"; } && os_used=t
 758               { test -n "$m" || test -n "$m0"; } && machine_used=t
 759               case x${m0:-$m} in
 760               x*/$submachine) submachine_used=t ;;
 761               esac
 762             fi
 763           fi
 764         done
 765       done
 766     done
 767   done
 768 done
 769
 770 # If the assembler supports gnu_indirect_function symbol type and the
 771 # architecture supports multi-arch, we enable multi-arch by default.
 772 case $sysnames in
 773 *"$multi_arch_d"*)
 774   ;;
 775 *)
 776   test x"$multi_arch" = xdefault && multi_arch=no
 777   ;;
 778 esac
 779 if test x"$multi_arch" != xno; then
 780   AC_DEFINE(USE_MULTIARCH)
 781 fi
 782 AC_SUBST(multi_arch)
 783
 784 if test -z "$os_used" && test "$os" != none; then
 785   AC_MSG_ERROR(Operating system $os is not supported.)
 786 fi
 787 if test -z "$machine_used" && test "$machine" != none; then
 788   AC_MSG_ERROR(The $machine is not supported.)
 789 fi
 790 if test -z "$submachine_used" && test -n "$submachine"; then
 791   AC_MSG_ERROR(The $submachine subspecies of $host_cpu is not supported.)
 792 fi
 793 AC_SUBST(submachine)
 794
 795 # We have now validated the configuration.
 796
 797 # Expand the list of system names into a full list of directories
 798 # from each element's parent name and Implies file (if present).
 799 set $sysnames
 800 names=
 801 while test $# -gt 0; do
 802   name=$1
 803   shift
 804
 805   case " $names " in *" $name "*)
 806     # Already in the list.
 807     continue
 808   esac
 809
 810   # Report each name as we discover it, so there is no long pause in output.
 811   echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
 812
 813   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 814
 815   case $name in
 816     /*) xsrcdir= ;;
 817     *)  xsrcdir=$srcdir/ ;;
 818   esac
 819   test -n "$enable_debug_configure" &&
 820   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 821
 822   for implies_file in Implies Implies-before Implies-after; do
 823     implies_type=`echo $implies_file | sed s/-/_/`
 824     eval ${implies_type}=
 825     if test -f $xsrcdir$name/$implies_file; then
 826       # Collect more names from the `Implies' file (removing comments).
 827       implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/$implies_file`"
 828       for x in $implied_candidate; do
 829         found=no
 830         if test -d $xsrcdir$name_base/$x; then
 831           eval "${implies_type}=\"\$${implies_type} \$name_base/\$x\""
 832           found=yes
 833         fi
 834         try="sysdeps/$x"
 835         try_srcdir=$srcdir/
 836         test -n "$enable_debug_configure" &&
 837          echo "[DEBUG]: $name $implies_file $x try() {$try_srcdir}$try" >&2
 838         if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
 839         then
 840           eval "${implies_type}=\"\$${implies_type} \$try\""
 841           found=yes
 842         fi
 843         if test $found = no; then
 844           AC_MSG_WARN($name/$implies_file specifies nonexistent $x)
 845         fi
 846       done
 847     fi
 848   done
 849
 850   # Add NAME to the list of names.
 851   names="$names $name"
 852
 853   # Find the parent of NAME, using the empty string if it has none.
 854 changequote(,)dnl
 855   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 856 changequote([,])dnl
 857
 858   test -n "$enable_debug_configure" &&
 859     echo "[DEBUG]: $name Implies='$Implies' rest='$*' parent='$parent' \
 860 Implies_before='$Implies_before' Implies_after='$Implies_after'" >&2
 861
 862   # Add the names implied by NAME, and NAME's parent (if it has one), to
 863   # the list of names to be processed (the argument list).  We prepend the
 864   # implied names to the list and append the parent.  We want implied
 865   # directories to come before further directories inferred from the
 866   # configuration components; this ensures that for sysv4, unix/common
 867   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 868   # after sysv4).
 869   sysnames="`echo $Implies $* $Implies_before $parent $Implies_after`"
 870   test -n "$sysnames" && set $sysnames
 871 done
 872
 873 # Add the default directories.
 874 default_sysnames="sysdeps/generic"
 875 sysnames="$names $default_sysnames"
 876 AC_SUBST(sysnames)
 877 # The other names were emitted during the scan.
 878 AC_MSG_RESULT($default_sysnames)
 879
 880
 881 ### Locate tools.
 882
 883 AC_PROG_INSTALL
 884 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
 885   # The makefiles need to use a different form to find it in $srcdir.
 886   INSTALL='\$(..)./scripts/install-sh -c'
 887 fi
 888 AC_PROG_LN_S
 889
 890 LIBC_PROG_BINUTILS
 891
 892 # Accept binutils 2.25 or newer.
 893 AC_CHECK_PROG_VER(AS, $AS, --version,
 894                   [GNU assembler.* \([0-9]*\.[0-9.]*\)],
 895                   [2.1[0-9][0-9]*|2.2[5-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
 896                   AS=: critic_missing="$critic_missing as")
 897
 898 if test -n "`$LD --version | sed -n 's/^GNU \(gold\).*$/\1/p'`"; then
 899   # Accept gold 1.14 or higher
 900   AC_CHECK_PROG_VER(LD, $LD, --version,
 901                     [GNU gold.* \([0-9][0-9]*\.[0-9.]*\)],
 902                     [1.1[4-9]*|1.[2-9][0-9]*|1.1[0-9][0-9]*|[2-9].*|[1-9][0-9]*],
 903                     LD=: critic_missing="$critic_missing GNU gold")
 904 else
 905   AC_CHECK_PROG_VER(LD, $LD, --version,
 906                     [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
 907                     [2.1[0-9][0-9]*|2.2[5-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
 908                     LD=: critic_missing="$critic_missing GNU ld")
 909 fi
 910
 911 # These programs are version sensitive.
 912 AC_CHECK_TOOL_PREFIX
 913 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
 914   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
 915   [3.79* | 3.[89]* | [4-9].* | [1-9][0-9]*], critic_missing="$critic_missing make")
 916
 917 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
 918   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
 919   [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
 920   MSGFMT=: aux_missing="$aux_missing msgfmt")
 921 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 922   [GNU texinfo.* \([0-9][0-9.]*\)],
 923   [4.[7-9]*|4.[1-9][0-9]*|[5-9].*],
 924   MAKEINFO=: aux_missing="$aux_missing makeinfo")
 925 AC_CHECK_PROG_VER(SED, sed, --version,
 926   [GNU sed[^0-9]* \([0-9]*\.[0-9.]*\)],
 927   [3.0[2-9]*|3.[1-9]*|[4-9]*],
 928   SED=: aux_missing="$aux_missing sed")
 929 AC_CHECK_PROG_VER(AWK, gawk, --version,
 930   [GNU Awk[^0-9]*\([0-9][0-9.]*\)],
 931   [3.1.[2-9]*|3.[2-9]*|[4-9]*], critic_missing="$critic_missing gawk")
 932 AC_CHECK_PROG_VER(BISON, bison, --version,
 933   [bison (GNU Bison) \([0-9]*\.[0-9.]*\)],
 934   [2.7*|[3-9].*|[1-9][0-9]*], critic_missing="$critic_missing bison")
 935
 936 AC_CACHE_CHECK([if $CC is sufficient to build libc], libc_cv_compiler_ok, [
 937 AC_TRY_COMPILE([], [
 938 #if !defined __GNUC__ || __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 9)
 939 #error insufficient compiler
 940 #endif],
 941                [libc_cv_compiler_ok=yes],
 942                [libc_cv_compiler_ok=no])])
 943 AS_IF([test $libc_cv_compiler_ok != yes],
 944       [critic_missing="$critic_missing compiler"])
 945
 946 AC_CHECK_TOOL(NM, nm, false)
 947
 948 if test "x$maintainer" = "xyes"; then
 949   AC_CHECK_PROGS(AUTOCONF, autoconf, no)
 950   case "x$AUTOCONF" in
 951   xno|x|x:) AUTOCONF=no ;;
 952   *)
 953     AC_CACHE_CHECK(dnl
 954   whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
 955     if (cd $srcdir; $AUTOCONF $ACFLAGS configure.ac > /dev/null 2>&1); then
 956       libc_cv_autoconf_works=yes
 957     else
 958       libc_cv_autoconf_works=no
 959     fi])
 960     test $libc_cv_autoconf_works = yes || AUTOCONF=no
 961     ;;
 962   esac
 963   if test "x$AUTOCONF" = xno; then
 964     aux_missing="$aux_missing autoconf"
 965   fi
 966 else
 967   AUTOCONF=no
 968 fi
 969
 970 # Check for python3 if available, or else python.
 971 AC_CHECK_PROGS(PYTHON_PROG, python3 python,no)
 972 case "x$PYTHON_PROG" in
 973 xno|x|x:) PYTHON_PROG=no ;;
 974 *) ;;
 975 esac
 976
 977 if test "x$PYTHON_PROG" = xno; then
 978   aux_missing="$aux_missing python"
 979 else
 980   PYTHON="$PYTHON_PROG -B"
 981   AC_SUBST(PYTHON)
 982 fi
 983
 984 test -n "$critic_missing" && AC_MSG_ERROR([
 985 *** These critical programs are missing or too old:$critic_missing
 986 *** Check the INSTALL file for required versions.])
 987
 988 test -n "$aux_missing" && AC_MSG_WARN([
 989 *** These auxiliary programs are missing or incompatible versions:$aux_missing
 990 *** some features or tests will be disabled.
 991 *** Check the INSTALL file for required versions.])
 992
 993 # if using special system headers, find out the compiler's sekrit
 994 # header directory and add that to the list.  NOTE: Only does the right
 995 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
 996 if test -n "$sysheaders"; then
 997   SYSINCLUDES=-nostdinc
 998   for d in include include-fixed; do
 999     i=`$CC -print-file-name="$d"` && test "x$i" != x && test "x$i" != "x$d" &&
1000     SYSINCLUDES="$SYSINCLUDES -isystem $i"
1001   done
1002   SYSINCLUDES="$SYSINCLUDES \
1003 -isystem `echo $sysheaders | sed 's/:/ -isystem /g'`"
1004   if test -n "$CXX"; then
1005     CXX_SYSINCLUDES=
1006     for cxxheaders in `$CXX -v -S -x c++ /dev/null -o /dev/null 2>&1 \
1007     | sed -n -e '1,/#include/d' -e 's/^ \(\/.*\/[cg]++\)/\1/p'`; do
1008       test "x$cxxheaders" != x &&
1009       CXX_SYSINCLUDES="$CXX_SYSINCLUDES -isystem $cxxheaders"
1010     done
1011   fi
1012 fi
1013 AC_SUBST(SYSINCLUDES)
1014 AC_SUBST(CXX_SYSINCLUDES)
1015
1016 # Obtain some C++ header file paths.  This is used to make a local
1017 # copy of those headers in Makerules.
1018 if test -n "$CXX"; then
1019   find_cxx_header () {
1020     echo "#include <$1>" | $CXX -M -MP -x c++ - 2>/dev/null \
1021          | sed -n "\,$1:,{s/:\$//;p}"
1022   }
1023   CXX_CSTDLIB_HEADER="$(find_cxx_header cstdlib)"
1024   CXX_CMATH_HEADER="$(find_cxx_header cmath)"
1025   CXX_BITS_STD_ABS_H="$(find_cxx_header bits/std_abs.h)"
1026 fi
1027 AC_SUBST(CXX_CSTDLIB_HEADER)
1028 AC_SUBST(CXX_CMATH_HEADER)
1029 AC_SUBST(CXX_BITS_STD_ABS_H)
1030
1031 # Test if LD_LIBRARY_PATH contains the notation for the current directory
1032 # since this would lead to problems installing/building glibc.
1033 # LD_LIBRARY_PATH contains the current directory if one of the following
1034 # is true:
1035 # - one of the terminals (":" and ";") is the first or last sign
1036 # - two terminals occur directly after each other
1037 # - the path contains an element with a dot in it
1038 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
1039 changequote(,)dnl
1040 case ${LD_LIBRARY_PATH} in
1041   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
1042     ld_library_path_setting="contains current directory"
1043     ;;
1044   *)
1045     ld_library_path_setting="ok"
1046     ;;
1047 esac
1048 changequote([,])dnl
1049 AC_MSG_RESULT($ld_library_path_setting)
1050 if test "$ld_library_path_setting" != "ok"; then
1051 AC_MSG_ERROR([
1052 *** LD_LIBRARY_PATH shouldn't contain the current directory when
1053 *** building glibc. Please change the environment variable
1054 *** and run configure again.])
1055 fi
1056
1057 AC_PATH_PROG(BASH_SHELL, bash, no)
1058
1059 AC_PATH_PROG(PERL, perl, no)
1060 if test "$PERL" != no &&
1061    (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
1062   PERL=no
1063 fi
1064 AC_PATH_PROG(INSTALL_INFO, install-info, no,
1065              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
1066
1067 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
1068 cat > conftest.s <<EOF
1069 .text
1070 foo:
1071 .set glibc_conftest_frobozz,foo
1072 .globl glibc_conftest_frobozz
1073 EOF
1074 # The alpha-dec-osf1 assembler gives only a warning for `.set'
1075 # (but it doesn't work), so we must do a linking check to be sure.
1076 cat > conftest1.c <<\EOF
1077 extern int glibc_conftest_frobozz;
1078 void _start() { glibc_conftest_frobozz = 1; }
1079 EOF
1080 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1081             -nostartfiles -nostdlib $no_ssp \
1082             -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1083   libc_cv_asm_set_directive=yes
1084 else
1085   libc_cv_asm_set_directive=no
1086 fi
1087 rm -f conftest*])
1088 if test $libc_cv_asm_set_directive = yes; then
1089   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
1090 fi
1091
1092 AC_CACHE_CHECK(linker support for protected data symbol,
1093                libc_cv_protected_data,
1094                [cat > conftest.c <<EOF
1095                 int bar __attribute__ ((visibility ("protected"))) = 1;
1096 EOF
1097                 libc_cv_protected_data=no
1098                 if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles $no_ssp -fPIC -shared conftest.c -o conftest.so); then
1099                   cat > conftest.c <<EOF
1100                   extern int bar;
1101                   int main (void) { return bar; }
1102 EOF
1103                   if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles $no_ssp conftest.c -o conftest conftest.so); then
1104                     libc_cv_protected_data=yes
1105                   fi
1106                 fi
1107                 rm -f conftest.*
1108                ])
1109 AC_SUBST(libc_cv_protected_data)
1110
1111 AC_CACHE_CHECK(linker support for INSERT in linker script,
1112                libc_cv_insert,
1113                [cat > conftest.c <<EOF
1114                 const int __attribute__ ((section(".bar"))) bar = 0x12345678;
1115                 int test (void) { return bar; }
1116 EOF
1117                 cat > conftest.t <<EOF
1118                 SECTIONS
1119                 {
1120                   .bar : { *(.bar) }
1121                 }
1122                 INSERT AFTER .rela.dyn;
1123 EOF
1124                 libc_cv_insert=no
1125                 if AC_TRY_COMMAND([${CC-cc} -nostdlib -nostartfiles $no_ssp -fPIC -shared conftest.c -Wl,-T,conftest.t -o conftest.so]); then
1126                   libc_cv_insert=yes
1127                 fi
1128                 rm -f conftest.*
1129                ])
1130 AC_SUBST(libc_cv_insert)
1131
1132 AC_CACHE_CHECK(for broken __attribute__((alias())),
1133                libc_cv_broken_alias_attribute,
1134                [cat > conftest.c <<EOF
1135                extern int foo (int x) __asm ("xyzzy");
1136                int bar (int x) { return x; }
1137                extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1138                extern int dfoo;
1139                extern __typeof (dfoo) dfoo __asm ("abccb");
1140                int dfoo = 1;
1141 EOF
1142                libc_cv_broken_alias_attribute=yes
1143                if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1144                  if grep 'xyzzy' conftest.s >/dev/null &&
1145                     grep 'abccb' conftest.s >/dev/null; then
1146                    libc_cv_broken_alias_attribute=no
1147                  fi
1148                fi
1149                rm -f conftest.c conftest.s
1150                ])
1151 if test $libc_cv_broken_alias_attribute = yes; then
1152   AC_MSG_ERROR(working alias attribute support required)
1153 fi
1154
1155 AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1156                libc_cv_have_sdata_section,
1157                [echo "int i;" > conftest.c
1158                 libc_cv_have_sdata_section=no
1159                 if ${CC-cc} $LDFLAGS -fPIC -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1160                    | grep '\.sdata' >/dev/null; then
1161                   libc_cv_have_sdata_section=yes
1162                 fi
1163                 rm -f conftest.c conftest.so
1164                ])
1165 if test $libc_cv_have_sdata_section = yes; then
1166   AC_DEFINE(HAVE_SDATA_SECTION)
1167 fi
1168
1169 AC_CACHE_CHECK(whether to use .ctors/.dtors header and trailer,
1170                libc_cv_ctors_header, [dnl
1171   libc_cv_ctors_header=yes
1172   LIBC_TRY_LINK_STATIC([
1173 __attribute__ ((constructor)) void ctor (void) { asm (""); }
1174 __attribute__ ((destructor))  void dtor (void) { asm (""); }
1175 ],
1176               [dnl
1177       AS_IF([$READELF -WS conftest$ac_exeext | $AWK '
1178         { gsub(/\@<:@ */, "@<:@") }
1179         $2 == ".ctors" || $2 == ".dtors" {
1180           size = strtonum("0x" $6)
1181           align = strtonum("0x" $NF)
1182           seen@<:@$2@:>@ = 1
1183           stub@<:@$2@:>@ = size == align * 2
1184         }
1185         END {
1186           ctors_ok = !seen@<:@".ctors"@:>@ || stub@<:@".ctors"@:>@
1187           dtors_ok = !seen@<:@".dtors"@:>@ || stub@<:@".dtors"@:>@
1188           exit ((ctors_ok && dtors_ok) ? 0 : 1)
1189         }
1190       '], [libc_cv_ctors_header=no])
1191     ], [dnl
1192       AC_MSG_ERROR([missing __attribute__ ((constructor)) support??])
1193     ])
1194 ])
1195 if test $libc_cv_ctors_header = no; then
1196   AC_DEFINE(NO_CTORS_DTORS_SECTIONS)
1197 fi
1198
1199 AC_CACHE_CHECK(for libunwind-support in compiler,
1200                libc_cv_cc_with_libunwind, [
1201   cat > conftest.c <<EOF
1202 int main (void) { return 0; }
1203 EOF
1204   if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static -o conftest \
1205      conftest.c -v 2>&1 >/dev/null | grep ' -lunwind ' >/dev/null; then
1206     libc_cv_cc_with_libunwind=yes
1207   else
1208     libc_cv_cc_with_libunwind=no
1209   fi
1210   rm -f conftest*])
1211 AC_SUBST(libc_cv_cc_with_libunwind)
1212 if test $libc_cv_cc_with_libunwind = yes; then
1213   AC_DEFINE(HAVE_CC_WITH_LIBUNWIND)
1214 fi
1215
1216 ASFLAGS_config=
1217 AC_CACHE_CHECK(whether --noexecstack is desirable for .S files,
1218                libc_cv_as_noexecstack, [dnl
1219 cat > conftest.c <<EOF
1220 void foo (void) { }
1221 EOF
1222 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS
1223                    -S -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD]) \
1224    && grep .note.GNU-stack conftest.s >/dev/null \
1225    && AC_TRY_COMMAND([${CC-cc} $ASFLAGS -Wa,--noexecstack
1226                       -c -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
1227 then
1228   libc_cv_as_noexecstack=yes
1229 else
1230   libc_cv_as_noexecstack=no
1231 fi
1232 rm -f conftest*])
1233 if test $libc_cv_as_noexecstack = yes; then
1234   ASFLAGS_config="$ASFLAGS_config -Wa,--noexecstack"
1235 fi
1236 AC_SUBST(ASFLAGS_config)
1237
1238 AC_CACHE_CHECK(for -z combreloc,
1239                libc_cv_z_combreloc, [dnl
1240 cat > conftest.c <<EOF
1241 extern int bar (int);
1242 extern int mumble;
1243 int foo (void) { return bar (mumble); }
1244 EOF
1245 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1246                         -fPIC -shared $no_ssp -o conftest.so conftest.c
1247                         -nostdlib -nostartfiles
1248                         -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1249 then
1250 dnl The following test is a bit weak.  We must use a tool which can test
1251 dnl cross-platform since the gcc used can be a cross compiler.  Without
1252 dnl introducing new options this is not easily doable.  Instead use a tool
1253 dnl which always is cross-platform: readelf.  To detect whether -z combreloc
1254 dnl look for a section named .rel.dyn or .rela.dyn.
1255   if $READELF -S conftest.so | grep -E '.rela?.dyn' > /dev/null; then
1256     libc_cv_z_combreloc=yes
1257   else
1258     libc_cv_z_combreloc=no
1259   fi
1260 else
1261   libc_cv_z_combreloc=no
1262 fi
1263 rm -f conftest*])
1264 if test "$libc_cv_z_combreloc" = yes; then
1265   AC_DEFINE(HAVE_Z_COMBRELOC)
1266 fi
1267 AC_SUBST(libc_cv_z_combreloc)
1268
1269 LIBC_LINKER_FEATURE([-z execstack], [-Wl,-z,execstack],
1270                     [libc_cv_z_execstack=yes], [libc_cv_z_execstack=no])
1271 AC_SUBST(libc_cv_z_execstack)
1272
1273 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
1274 LIBC_TRY_CC_OPTION([-fpie], [libc_cv_fpie=yes], [libc_cv_fpie=no])
1275 ])
1276
1277 AC_SUBST(libc_cv_fpie)
1278
1279 AC_CACHE_CHECK(for --hash-style option,
1280                libc_cv_hashstyle, [dnl
1281 cat > conftest.c <<EOF
1282 int _start (void) { return 42; }
1283 EOF
1284 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS $no_ssp
1285                             -fPIC -shared -o conftest.so conftest.c
1286                             -Wl,--hash-style=both -nostdlib 1>&AS_MESSAGE_LOG_FD])
1287 then
1288   libc_cv_hashstyle=yes
1289 else
1290   libc_cv_hashstyle=no
1291 fi
1292 rm -f conftest*])
1293 AC_SUBST(libc_cv_hashstyle)
1294
1295 # The linker's default -shared behavior is good enough if it
1296 # does these things that our custom linker scripts ensure that
1297 # all allocated NOTE sections come first.
1298 if test "$use_default_link" = default; then
1299   AC_CACHE_CHECK([for sufficient default -shared layout],
1300                   libc_cv_use_default_link, [dnl
1301   libc_cv_use_default_link=no
1302   cat > conftest.s <<\EOF
1303           .section .note.a,"a",%note
1304           .balign 4
1305           .long 4,4,9
1306           .string "GNU"
1307           .string "foo"
1308           .section .note.b,"a",%note
1309           .balign 4
1310           .long 4,4,9
1311           .string "GNU"
1312           .string "bar"
1313 EOF
1314   if AC_TRY_COMMAND([dnl
1315   ${CC-cc} $ASFLAGS -shared -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD]) &&
1316        ac_try=`$READELF -S conftest.so | sed -n \
1317          ['${x;p;}
1318           s/^ *\[ *[1-9][0-9]*\]  *\([^ ][^ ]*\)  *\([^ ][^ ]*\) .*$/\2 \1/
1319           t a
1320           b
1321           : a
1322           H']`
1323   then
1324     libc_seen_a=no libc_seen_b=no
1325     set -- $ac_try
1326     while test $# -ge 2 -a "$1" = NOTE; do
1327       case "$2" in
1328       .note.a) libc_seen_a=yes ;;
1329       .note.b) libc_seen_b=yes ;;
1330       esac
1331       shift 2
1332     done
1333     case "$libc_seen_a$libc_seen_b" in
1334     yesyes)
1335       libc_cv_use_default_link=yes
1336       ;;
1337     *)
1338       echo >&AS_MESSAGE_LOG_FD "\
1339 $libc_seen_a$libc_seen_b from:
1340 $ac_try"
1341       ;;
1342     esac
1343   fi
1344   rm -f conftest*])
1345   use_default_link=$libc_cv_use_default_link
1346 fi
1347
1348 AC_CACHE_CHECK(for GLOB_DAT reloc,
1349                libc_cv_has_glob_dat, [dnl
1350 cat > conftest.c <<EOF
1351 extern int mumble;
1352 int foo (void) { return mumble; }
1353 EOF
1354 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1355                         -fPIC -shared -o conftest.so conftest.c
1356                         -nostdlib -nostartfiles $no_ssp
1357                         1>&AS_MESSAGE_LOG_FD])
1358 then
1359 dnl look for GLOB_DAT relocation.
1360   if $READELF -rW conftest.so | grep '_GLOB_DAT' > /dev/null; then
1361     libc_cv_has_glob_dat=yes
1362   else
1363     libc_cv_has_glob_dat=no
1364   fi
1365 else
1366   libc_cv_has_glob_dat=no
1367 fi
1368 rm -f conftest*])
1369 AC_SUBST(libc_cv_has_glob_dat)
1370
1371 AC_CACHE_CHECK(linker output format, libc_cv_output_format, [dnl
1372 if libc_cv_output_format=`
1373 ${CC-cc} -nostartfiles -nostdlib $no_ssp -Wl,--print-output-format 2>&AS_MESSAGE_LOG_FD`
1374 then
1375   :
1376 else
1377   libc_cv_output_format=
1378 fi
1379 test -n "$libc_cv_output_format" || libc_cv_output_format=unknown])
1380 AC_SUBST(libc_cv_output_format)
1381
1382 AC_CACHE_CHECK(for -fno-toplevel-reorder -fno-section-anchors, libc_cv_fno_toplevel_reorder, [dnl
1383 cat > conftest.c <<EOF
1384 int foo;
1385 EOF
1386 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fno-toplevel-reorder -fno-section-anchors
1387                             conftest.c 1>&AS_MESSAGE_LOG_FD])
1388 then
1389   libc_cv_fno_toplevel_reorder=yes
1390 else
1391   libc_cv_fno_toplevel_reorder=no
1392 fi
1393 rm -f conftest*])
1394 if test $libc_cv_fno_toplevel_reorder = yes; then
1395   fno_unit_at_a_time="-fno-toplevel-reorder -fno-section-anchors"
1396 else
1397   fno_unit_at_a_time=-fno-unit-at-a-time
1398 fi
1399 AC_SUBST(fno_unit_at_a_time)
1400
1401 AC_CACHE_CHECK([for -mtls-dialect=gnu2], libc_cv_mtls_dialect_gnu2,
1402 [dnl
1403 cat > conftest.c <<EOF
1404 __thread int i;
1405 void foo (void)
1406 {
1407   i = 10;
1408 }
1409 EOF
1410 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fPIC -mtls-dialect=gnu2
1411                    conftest.c 1>&AS_MESSAGE_LOG_FD])
1412 then
1413   libc_cv_mtls_dialect_gnu2=yes
1414 else
1415   libc_cv_mtls_dialect_gnu2=no
1416 fi
1417 rm -f conftest*])
1418 AC_SUBST(libc_cv_mtls_dialect_gnu2)
1419 LIBC_CONFIG_VAR([have-mtls-dialect-gnu2], [$libc_cv_mtls_dialect_gnu2])
1420
1421 AC_CACHE_CHECK(whether cc puts quotes around section names,
1422                libc_cv_have_section_quotes,
1423                [cat > conftest.c <<EOF
1424                 static const int foo
1425                 __attribute__ ((section ("bar"))) = 1;
1426 EOF
1427                 if ${CC-cc} -S conftest.c -o conftest.s; then
1428                   if grep '\.section.*"bar"' conftest.s >/dev/null; then
1429                     libc_cv_have_section_quotes=yes
1430                   else
1431                     libc_cv_have_section_quotes=no
1432                   fi
1433                 else
1434                   libc_cv_have_section_quotes=unknown
1435                 fi
1436                 rm -f conftest.{c,s}
1437                 ])
1438 if test $libc_cv_have_section_quotes = yes; then
1439   AC_DEFINE(HAVE_SECTION_QUOTES)
1440 fi
1441
1442 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
1443 cat > conftest.c <<\EOF
1444 void zero (void *x)
1445 {
1446   __builtin_memset (x, 0, 1000);
1447 }
1448 EOF
1449 dnl
1450 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | grep -F "memset" > /dev/null]);
1451 then
1452   libc_cv_gcc_builtin_memset=no
1453 else
1454   libc_cv_gcc_builtin_memset=yes
1455 fi
1456 rm -f conftest* ])
1457 if test "$libc_cv_gcc_builtin_memset" = yes ; then
1458   AC_DEFINE(HAVE_BUILTIN_MEMSET)
1459 fi
1460
1461 AC_CACHE_CHECK(for redirection of built-in functions, libc_cv_gcc_builtin_redirection, [dnl
1462 cat > conftest.c <<\EOF
1463 extern char *strstr (const char *, const char *) __asm ("my_strstr");
1464 char *foo (const char *a, const char *b)
1465 {
1466   return __builtin_strstr (a, b);
1467 }
1468 EOF
1469 dnl
1470 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | grep -F "my_strstr" > /dev/null]);
1471 then
1472   libc_cv_gcc_builtin_redirection=yes
1473 else
1474   libc_cv_gcc_builtin_redirection=no
1475 fi
1476 rm -f conftest* ])
1477 if test "$libc_cv_gcc_builtin_redirection" = no; then
1478   AC_MSG_ERROR([support for the symbol redirection needed])
1479 fi
1480
1481 dnl Determine how to disable generation of FMA instructions.
1482 AC_CACHE_CHECK([for compiler option to disable generation of FMA instructions],
1483                libc_cv_cc_nofma, [dnl
1484 libc_cv_cc_nofma=
1485 for opt in -ffp-contract=off -mno-fused-madd; do
1486   LIBC_TRY_CC_OPTION([$opt], [libc_cv_cc_nofma=$opt; break])
1487 done])
1488 AC_SUBST(libc_cv_cc_nofma)
1489
1490 if test -n "$submachine"; then
1491   AC_CACHE_CHECK([for compiler option for CPU variant],
1492                  libc_cv_cc_submachine, [dnl
1493   libc_cv_cc_submachine=no
1494   for opt in "-march=$submachine" "-mcpu=$submachine"; do
1495     LIBC_TRY_CC_OPTION([$opt], [
1496       libc_cv_cc_submachine="$opt"
1497       break], [])
1498   done])
1499   if test "x$libc_cv_cc_submachine" = xno; then
1500     AC_MSG_ERROR([${CC-cc} does not support $submachine])
1501   fi
1502 fi
1503 AC_SUBST(libc_cv_cc_submachine)
1504
1505 AC_CACHE_CHECK(if $CC accepts -fno-tree-loop-distribute-patterns with \
1506 __attribute__ ((__optimize__)), libc_cv_cc_loop_to_function, [dnl
1507 cat > conftest.c <<EOF
1508 void
1509 __attribute__ ((__optimize__ ("-fno-tree-loop-distribute-patterns")))
1510 foo (void) {}
1511 EOF
1512 libc_cv_cc_loop_to_function=no
1513 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c])
1514 then
1515   libc_cv_cc_loop_to_function=yes
1516 fi
1517 rm -f conftest*])
1518 if test $libc_cv_cc_loop_to_function = yes; then
1519   AC_DEFINE(HAVE_CC_INHIBIT_LOOP_TO_LIBCALL)
1520 fi
1521 AC_SUBST(libc_cv_cc_loop_to_function)
1522
1523 dnl Check whether we have the gd library available.
1524 AC_MSG_CHECKING(for libgd)
1525 if test "$with_gd" != "no"; then
1526   old_CFLAGS="$CFLAGS"
1527   CFLAGS="$CFLAGS $libgd_include"
1528   old_LDFLAGS="$LDFLAGS"
1529   LDFLAGS="$LDFLAGS $libgd_ldflags"
1530   old_LIBS="$LIBS"
1531   LIBS="$LIBS -lgd -lpng -lz -lm"
1532   AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1533   CFLAGS="$old_CFLAGS"
1534   LDFLAGS="$old_LDFLAGS"
1535   LIBS="$old_LIBS"
1536 else
1537   LIBGD=no
1538 fi
1539 AC_MSG_RESULT($LIBGD)
1540 AC_SUBST(LIBGD)
1541
1542 # SELinux detection
1543 if test x$with_selinux = xno ; then
1544   have_selinux=no;
1545 else
1546   # See if we have the SELinux library
1547   AC_CHECK_LIB(selinux, is_selinux_enabled,
1548                have_selinux=yes, have_selinux=no)
1549   if test x$with_selinux = xyes ; then
1550     if test x$have_selinux = xno ; then
1551       AC_MSG_ERROR([SELinux explicitly required, but SELinux library not found])
1552     fi
1553   fi
1554 fi
1555 # Check if we're building with SELinux support.
1556 if test "x$have_selinux" = xyes; then
1557   AC_DEFINE(HAVE_SELINUX, 1, [SELinux support])
1558
1559   # See if we have the libaudit library
1560   AC_CHECK_LIB(audit, audit_log_user_avc_message,
1561                have_libaudit=yes, have_libaudit=no)
1562   if test "x$have_libaudit" = xyes; then
1563     AC_DEFINE(HAVE_LIBAUDIT, 1, [SELinux libaudit support])
1564   fi
1565   AC_SUBST(have_libaudit)
1566
1567   # See if we have the libcap library
1568   AC_CHECK_LIB(cap, cap_init, have_libcap=yes, have_libcap=no)
1569   if test "x$have_libcap" = xyes; then
1570     AC_DEFINE(HAVE_LIBCAP, 1, [SELinux libcap support])
1571   fi
1572   AC_SUBST(have_libcap)
1573 fi
1574 AC_SUBST(have_selinux)
1575
1576 CPPUNDEFS=
1577 dnl Check for silly hacked compilers predefining _FORTIFY_SOURCE.
1578 dnl Since we are building the implementations of the fortified functions here,
1579 dnl having the macro defined interacts very badly.
1580 AC_CACHE_CHECK([for _FORTIFY_SOURCE predefine], libc_cv_predef_fortify_source,
1581 [AC_TRY_COMPILE([], [
1582 #ifdef _FORTIFY_SOURCE
1583 # error bogon
1584 #endif],
1585                 [libc_cv_predef_fortify_source=no],
1586                 [libc_cv_predef_fortify_source=yes])])
1587 if test $libc_cv_predef_fortify_source = yes; then
1588   CPPUNDEFS="${CPPUNDEFS:+$CPPUNDEFS }-U_FORTIFY_SOURCE"
1589 fi
1590 AC_SUBST(CPPUNDEFS)
1591
1592 # Some linkers on some architectures support __ehdr_start but with
1593 # bugs.  Make sure usage of it does not create relocations in the
1594 # output (as the linker should resolve them all for us).
1595 AC_CACHE_CHECK([whether the linker provides working __ehdr_start],
1596                libc_cv_ehdr_start, [
1597 old_CFLAGS="$CFLAGS"
1598 old_LDFLAGS="$LDFLAGS"
1599 old_LIBS="$LIBS"
1600 CFLAGS="$CFLAGS -fPIC"
1601 LDFLAGS="$LDFLAGS -nostdlib -nostartfiles -shared $no_ssp"
1602 LIBS=
1603 AC_LINK_IFELSE([AC_LANG_SOURCE([
1604 typedef struct {
1605   char foo;
1606   long val;
1607 } Ehdr;
1608 extern const Ehdr __ehdr_start __attribute__ ((visibility ("hidden")));
1609 long ehdr (void) { return __ehdr_start.val; }
1610 ])],
1611                [if $READELF -r conftest | grep -F __ehdr_start >/dev/null; then
1612                   libc_cv_ehdr_start=broken
1613                 else
1614                   libc_cv_ehdr_start=yes
1615                 fi], [libc_cv_ehdr_start=no])
1616 CFLAGS="$old_CFLAGS"
1617 LDFLAGS="$old_LDFLAGS"
1618 LIBS="$old_LIBS"
1619 ])
1620 if test "$libc_cv_ehdr_start" = yes; then
1621   AC_DEFINE([HAVE_EHDR_START])
1622 elif test "$libc_cv_ehdr_start" = broken; then
1623   AC_MSG_WARN([linker is broken -- you should upgrade])
1624 fi
1625
1626 AC_CACHE_CHECK(for __builtin_trap with no external dependencies,
1627                libc_cv_builtin_trap, [dnl
1628 libc_cv_builtin_trap=no
1629 AC_TRY_COMPILE([], [__builtin_trap ()], [
1630 libc_undefs=`$NM -u conftest.o |
1631   LC_ALL=C $AWK '$1 == "U" { print $2 | "sort -u"; next } { exit(1) }' \
1632     2>&AS_MESSAGE_LOG_FD` || {
1633   AC_MSG_ERROR([confusing output from $NM -u])
1634 }
1635 echo >&AS_MESSAGE_LOG_FD "libc_undefs='$libc_undefs'"
1636 if test -z "$libc_undefs"; then
1637   libc_cv_builtin_trap=yes
1638 fi])])
1639 if test $libc_cv_builtin_trap = yes; then
1640   AC_DEFINE([HAVE_BUILTIN_TRAP])
1641 fi
1642
1643 dnl C++ feature tests.
1644 AC_LANG_PUSH([C++])
1645
1646 AC_CACHE_CHECK([whether the C++ compiler supports thread_local],
1647                libc_cv_cxx_thread_local, [
1648 old_CXXFLAGS="$CXXFLAGS"
1649 CXXFLAGS="$CXXFLAGS -std=gnu++11"
1650 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1651 #include <thread>
1652
1653 // Compiler support.
1654 struct S
1655 {
1656   S ();
1657   ~S ();
1658 };
1659 thread_local S s;
1660 S * get () { return &s; }
1661
1662 // libstdc++ support.
1663 #ifndef _GLIBCXX_HAVE___CXA_THREAD_ATEXIT_IMPL
1664 #error __cxa_thread_atexit_impl not supported
1665 #endif
1666 ])],
1667                [libc_cv_cxx_thread_local=yes],
1668                [libc_cv_cxx_thread_local=no])
1669 CXXFLAGS="$old_CXXFLAGS"
1670 ])
1671 AC_SUBST(libc_cv_cxx_thread_local)
1672
1673 AC_LANG_POP([C++])
1674 dnl End of C++ feature tests.
1675
1676 ### End of automated tests.
1677 ### Now run sysdeps configure fragments.
1678
1679 # They also can set these variables.
1680 use_ldconfig=no
1681 ldd_rewrite_script=no
1682 libc_cv_sysconfdir=$sysconfdir
1683 libc_cv_localstatedir=$localstatedir
1684 libc_cv_gcc_unwind_find_fde=no
1685 libc_cv_idn=no
1686
1687 # Iterate over all the sysdep directories we will use, running their
1688 # configure fragments.
1689 for dir in $sysnames; do
1690   case $dir in
1691     /*) dest=$dir ;;
1692     *)  dest=$srcdir/$dir ;;
1693   esac
1694   if test -r $dest/configure; then
1695     AC_MSG_RESULT(running configure fragment for $dir)
1696     . $dest/configure
1697   fi
1698 done
1699
1700 if test x"$build_mathvec" = xnotset; then
1701   build_mathvec=no
1702 fi
1703 LIBC_CONFIG_VAR([build-mathvec], [$build_mathvec])
1704
1705 AC_SUBST(libc_extra_cflags)
1706 AC_SUBST(libc_extra_cppflags)
1707
1708 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
1709   AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
1710 fi
1711 AC_SUBST(libc_cv_gcc_unwind_find_fde)
1712
1713 # A sysdeps configure fragment can reset this if IFUNC is not actually
1714 # usable even though the assembler knows how to generate the symbol type.
1715 if test x"$libc_cv_ld_gnu_indirect_function" = xyes; then
1716   AC_DEFINE(HAVE_IFUNC)
1717 fi
1718
1719 if test x"$libc_cv_gcc_indirect_function" = xyes; then
1720   AC_DEFINE(HAVE_GCC_IFUNC)
1721 fi
1722
1723 # This is far from the AC_ARG_ENABLE that sets it so that a sysdeps
1724 # configure fragment can override the value to prevent this AC_DEFINE.
1725 AC_SUBST(use_nscd)
1726 if test "x$use_nscd" != xno; then
1727   AC_DEFINE([USE_NSCD])
1728 fi
1729 if test "x$build_nscd" = xdefault; then
1730   build_nscd=$use_nscd
1731 fi
1732
1733 AC_SUBST(libc_cv_slibdir)
1734 AC_SUBST(libc_cv_rtlddir)
1735 AC_SUBST(libc_cv_complocaledir)
1736 AC_SUBST(libc_cv_sysconfdir)
1737 AC_SUBST(libc_cv_localstatedir)
1738 AC_SUBST(libc_cv_rootsbindir)
1739
1740 if test x$use_ldconfig = xyes; then
1741   AC_DEFINE(USE_LDCONFIG)
1742 fi
1743 AC_SUBST(use_ldconfig)
1744 AC_SUBST(ldd_rewrite_script)
1745
1746 AC_SUBST(static)
1747 AC_SUBST(shared)
1748
1749 AC_CACHE_CHECK([whether -fPIC is default], libc_cv_pic_default,
1750 [libc_cv_pic_default=yes
1751 cat > conftest.c <<EOF
1752 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1753 # error PIC is default.
1754 #endif
1755 EOF
1756 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1757   libc_cv_pic_default=no
1758 fi
1759 rm -f conftest.*])
1760 AC_SUBST(libc_cv_pic_default)
1761
1762 AC_CACHE_CHECK([whether -fPIE is default], libc_cv_pie_default,
1763 [libc_cv_pie_default=yes
1764 cat > conftest.c <<EOF
1765 #if defined __PIE__ || defined __pie__ || defined PIE || defined pie
1766 # error PIE is default.
1767 #endif
1768 EOF
1769 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1770   libc_cv_pie_default=no
1771 fi
1772 rm -f conftest.*])
1773 AC_SUBST(libc_cv_pie_default)
1774
1775 # Set the `multidir' variable by grabbing the variable from the compiler.
1776 # We do it once and save the result in a generated makefile.
1777 libc_cv_multidir=`${CC-cc} $CFLAGS $CPPFLAGS -print-multi-directory`
1778 AC_SUBST(libc_cv_multidir)
1779
1780 AC_SUBST(profile)
1781 AC_SUBST(static_nss)
1782
1783 AC_SUBST(DEFINES)
1784
1785 dnl See sysdeps/mach/configure.ac for this variable.
1786 AC_SUBST(mach_interface_list)
1787
1788 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1789 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1790 AC_SUBST(VERSION)
1791 AC_SUBST(RELEASE)
1792
1793 AC_CONFIG_FILES([config.make Makefile])
1794 AC_CONFIG_COMMANDS([default],[[
1795 case $CONFIG_FILES in *config.make*)
1796 echo "$config_vars" >> config.make;;
1797 esac
1798 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
1799 AC_OUTPUT