configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Note we do not use AC_PREREQ here!  See aclocal.m4 for what we use instead.
   3 AC_INIT([GNU C Library], [(see version.h)], [https://sourceware.org/bugzilla/], [glibc])
   4 AC_CONFIG_SRCDIR([include/features.h])
   5 AC_CONFIG_HEADERS([config.h])
   6 AC_CONFIG_AUX_DIR([scripts])
   7
   8 ACX_PKGVERSION([GNU libc])
   9 ACX_BUGURL([http://www.gnu.org/software/libc/bugs.html])
  10 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"],
  11                    [Package description])
  12 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"],
  13                    [Bug reporting address])
  14
  15 # Glibc should not depend on any header files
  16 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
  17   [m4_divert_text([DEFAULTS],
  18     [ac_includes_default='/* none */'])])
  19
  20 # We require GCC, and by default use its preprocessor.  Override AC_PROG_CPP
  21 # here to work around the Autoconf issue discussed in
  22 # <https://sourceware.org/ml/libc-alpha/2013-01/msg00721.html>.
  23 AC_DEFUN([AC_PROG_CPP],
  24 [AC_REQUIRE([AC_PROG_CC])dnl
  25 AC_ARG_VAR([CPP],      [C preprocessor])dnl
  26 _AC_ARG_VAR_CPPFLAGS()dnl
  27 # On Suns, sometimes $CPP names a directory.
  28 if test -n "$CPP" && test -d "$CPP"; then
  29   CPP=
  30 fi
  31 if test -z "$CPP"; then
  32   CPP="$CC -E"
  33 fi
  34 AC_SUBST(CPP)dnl
  35 ])# AC_PROG_CPP
  36
  37 # We require GCC.  Override _AC_PROG_CC_C89 here to work around the Autoconf
  38 # issue discussed in
  39 # <https://sourceware.org/ml/libc-alpha/2013-01/msg00757.html>.
  40 AC_DEFUN([_AC_PROG_CC_C89], [[$1]])
  41
  42 dnl This is here so we can set $subdirs directly based on configure fragments.
  43 AC_CONFIG_SUBDIRS()
  44
  45 AC_CANONICAL_HOST
  46
  47 AC_PROG_CC
  48 if test $host != $build; then
  49   AC_CHECK_PROGS(BUILD_CC, gcc cc)
  50 fi
  51 AC_SUBST(cross_compiling)
  52 AC_PROG_CPP
  53 AC_CHECK_TOOL(READELF, readelf, false)
  54
  55 # We need the C++ compiler only for testing.
  56 AC_PROG_CXX
  57 # It's useless to us if it can't link programs (e.g. missing -lstdc++).
  58 AC_CACHE_CHECK([whether $CXX can link programs], libc_cv_cxx_link_ok, [dnl
  59 AC_LANG_PUSH([C++])
  60 # Default, dynamic case.
  61 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
  62                [libc_cv_cxx_link_ok=yes],
  63                [libc_cv_cxx_link_ok=no])
  64 # Static case.
  65 old_LDFLAGS="$LDFLAGS"
  66 LDFLAGS="$LDFLAGS -static"
  67 AC_LINK_IFELSE([AC_LANG_SOURCE([
  68 #include <iostream>
  69
  70 int
  71 main()
  72 {
  73   std::cout << "Hello, world!";
  74   return 0;
  75 }
  76 ])],
  77                [],
  78                [libc_cv_cxx_link_ok=no])
  79 LDFLAGS="$old_LDFLAGS"
  80 AC_LANG_POP([C++])])
  81 AS_IF([test $libc_cv_cxx_link_ok != yes], [CXX=])
  82
  83 if test "`cd $srcdir; pwd -P`" = "`pwd -P`"; then
  84   AC_MSG_ERROR([you must configure in a separate build directory])
  85 fi
  86
  87 # This will get text that should go into config.make.
  88 config_vars=
  89
  90 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
  91 AC_ARG_WITH([gd],
  92             AC_HELP_STRING([--with-gd=DIR],
  93                            [find libgd include dir and library with prefix DIR]),
  94             [dnl
  95 case "$with_gd" in
  96 yes|''|no) ;;
  97 *) libgd_include="-I$withval/include"
  98    libgd_ldflags="-L$withval/lib" ;;
  99 esac
 100 ])
 101 AC_ARG_WITH([gd-include],
 102             AC_HELP_STRING([--with-gd-include=DIR],
 103                            [find libgd include files in DIR]),
 104             [dnl
 105 case "$with_gd_include" in
 106 ''|no) ;;
 107 *) libgd_include="-I$withval" ;;
 108 esac
 109 ])
 110 AC_ARG_WITH([gd-lib],
 111             AC_HELP_STRING([--with-gd-lib=DIR],
 112                            [find libgd library files in DIR]),
 113             [dnl
 114 case "$with_gd_lib" in
 115 ''|no) ;;
 116 *) libgd_ldflags="-L$withval" ;;
 117 esac
 118 ])
 119
 120 if test -n "$libgd_include"; then
 121   config_vars="$config_vars
 122 CFLAGS-memusagestat.c = $libgd_include"
 123 fi
 124 if test -n "$libgd_ldflags"; then
 125   config_vars="$config_vars
 126 libgd-LDFLAGS = $libgd_ldflags"
 127 fi
 128
 129 dnl Arguments to specify presence of other packages/features.
 130 AC_ARG_WITH([binutils],
 131             AC_HELP_STRING([--with-binutils=PATH],
 132                            [specify location of binutils (as and ld)]),
 133             [path_binutils=$withval],
 134             [path_binutils=''])
 135 AC_ARG_WITH([selinux],
 136             AC_HELP_STRING([--with-selinux],
 137                            [if building with SELinux support]),
 138             [with_selinux=$withval],
 139             [with_selinux=auto])
 140
 141 AC_ARG_WITH([headers],
 142             AC_HELP_STRING([--with-headers=PATH],
 143                            [location of system headers to use
 144                             (for example /usr/src/linux/include)
 145                             @<:@default=compiler default@:>@]),
 146             [sysheaders=$withval],
 147             [sysheaders=''])
 148 AC_SUBST(sysheaders)
 149
 150 AC_SUBST(use_default_link)
 151 AC_ARG_WITH([default-link],
 152             AC_HELP_STRING([--with-default-link],
 153                            [do not use explicit linker scripts]),
 154             [use_default_link=$withval],
 155             [use_default_link=default])
 156
 157 dnl Additional build flags injection.
 158 AC_ARG_WITH([nonshared-cflags],
 159             AC_HELP_STRING([--with-nonshared-cflags=CFLAGS],
 160                            [build nonshared libraries with additional CFLAGS]),
 161             [extra_nonshared_cflags=$withval],
 162             [extra_nonshared_cflags=])
 163 AC_SUBST(extra_nonshared_cflags)
 164
 165 AC_ARG_ENABLE([sanity-checks],
 166               AC_HELP_STRING([--disable-sanity-checks],
 167                              [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
 168               [enable_sanity=$enableval],
 169               [enable_sanity=yes])
 170
 171 AC_ARG_ENABLE([shared],
 172               AC_HELP_STRING([--enable-shared],
 173                              [build shared library @<:@default=yes if GNU ld@:>@]),
 174               [shared=$enableval],
 175               [shared=yes])
 176 AC_ARG_ENABLE([profile],
 177               AC_HELP_STRING([--enable-profile],
 178                              [build profiled library @<:@default=no@:>@]),
 179               [profile=$enableval],
 180               [profile=no])
 181 AC_ARG_ENABLE([static-pie],
 182               AC_HELP_STRING([--enable-static-pie],
 183                              [enable static PIE support and use it in the testsuite @<:@default=no@:>@]),
 184               [static_pie=$enableval],
 185               [static_pie=no])
 186 AC_ARG_ENABLE([timezone-tools],
 187               AC_HELP_STRING([--disable-timezone-tools],
 188                              [do not install timezone tools @<:@default=install@:>@]),
 189               [enable_timezone_tools=$enableval],
 190               [enable_timezone_tools=yes])
 191 AC_SUBST(enable_timezone_tools)
 192
 193 AC_ARG_ENABLE([hardcoded-path-in-tests],
 194               AC_HELP_STRING([--enable-hardcoded-path-in-tests],
 195                              [hardcode newly built glibc path in tests @<:@default=no@:>@]),
 196               [hardcoded_path_in_tests=$enableval],
 197               [hardcoded_path_in_tests=no])
 198 AC_SUBST(hardcoded_path_in_tests)
 199
 200 AC_ARG_ENABLE([stackguard-randomization],
 201               AC_HELP_STRING([--enable-stackguard-randomization],
 202                              [initialize __stack_chk_guard canary with a random number at program start]),
 203               [enable_stackguard_randomize=$enableval],
 204               [enable_stackguard_randomize=no])
 205 if test "$enable_stackguard_randomize" = yes; then
 206   AC_DEFINE(ENABLE_STACKGUARD_RANDOMIZE)
 207 fi
 208
 209 AC_ARG_ENABLE([hidden-plt],
 210               AC_HELP_STRING([--disable-hidden-plt],
 211                              [do not hide internal function calls to avoid PLT]),
 212               [hidden=$enableval],
 213               [hidden=yes])
 214 if test "x$hidden" = xno; then
 215   AC_DEFINE(NO_HIDDEN)
 216 fi
 217
 218 AC_ARG_ENABLE([bind-now],
 219               AC_HELP_STRING([--enable-bind-now],
 220                              [disable lazy relocations in DSOs]),
 221               [bindnow=$enableval],
 222               [bindnow=no])
 223 AC_SUBST(bindnow)
 224 if test "x$bindnow" = xyes; then
 225   AC_DEFINE(BIND_NOW)
 226 fi
 227
 228 dnl Build glibc with -fstack-protector, -fstack-protector-all, or
 229 dnl -fstack-protector-strong.
 230 AC_ARG_ENABLE([stack-protector],
 231               AC_HELP_STRING([--enable-stack-protector=@<:@yes|no|all|strong@:>@],
 232                              [Use -fstack-protector[-all|-strong] to detect glibc buffer overflows]),
 233               [enable_stack_protector=$enableval],
 234               [enable_stack_protector=no])
 235 case "$enable_stack_protector" in
 236 all|yes|no|strong) ;;
 237 *) AC_MSG_ERROR([Not a valid argument for --enable-stack-protector: \"$enable_stack_protector\"]);;
 238 esac
 239
 240 dnl On some platforms we cannot use dynamic loading.  We must provide
 241 dnl static NSS modules.
 242 AC_ARG_ENABLE([static-nss],
 243               AC_HELP_STRING([--enable-static-nss],
 244                              [build static NSS modules @<:@default=no@:>@]),
 245               [static_nss=$enableval],
 246               [static_nss=no])
 247 dnl Enable static NSS also if we build no shared objects.
 248 if test x"$static_nss" = xyes || test x"$shared" = xno; then
 249   static_nss=yes
 250   AC_DEFINE(DO_STATIC_NSS)
 251 fi
 252
 253 AC_ARG_ENABLE([force-install],
 254               AC_HELP_STRING([--disable-force-install],
 255                              [don't force installation of files from this package, even if they are older than the installed files]),
 256               [force_install=$enableval],
 257               [force_install=yes])
 258 AC_SUBST(force_install)
 259
 260 AC_ARG_ENABLE([maintainer-mode],
 261               AC_HELP_STRING([--enable-maintainer-mode],
 262                              [enable make rules and dependencies not useful (and sometimes confusing) to the casual installer]),
 263               [maintainer=$enableval],
 264               [maintainer=no])
 265
 266 dnl On some platforms we allow dropping compatibility with all kernel
 267 dnl versions.
 268 AC_ARG_ENABLE([kernel],
 269               AC_HELP_STRING([--enable-kernel=VERSION],
 270                              [compile for compatibility with kernel not older than VERSION]),
 271               [minimum_kernel=$enableval],
 272               [])
 273 dnl Prevent unreasonable values.
 274 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
 275   # Better nothing than this.
 276   minimum_kernel=""
 277 else
 278   if test "$minimum_kernel" = current; then
 279     minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
 280   fi
 281 fi
 282
 283 dnl For the development we sometimes want gcc to issue even more warnings.
 284 dnl This is not the default since many of the extra warnings are not
 285 dnl appropriate.
 286 AC_ARG_ENABLE([all-warnings],
 287               AC_HELP_STRING([--enable-all-warnings],
 288                              [enable all useful warnings gcc can issue]),
 289               [all_warnings=$enableval],
 290               [])
 291 AC_SUBST(all_warnings)
 292
 293 AC_ARG_ENABLE([werror],
 294               AC_HELP_STRING([--disable-werror],
 295                              [do not build with -Werror]),
 296               [enable_werror=$enableval],
 297               [enable_werror=yes])
 298 AC_SUBST(enable_werror)
 299
 300 AC_ARG_ENABLE([multi-arch],
 301               AC_HELP_STRING([--enable-multi-arch],
 302                              [enable single DSO with optimizations for multiple architectures]),
 303               [multi_arch=$enableval],
 304               [multi_arch=default])
 305
 306 AC_ARG_ENABLE([experimental-malloc],
 307               AC_HELP_STRING([--disable-experimental-malloc],
 308                              [disable experimental malloc features]),
 309               [experimental_malloc=$enableval],
 310               [experimental_malloc=yes])
 311 AC_SUBST(experimental_malloc)
 312
 313 AC_ARG_ENABLE([crypt],
 314               AC_HELP_STRING([--disable-crypt],
 315                              [do not build nor install the passphrase hashing library, libcrypt]),
 316               [build_crypt=$enableval],
 317               [build_crypt=yes])
 318 AC_SUBST(build_crypt)
 319
 320 AC_ARG_ENABLE([nss-crypt],
 321               AC_HELP_STRING([--enable-nss-crypt],
 322                              [enable libcrypt to use nss]),
 323               [nss_crypt=$enableval],
 324               [nss_crypt=no])
 325 if test x$build_libcrypt = xno && test x$nss_crypt = xyes; then
 326   AC_MSG_WARN([--enable-nss-crypt has no effect when libcrypt is disabled])
 327   nss_crypt=no
 328 fi
 329 if test x$nss_crypt = xyes; then
 330   nss_includes=-I$(nss-config --includedir 2>/dev/null)
 331   if test $? -ne 0; then
 332     AC_MSG_ERROR([cannot find include directory with nss-config])
 333   fi
 334   nspr_includes=-I$(nspr-config --includedir 2>/dev/null)
 335   if test $? -ne 0; then
 336     AC_MSG_ERROR([cannot find include directory with nspr-config])
 337   fi
 338   old_CFLAGS="$CFLAGS"
 339   CFLAGS="$CFLAGS $nss_includes $nspr_includes"
 340   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 341 #include <hasht.h>
 342 #include <nsslowhash.h>
 343 void f (void) { NSSLOW_Init (); }])],
 344              libc_cv_nss_crypt=yes,
 345              AC_MSG_ERROR([
 346 cannot find NSS headers with lowlevel hash function interfaces]))
 347   old_LIBS="$LIBS"
 348   old_LDFLAGS="$LDFLAGS"
 349   LIBS="$LIBS -lfreebl3"
 350   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 351 #include <hasht.h>
 352 #include <nsslowhash.h>],
 353                                   [NSSLOW_Init();])],
 354                  libc_cv_nss_crypt=yes,
 355                  AC_MSG_ERROR([
 356 cannot link program using lowlevel NSS hash functions]))
 357   # Check to see if there is a static NSS cryptographic library.
 358   # If there isn't then we can't link anything with libcrypt.a,
 359   # and that might mean disabling some static tests.
 360   LDFLAGS="$LDFLAGS -static"
 361   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 362 #include <hasht.h>
 363 #include <nsslowhash.h>],
 364                                   [NSSLOW_Init();])],
 365                  libc_cv_static_nss_crypt=yes,
 366                  libc_cv_static_nss_crypt=no)
 367   LDFLAGS="$old_LDFLAGS"
 368   CFLAGS="$old_CFLAGS"
 369   LIBS="$old_LIBS"
 370 else
 371   libc_cv_nss_crypt=no
 372   libc_cv_static_nss_crypt=no
 373 fi
 374 AC_SUBST(libc_cv_nss_crypt)
 375 AC_SUBST(libc_cv_static_nss_crypt)
 376
 377
 378 AC_ARG_ENABLE([obsolete-rpc],
 379               AC_HELP_STRING([--enable-obsolete-rpc],
 380                              [build and install the obsolete RPC code for link-time usage]),
 381               [link_obsolete_rpc=$enableval],
 382               [link_obsolete_rpc=no])
 383 AC_SUBST(link_obsolete_rpc)
 384
 385 if test "$link_obsolete_rpc" = yes; then
 386   AC_DEFINE(LINK_OBSOLETE_RPC)
 387 fi
 388
 389 AC_ARG_ENABLE([obsolete-nsl],
 390               AC_HELP_STRING([--enable-obsolete-nsl],
 391                              [build and install the obsolete libnsl library and depending NSS modules]),
 392               [build_obsolete_nsl=$enableval],
 393               [build_obsolete_nsl=no])
 394 AC_SUBST(build_obsolete_nsl)
 395
 396 if test "$build_obsolete_nsl" = yes; then
 397   AC_DEFINE(LINK_OBSOLETE_NSL)
 398 fi
 399
 400 AC_ARG_ENABLE([systemtap],
 401               [AS_HELP_STRING([--enable-systemtap],
 402                [enable systemtap static probe points @<:@default=no@:>@])],
 403               [systemtap=$enableval],
 404               [systemtap=no])
 405 if test "x$systemtap" != xno; then
 406   AC_CACHE_CHECK([for systemtap static probe support], libc_cv_sdt, [dnl
 407   old_CFLAGS="$CFLAGS"
 408   CFLAGS="-std=gnu11 $CFLAGS"
 409   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#include <sys/sdt.h>
 410 void foo (int i, void *p)
 411 {
 412   asm ("" STAP_PROBE_ASM (foo, bar, STAP_PROBE_ASM_TEMPLATE (2)) ""
 413        :: STAP_PROBE_ASM_OPERANDS (2, i, p));
 414 }]])], [libc_cv_sdt=yes], [libc_cv_sdt=no])
 415   CFLAGS="$old_CFLAGS"])
 416   if test $libc_cv_sdt = yes; then
 417     AC_DEFINE([USE_STAP_PROBE])
 418   elif test "x$systemtap" != xauto; then
 419     AC_MSG_FAILURE([systemtap support needs sys/sdt.h with asm support])
 420   fi
 421 fi
 422
 423 AC_ARG_ENABLE([build-nscd],
 424               [AS_HELP_STRING([--disable-build-nscd],
 425                [disable building and installing the nscd daemon])],
 426               [build_nscd=$enableval],
 427               [build_nscd=default])
 428 AC_SUBST(build_nscd)
 429
 430 # Note the use of $use_nscd is near the bottom of the file.
 431 AC_ARG_ENABLE([nscd],
 432               [AS_HELP_STRING([--disable-nscd],
 433                [library functions will not contact the nscd daemon])],
 434               [use_nscd=$enableval],
 435               [use_nscd=yes])
 436
 437 AC_ARG_ENABLE([pt_chown],
 438               [AS_HELP_STRING([--enable-pt_chown],
 439                [Enable building and installing pt_chown])],
 440               [build_pt_chown=$enableval],
 441               [build_pt_chown=no])
 442 AC_SUBST(build_pt_chown)
 443 if test "$build_pt_chown" = yes; then
 444   AC_DEFINE(HAVE_PT_CHOWN)
 445 fi
 446
 447 AC_ARG_ENABLE([tunables],
 448               [AS_HELP_STRING([--enable-tunables],
 449                [Enable tunables support. Known values are 'yes', 'no' and 'valstring'])],
 450               [have_tunables=$enableval],
 451               [have_tunables=yes])
 452 AC_SUBST(have_tunables)
 453 if test "$have_tunables" = yes; then
 454   AC_DEFINE(HAVE_TUNABLES)
 455 fi
 456
 457 # The abi-tags file uses a fairly simplistic model for name recognition that
 458 # can't distinguish i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a
 459 # $host_os of `gnu*' here to be `gnu-gnu*' just so that it can tell.
 460 # This doesn't get used much beyond that, so it's fairly safe.
 461 case "$host_os" in
 462 linux*)
 463   ;;
 464 gnu*)
 465   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 466   ;;
 467 esac
 468
 469 AC_ARG_ENABLE([mathvec],
 470               [AS_HELP_STRING([--enable-mathvec],
 471               [Enable building and installing mathvec @<:@default depends on architecture@:>@])],
 472               [build_mathvec=$enableval],
 473               [build_mathvec=notset])
 474
 475 AC_ARG_ENABLE([cet],
 476               AC_HELP_STRING([--enable-cet],
 477                              [enable Intel Control-flow Enforcement Technology (CET), x86 only]),
 478               [enable_cet=$enableval],
 479               [enable_cet=no])
 480
 481 # We keep the original values in `$config_*' and never modify them, so we
 482 # can write them unchanged into config.make.  Everything else uses
 483 # $machine, $vendor, and $os, and changes them whenever convenient.
 484 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 485
 486 # Don't allow vendor == "unknown"
 487 test "$config_vendor" = unknown && config_vendor=
 488 config_os="`echo $config_os | sed 's/^unknown-//'`"
 489
 490 # Some configurations imply other options.
 491 elf=yes
 492
 493 # The configure fragment of a port can modify these to supplement
 494 # or override the table in the case statement below.  No fragment should
 495 # ever change the config_* variables, however.
 496 machine=$config_machine
 497 vendor=$config_vendor
 498 os=$config_os
 499 base_os=''
 500
 501 submachine=
 502 AC_ARG_WITH([cpu],
 503             AS_HELP_STRING([--with-cpu=CPU], [select code for CPU variant]),
 504             [dnl
 505   case "$withval" in
 506   yes|'') AC_MSG_ERROR([--with-cpu requires an argument]) ;;
 507   no) ;;
 508   *) submachine="$withval" ;;
 509   esac
 510 ])
 511
 512 # An preconfigure script can set this when it wants to disable the sanity
 513 # check below.
 514 libc_config_ok=no
 515
 516 # A preconfigure script for a system that may or may not use fpu
 517 # sysdeps directories sets this to a preprocessor conditional for
 518 # whether to use such directories.
 519 with_fp_cond=1
 520
 521 dnl Let sysdeps/*/preconfigure act here.
 522 LIBC_PRECONFIGURE([$srcdir], [for sysdeps])
 523
 524
 525 ###
 526 ### By using the undocumented --enable-hacker-mode option for configure
 527 ### one can skip this test to make the configuration not fail for unsupported
 528 ### platforms.
 529 ###
 530 if test -z "$enable_hacker_mode" && test x"$libc_config_ok" != xyes; then
 531   case "$machine-$host_os" in
 532   *-linux* | *-gnu*)
 533     ;;
 534   *)
 535     AC_MSG_ERROR([
 536 *** The GNU C library is currently unavailable for this platform.
 537 *** If you are interested in seeing glibc on this platform visit
 538 *** the "How to submit a new port" in the wiki:
 539 ***   https://sourceware.org/glibc/wiki/#Development
 540 *** and join the community!])
 541     ;;
 542   esac
 543 fi
 544
 545 # Set base_machine if not set by a preconfigure fragment.
 546 test -n "$base_machine" || base_machine=$machine
 547 AC_SUBST(base_machine)
 548
 549 # Determine whether to use fpu or nofpu sysdeps directories.
 550 AC_CACHE_CHECK([for use of fpu sysdeps directories],
 551                libc_cv_with_fp, [dnl
 552 cat > conftest.c <<EOF
 553 #if $with_fp_cond
 554 int dummy;
 555 #else
 556 # error "no hardware floating point"
 557 #endif
 558 EOF
 559 libc_cv_with_fp=no
 560 if ${CC-cc} $CFLAGS $CPPFLAGS -S conftest.c -o conftest.s \
 561    1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD ; then
 562   libc_cv_with_fp=yes
 563 fi
 564 rm -f conftest*])
 565 AC_SUBST(libc_cv_with_fp)
 566
 567 AC_CACHE_CHECK(for -fstack-protector, libc_cv_ssp, [dnl
 568 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector],
 569                    [libc_cv_ssp=yes],
 570                    [libc_cv_ssp=no])
 571 ])
 572
 573 AC_CACHE_CHECK(for -fstack-protector-strong, libc_cv_ssp_strong, [dnl
 574 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector-strong],
 575                    [libc_cv_ssp_strong=yes],
 576                    [libc_cv_ssp_strong=no])
 577 ])
 578
 579 AC_CACHE_CHECK(for -fstack-protector-all, libc_cv_ssp_all, [dnl
 580 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector-all],
 581                    [libc_cv_ssp_all=yes],
 582                    [libc_cv_ssp_all=no])
 583 ])
 584
 585 stack_protector=
 586 no_stack_protector=
 587 if test "$libc_cv_ssp" = yes; then
 588   no_stack_protector="-fno-stack-protector -DSTACK_PROTECTOR_LEVEL=0"
 589   AC_DEFINE(HAVE_CC_NO_STACK_PROTECTOR)
 590 fi
 591
 592 if test "$enable_stack_protector" = yes && test "$libc_cv_ssp" = yes; then
 593   stack_protector="-fstack-protector"
 594   AC_DEFINE(STACK_PROTECTOR_LEVEL, 1)
 595 elif test "$enable_stack_protector" = all && test "$libc_cv_ssp_all" = yes; then
 596   stack_protector="-fstack-protector-all"
 597   AC_DEFINE(STACK_PROTECTOR_LEVEL, 2)
 598 elif test "$enable_stack_protector" = strong && test "$libc_cv_ssp_strong" = yes; then
 599   stack_protector="-fstack-protector-strong"
 600   AC_DEFINE(STACK_PROTECTOR_LEVEL, 3)
 601 else
 602   stack_protector="-fno-stack-protector"
 603   AC_DEFINE(STACK_PROTECTOR_LEVEL, 0)
 604 fi
 605 AC_SUBST(libc_cv_ssp)
 606 AC_SUBST(stack_protector)
 607 AC_SUBST(no_stack_protector)
 608
 609 if test -n "$stack_protector"; then
 610   dnl Don't run configure tests with stack-protection on, to avoid problems with
 611   dnl bootstrapping.
 612   no_ssp=-fno-stack-protector
 613 else
 614   no_ssp=
 615
 616   if test "$enable_stack_protector" != no; then
 617     AC_MSG_ERROR([--enable-stack-protector=$enable_stack_protector specified, but specified level of stack protection is not supported by the compiler.])
 618   fi
 619 fi
 620
 621 # For the multi-arch option we need support in the assembler & linker.
 622 AC_CACHE_CHECK([for assembler and linker STT_GNU_IFUNC support],
 623                libc_cv_ld_gnu_indirect_function, [dnl
 624 cat > conftest.S <<EOF
 625 .type foo,%gnu_indirect_function
 626 foo:
 627 .globl _start
 628 _start:
 629 .globl __start
 630 __start:
 631 .data
 632 #ifdef _LP64
 633 .quad foo
 634 #else
 635 .long foo
 636 #endif
 637 EOF
 638 libc_cv_ld_gnu_indirect_function=no
 639 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 640             -nostartfiles -nostdlib $no_ssp \
 641             -o conftest conftest.S 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
 642   # Do a link to see if the backend supports IFUNC relocs.
 643   $READELF -r conftest 1>&AS_MESSAGE_LOG_FD
 644   LC_ALL=C $READELF -r conftest | grep 'no relocations' >/dev/null || {
 645     libc_cv_ld_gnu_indirect_function=yes
 646   }
 647 fi
 648 rm -f conftest*])
 649
 650 # Check if gcc supports attribute ifunc as it is used in libc_ifunc macro.
 651 AC_CACHE_CHECK([for gcc attribute ifunc support],
 652                libc_cv_gcc_indirect_function, [dnl
 653 cat > conftest.c <<EOF
 654 extern int func (int);
 655 int used_func (int a)
 656 {
 657   return a;
 658 }
 659 static void *resolver ()
 660 {
 661   return &used_func;
 662 }
 663 extern __typeof (func) func __attribute__ ((ifunc ("resolver")));
 664 EOF
 665 libc_cv_gcc_indirect_function=no
 666 if ${CC-cc} -c conftest.c -o conftest.o 1>&AS_MESSAGE_LOG_FD \
 667    2>&AS_MESSAGE_LOG_FD ; then
 668   if $READELF -s conftest.o | grep IFUNC >/dev/null 2>&AS_MESSAGE_LOG_FD; then
 669     libc_cv_gcc_indirect_function=yes
 670   fi
 671 fi
 672 rm -f conftest*])
 673
 674 # Check if linker supports textrel relocation with ifunc (used on elf/tests).
 675 # Note that it relies on libc_cv_ld_gnu_indirect_function test above.
 676 AC_CACHE_CHECK([whether the linker supports textrels along with ifunc],
 677                libc_cv_textrel_ifunc, [dnl
 678 cat > conftest.S <<EOF
 679 .type foo,%gnu_indirect_function
 680 foo:
 681 .globl _start
 682 _start:
 683 .globl __start
 684 __start:
 685 .data
 686 #ifdef _LP64
 687 .quad foo
 688 #else
 689 .long foo
 690 #endif
 691 .text
 692 .globl address
 693 address:
 694 #ifdef _LP64
 695 .quad address
 696 #else
 697 .long address
 698 #endif
 699 EOF
 700 libc_cv_textrel_ifunc=no
 701 if test $libc_cv_ld_gnu_indirect_function = yes; then
 702    if AC_TRY_COMMAND(${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -nostartfiles -nostdlib $no_ssp -pie -o conftest conftest.S); then
 703      libc_cv_textrel_ifunc=yes
 704    fi
 705 fi
 706 rm -f conftest*])
 707 AC_SUBST(libc_cv_textrel_ifunc)
 708
 709 # Check if gcc warns about alias for function with incompatible types.
 710 AC_CACHE_CHECK([if compiler warns about alias for function with incompatible types],
 711                libc_cv_gcc_incompatible_alias, [dnl
 712 cat > conftest.c <<EOF
 713 int __redirect_foo (const void *s, int c);
 714
 715 __typeof (__redirect_foo) *foo_impl (void) __asm__ ("foo");
 716 __typeof (__redirect_foo) *foo_impl (void)
 717 {
 718   return 0;
 719 }
 720
 721 extern __typeof (__redirect_foo) foo_alias __attribute__ ((alias ("foo")));
 722 EOF
 723 libc_cv_gcc_incompatible_alias=yes
 724 if ${CC-cc} -Werror -c conftest.c -o conftest.o 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD ; then
 725   libc_cv_gcc_incompatible_alias=no
 726 fi
 727 rm -f conftest*])
 728
 729 if test x"$libc_cv_ld_gnu_indirect_function" != xyes; then
 730   if test x"$multi_arch" = xyes; then
 731     AC_MSG_ERROR([--enable-multi-arch support requires assembler and linker support])
 732   else
 733     multi_arch=no
 734   fi
 735 fi
 736 if test x"$libc_cv_gcc_indirect_function" != xyes; then
 737   # GCC 8+ emits a warning for alias with incompatible types and it might
 738   # fail to build ifunc resolvers aliases to either weak or internal
 739   # symbols.  Disables multiarch build in this case.
 740   if test x"$libc_cv_gcc_incompatible_alias" == xyes; then
 741     AC_MSG_WARN([gcc emits a warning for alias between functions of incompatible types])
 742     if test x"$multi_arch" = xyes; then
 743       AC_MSG_ERROR([--enable-multi-arch support requires a gcc with gnu-indirect-function support])
 744     fi
 745     AC_MSG_WARN([Multi-arch is disabled.])
 746     multi_arch=no
 747   elif test x"$multi_arch" = xyes; then
 748     AC_MSG_WARN([--enable-multi-arch support recommends a gcc with gnu-indirect-function support.
 749 Please use a gcc which supports it by default or configure gcc with --enable-gnu-indirect-function])
 750   fi
 751 fi
 752 multi_arch_d=
 753 if test x"$multi_arch" != xno; then
 754   multi_arch_d=/multiarch
 755 fi
 756
 757 # Compute the list of sysdep directories for this configuration.
 758 # This can take a while to compute.
 759 sysdep_dir=$srcdir/sysdeps
 760 AC_MSG_CHECKING(sysdep dirs)
 761 dnl We need to use [ and ] for other purposes for a while now.
 762 changequote(,)dnl
 763 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 764 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 765
 766 test "x$base_os" != x || case "$os" in
 767 gnu*)
 768   base_os=mach/hurd ;;
 769 linux*)
 770   base_os=unix/sysv ;;
 771 esac
 772
 773 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 774 tail=$os
 775 ostry=$os
 776 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 777   ostry="$ostry /$o"
 778   tail=$o
 779 done
 780 o=`echo $tail | sed 's/[0-9]*$//'`
 781 if test $o != $tail; then
 782   ostry="$ostry /$o"
 783 fi
 784 # For linux-gnu, try linux-gnu, then linux.
 785 o=`echo $tail | sed 's/-.*$//'`
 786 if test $o != $tail; then
 787   ostry="$ostry /$o"
 788 fi
 789
 790 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 791 base=
 792 tail=$base_os
 793 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 794   set $b
 795   base="$base /$1"
 796   tail="$2"
 797 done
 798
 799 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 800 mach=
 801 tail=$machine${submachine:+/$submachine}
 802 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 803   set $m
 804   # Prepend the machine's FPU directory unless --without-fp.
 805   if test "$libc_cv_with_fp" = yes; then
 806     maybe_fpu=/fpu
 807   else
 808     maybe_fpu=/nofpu
 809   fi
 810   # For each machine term, try it with and then without /multiarch.
 811   for try_fpu in $maybe_fpu ''; do
 812     for try_multi in $multi_arch_d ''; do
 813       mach="$mach /$1$try_fpu$try_multi"
 814     done
 815   done
 816   tail="$2"
 817 done
 818
 819 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 820 changequote([,])dnl
 821
 822 # Find what sysdep directories exist.
 823 sysnames=
 824 for b in $base ''; do
 825   for m0 in $mach ''; do
 826     for v in /$vendor ''; do
 827       test "$v" = / && continue
 828       for o in /$ostry ''; do
 829         test "$o" = / && continue
 830         for m in $mach ''; do
 831           try_suffix="$m0$b$v$o$m"
 832           if test -n "$try_suffix"; then
 833             try_srcdir="${srcdir}/"
 834             try="sysdeps$try_suffix"
 835             test -n "$enable_debug_configure" &&
 836             echo "$0 [DEBUG]: try $try" >&2
 837             if test -d "$try_srcdir$try"; then
 838               sysnames="$sysnames $try"
 839               { test -n "$o" || test -n "$b"; } && os_used=t
 840               { test -n "$m" || test -n "$m0"; } && machine_used=t
 841               case x${m0:-$m} in
 842               x*/$submachine) submachine_used=t ;;
 843               esac
 844             fi
 845           fi
 846         done
 847       done
 848     done
 849   done
 850 done
 851
 852 # If the assembler supports gnu_indirect_function symbol type and the
 853 # architecture supports multi-arch, we enable multi-arch by default.
 854 case $sysnames in
 855 *"$multi_arch_d"*)
 856   ;;
 857 *)
 858   test x"$multi_arch" = xdefault && multi_arch=no
 859   ;;
 860 esac
 861 if test x"$multi_arch" != xno; then
 862   AC_DEFINE(USE_MULTIARCH)
 863 fi
 864 AC_SUBST(multi_arch)
 865
 866 if test -z "$os_used" && test "$os" != none; then
 867   AC_MSG_ERROR(Operating system $os is not supported.)
 868 fi
 869 if test -z "$machine_used" && test "$machine" != none; then
 870   AC_MSG_ERROR(The $machine is not supported.)
 871 fi
 872 if test -z "$submachine_used" && test -n "$submachine"; then
 873   AC_MSG_ERROR(The $submachine subspecies of $host_cpu is not supported.)
 874 fi
 875 AC_SUBST(submachine)
 876
 877 # We have now validated the configuration.
 878
 879 # Expand the list of system names into a full list of directories
 880 # from each element's parent name and Implies file (if present).
 881 set $sysnames
 882 names=
 883 while test $# -gt 0; do
 884   name=$1
 885   shift
 886
 887   case " $names " in *" $name "*)
 888     # Already in the list.
 889     continue
 890   esac
 891
 892   # Report each name as we discover it, so there is no long pause in output.
 893   echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
 894
 895   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 896
 897   case $name in
 898     /*) xsrcdir= ;;
 899     *)  xsrcdir=$srcdir/ ;;
 900   esac
 901   test -n "$enable_debug_configure" &&
 902   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 903
 904   for implies_file in Implies Implies-before Implies-after; do
 905     implies_type=`echo $implies_file | sed s/-/_/`
 906     eval ${implies_type}=
 907     if test -f $xsrcdir$name/$implies_file; then
 908       # Collect more names from the `Implies' file (removing comments).
 909       implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/$implies_file`"
 910       for x in $implied_candidate; do
 911         found=no
 912         if test -d $xsrcdir$name_base/$x; then
 913           eval "${implies_type}=\"\$${implies_type} \$name_base/\$x\""
 914           found=yes
 915         fi
 916         try="sysdeps/$x"
 917         try_srcdir=$srcdir/
 918         test -n "$enable_debug_configure" &&
 919          echo "[DEBUG]: $name $implies_file $x try() {$try_srcdir}$try" >&2
 920         if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
 921         then
 922           eval "${implies_type}=\"\$${implies_type} \$try\""
 923           found=yes
 924         fi
 925         if test $found = no; then
 926           AC_MSG_WARN($name/$implies_file specifies nonexistent $x)
 927         fi
 928       done
 929     fi
 930   done
 931
 932   # Add NAME to the list of names.
 933   names="$names $name"
 934
 935   # Find the parent of NAME, using the empty string if it has none.
 936 changequote(,)dnl
 937   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 938 changequote([,])dnl
 939
 940   test -n "$enable_debug_configure" &&
 941     echo "[DEBUG]: $name Implies='$Implies' rest='$*' parent='$parent' \
 942 Implies_before='$Implies_before' Implies_after='$Implies_after'" >&2
 943
 944   # Add the names implied by NAME, and NAME's parent (if it has one), to
 945   # the list of names to be processed (the argument list).  We prepend the
 946   # implied names to the list and append the parent.  We want implied
 947   # directories to come before further directories inferred from the
 948   # configuration components; this ensures that for sysv4, unix/common
 949   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 950   # after sysv4).
 951   sysnames="`echo $Implies $* $Implies_before $parent $Implies_after`"
 952   test -n "$sysnames" && set $sysnames
 953 done
 954
 955 # Add the default directories.
 956 default_sysnames="sysdeps/generic"
 957 sysnames="$names $default_sysnames"
 958 AC_SUBST(sysnames)
 959 # The other names were emitted during the scan.
 960 AC_MSG_RESULT($default_sysnames)
 961
 962
 963 ### Locate tools.
 964
 965 AC_PROG_INSTALL
 966 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
 967   # The makefiles need to use a different form to find it in $srcdir.
 968   INSTALL='\$(..)./scripts/install-sh -c'
 969 fi
 970 AC_PROG_LN_S
 971
 972 LIBC_PROG_BINUTILS
 973
 974 # Accept binutils 2.25 or newer.
 975 AC_CHECK_PROG_VER(AS, $AS, --version,
 976                   [GNU assembler.* \([0-9]*\.[0-9.]*\)],
 977                   [2.1[0-9][0-9]*|2.2[5-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
 978                   AS=: critic_missing="$critic_missing as")
 979
 980 if test -n "`$LD --version | sed -n 's/^GNU \(gold\).*$/\1/p'`"; then
 981   # Accept gold 1.14 or higher
 982   AC_CHECK_PROG_VER(LD, $LD, --version,
 983                     [GNU gold.* \([0-9][0-9]*\.[0-9.]*\)],
 984                     [1.1[4-9]*|1.[2-9][0-9]*|1.1[0-9][0-9]*|[2-9].*|[1-9][0-9]*],
 985                     LD=: critic_missing="$critic_missing GNU gold")
 986 else
 987   AC_CHECK_PROG_VER(LD, $LD, --version,
 988                     [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
 989                     [2.1[0-9][0-9]*|2.2[5-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
 990                     LD=: critic_missing="$critic_missing GNU ld")
 991 fi
 992
 993 # These programs are version sensitive.
 994 AC_CHECK_TOOL_PREFIX
 995 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
 996   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
 997   [[4-9].* | [1-9][0-9]*], critic_missing="$critic_missing make")
 998
 999 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
1000   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
1001   [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
1002   MSGFMT=: aux_missing="$aux_missing msgfmt")
1003 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
1004   [GNU texinfo.* \([0-9][0-9.]*\)],
1005   [4.[7-9]*|4.[1-9][0-9]*|[5-9].*],
1006   MAKEINFO=: aux_missing="$aux_missing makeinfo")
1007 AC_CHECK_PROG_VER(SED, sed, --version,
1008   [GNU sed[^0-9]* \([0-9]*\.[0-9.]*\)],
1009   [3.0[2-9]*|3.[1-9]*|[4-9]*],
1010   SED=: aux_missing="$aux_missing sed")
1011 AC_CHECK_PROG_VER(AWK, gawk, --version,
1012   [GNU Awk[^0-9]*\([0-9][0-9.]*\)],
1013   [3.1.[2-9]*|3.[2-9]*|[4-9]*], critic_missing="$critic_missing gawk")
1014 AC_CHECK_PROG_VER(BISON, bison, --version,
1015   [bison (GNU Bison) \([0-9]*\.[0-9.]*\)],
1016   [2.7*|[3-9].*|[1-9][0-9]*], critic_missing="$critic_missing bison")
1017
1018 AC_CACHE_CHECK([if $CC is sufficient to build libc], libc_cv_compiler_ok, [
1019 AC_TRY_COMPILE([], [
1020 #if !defined __GNUC__ || __GNUC__ < 6 || (__GNUC__ == 6 && __GNUC_MINOR__ < 2)
1021 #error insufficient compiler
1022 #endif],
1023                [libc_cv_compiler_ok=yes],
1024                [libc_cv_compiler_ok=no])])
1025 AS_IF([test $libc_cv_compiler_ok != yes],
1026       [critic_missing="$critic_missing compiler"])
1027
1028 AC_CHECK_TOOL(NM, nm, false)
1029
1030 if test "x$maintainer" = "xyes"; then
1031   AC_CHECK_PROGS(AUTOCONF, autoconf, no)
1032   case "x$AUTOCONF" in
1033   xno|x|x:) AUTOCONF=no ;;
1034   *)
1035     AC_CACHE_CHECK(dnl
1036   whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
1037     if (cd $srcdir; $AUTOCONF $ACFLAGS configure.ac > /dev/null 2>&1); then
1038       libc_cv_autoconf_works=yes
1039     else
1040       libc_cv_autoconf_works=no
1041     fi])
1042     test $libc_cv_autoconf_works = yes || AUTOCONF=no
1043     ;;
1044   esac
1045   if test "x$AUTOCONF" = xno; then
1046     aux_missing="$aux_missing autoconf"
1047   fi
1048 else
1049   AUTOCONF=no
1050 fi
1051
1052 # Check for python3 if available, or else python.
1053 AC_CHECK_PROG_VER(PYTHON_PROG, python3 python, --version,
1054   [Python \([0-9][0-9.]*\)],
1055   [3.[4-9]*|3.[1-9][0-9]*|[4-9].*|[1-9][0-9]*],
1056   critic_missing="$critic_missing python")
1057 PYTHON="$PYTHON_PROG -B"
1058 AC_SUBST(PYTHON)
1059
1060 test -n "$critic_missing" && AC_MSG_ERROR([
1061 *** These critical programs are missing or too old:$critic_missing
1062 *** Check the INSTALL file for required versions.])
1063
1064 test -n "$aux_missing" && AC_MSG_WARN([
1065 *** These auxiliary programs are missing or incompatible versions:$aux_missing
1066 *** some features or tests will be disabled.
1067 *** Check the INSTALL file for required versions.])
1068
1069 # if using special system headers, find out the compiler's sekrit
1070 # header directory and add that to the list.  NOTE: Only does the right
1071 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
1072 if test -n "$sysheaders"; then
1073   SYSINCLUDES=-nostdinc
1074   for d in include include-fixed; do
1075     i=`$CC -print-file-name="$d"` && test "x$i" != x && test "x$i" != "x$d" &&
1076     SYSINCLUDES="$SYSINCLUDES -isystem $i"
1077   done
1078   SYSINCLUDES="$SYSINCLUDES \
1079 -isystem `echo $sysheaders | sed 's/:/ -isystem /g'`"
1080   if test -n "$CXX"; then
1081     CXX_SYSINCLUDES=
1082     for cxxheaders in `$CXX -v -S -x c++ /dev/null -o /dev/null 2>&1 \
1083     | sed -n -e '1,/#include/d' -e 's/^ \(\/.*\/[cg]++\)/\1/p'`; do
1084       test "x$cxxheaders" != x &&
1085       CXX_SYSINCLUDES="$CXX_SYSINCLUDES -isystem $cxxheaders"
1086     done
1087   fi
1088 fi
1089 AC_SUBST(SYSINCLUDES)
1090 AC_SUBST(CXX_SYSINCLUDES)
1091
1092 # Obtain some C++ header file paths.  This is used to make a local
1093 # copy of those headers in Makerules.
1094 if test -n "$CXX"; then
1095   find_cxx_header () {
1096     echo "#include <$1>" | $CXX -M -MP -x c++ - 2>/dev/null \
1097          | sed -n "\,$1:,{s/:\$//;p}"
1098   }
1099   CXX_CSTDLIB_HEADER="$(find_cxx_header cstdlib)"
1100   CXX_CMATH_HEADER="$(find_cxx_header cmath)"
1101   CXX_BITS_STD_ABS_H="$(find_cxx_header bits/std_abs.h)"
1102 fi
1103 AC_SUBST(CXX_CSTDLIB_HEADER)
1104 AC_SUBST(CXX_CMATH_HEADER)
1105 AC_SUBST(CXX_BITS_STD_ABS_H)
1106
1107 # Test if LD_LIBRARY_PATH contains the notation for the current directory
1108 # since this would lead to problems installing/building glibc.
1109 # LD_LIBRARY_PATH contains the current directory if one of the following
1110 # is true:
1111 # - one of the terminals (":" and ";") is the first or last sign
1112 # - two terminals occur directly after each other
1113 # - the path contains an element with a dot in it
1114 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
1115 changequote(,)dnl
1116 case ${LD_LIBRARY_PATH} in
1117   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
1118     ld_library_path_setting="contains current directory"
1119     ;;
1120   *)
1121     ld_library_path_setting="ok"
1122     ;;
1123 esac
1124 changequote([,])dnl
1125 AC_MSG_RESULT($ld_library_path_setting)
1126 if test "$ld_library_path_setting" != "ok"; then
1127 AC_MSG_ERROR([
1128 *** LD_LIBRARY_PATH shouldn't contain the current directory when
1129 *** building glibc. Please change the environment variable
1130 *** and run configure again.])
1131 fi
1132
1133 AC_PATH_PROG(BASH_SHELL, bash, no)
1134
1135 AC_PATH_PROG(PERL, perl, no)
1136 if test "$PERL" != no &&
1137    (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
1138   PERL=no
1139 fi
1140 AC_PATH_PROG(INSTALL_INFO, install-info, no,
1141              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
1142
1143 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
1144 cat > conftest.s <<EOF
1145 .text
1146 foo:
1147 .set glibc_conftest_frobozz,foo
1148 .globl glibc_conftest_frobozz
1149 EOF
1150 # The alpha-dec-osf1 assembler gives only a warning for `.set'
1151 # (but it doesn't work), so we must do a linking check to be sure.
1152 cat > conftest1.c <<\EOF
1153 extern int glibc_conftest_frobozz;
1154 void _start() { glibc_conftest_frobozz = 1; }
1155 EOF
1156 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1157             -nostartfiles -nostdlib $no_ssp \
1158             -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1159   libc_cv_asm_set_directive=yes
1160 else
1161   libc_cv_asm_set_directive=no
1162 fi
1163 rm -f conftest*])
1164 if test $libc_cv_asm_set_directive = yes; then
1165   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
1166 fi
1167
1168 AC_CACHE_CHECK(linker support for protected data symbol,
1169                libc_cv_protected_data,
1170                [cat > conftest.c <<EOF
1171                 int bar __attribute__ ((visibility ("protected"))) = 1;
1172 EOF
1173                 libc_cv_protected_data=no
1174                 if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles $no_ssp -fPIC -shared conftest.c -o conftest.so); then
1175                   cat > conftest.c <<EOF
1176                   extern int bar;
1177                   int main (void) { return bar; }
1178 EOF
1179                   if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles $no_ssp conftest.c -o conftest conftest.so); then
1180                     libc_cv_protected_data=yes
1181                   fi
1182                 fi
1183                 rm -f conftest.*
1184                ])
1185 AC_SUBST(libc_cv_protected_data)
1186
1187 AC_CACHE_CHECK(linker support for INSERT in linker script,
1188                libc_cv_insert,
1189                [cat > conftest.c <<EOF
1190                 const int __attribute__ ((section(".bar"))) bar = 0x12345678;
1191                 int test (void) { return bar; }
1192 EOF
1193                 cat > conftest.t <<EOF
1194                 SECTIONS
1195                 {
1196                   .bar : { *(.bar) }
1197                 }
1198                 INSERT AFTER .rela.dyn;
1199 EOF
1200                 libc_cv_insert=no
1201                 if AC_TRY_COMMAND([${CC-cc} -nostdlib -nostartfiles $no_ssp -fPIC -shared conftest.c -Wl,-T,conftest.t -o conftest.so]); then
1202                   libc_cv_insert=yes
1203                 fi
1204                 rm -f conftest.*
1205                ])
1206 AC_SUBST(libc_cv_insert)
1207
1208 AC_CACHE_CHECK(for broken __attribute__((alias())),
1209                libc_cv_broken_alias_attribute,
1210                [cat > conftest.c <<EOF
1211                extern int foo (int x) __asm ("xyzzy");
1212                int bar (int x) { return x; }
1213                extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1214                extern int dfoo;
1215                extern __typeof (dfoo) dfoo __asm ("abccb");
1216                int dfoo = 1;
1217 EOF
1218                libc_cv_broken_alias_attribute=yes
1219                if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1220                  if grep 'xyzzy' conftest.s >/dev/null &&
1221                     grep 'abccb' conftest.s >/dev/null; then
1222                    libc_cv_broken_alias_attribute=no
1223                  fi
1224                fi
1225                rm -f conftest.c conftest.s
1226                ])
1227 if test $libc_cv_broken_alias_attribute = yes; then
1228   AC_MSG_ERROR(working alias attribute support required)
1229 fi
1230
1231 AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1232                libc_cv_have_sdata_section,
1233                [echo "int i;" > conftest.c
1234                 libc_cv_have_sdata_section=no
1235                 if ${CC-cc} $LDFLAGS -fPIC -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1236                    | grep '\.sdata' >/dev/null; then
1237                   libc_cv_have_sdata_section=yes
1238                 fi
1239                 rm -f conftest.c conftest.so
1240                ])
1241 if test $libc_cv_have_sdata_section = yes; then
1242   AC_DEFINE(HAVE_SDATA_SECTION)
1243 fi
1244
1245 AC_CACHE_CHECK(whether to use .ctors/.dtors header and trailer,
1246                libc_cv_ctors_header, [dnl
1247   libc_cv_ctors_header=yes
1248   LIBC_TRY_LINK_STATIC([
1249 __attribute__ ((constructor)) void ctor (void) { asm (""); }
1250 __attribute__ ((destructor))  void dtor (void) { asm (""); }
1251 ],
1252               [dnl
1253       AS_IF([$READELF -WS conftest$ac_exeext | $AWK '
1254         { gsub(/\@<:@ */, "@<:@") }
1255         $2 == ".ctors" || $2 == ".dtors" {
1256           size = strtonum("0x" $6)
1257           align = strtonum("0x" $NF)
1258           seen@<:@$2@:>@ = 1
1259           stub@<:@$2@:>@ = size == align * 2
1260         }
1261         END {
1262           ctors_ok = !seen@<:@".ctors"@:>@ || stub@<:@".ctors"@:>@
1263           dtors_ok = !seen@<:@".dtors"@:>@ || stub@<:@".dtors"@:>@
1264           exit ((ctors_ok && dtors_ok) ? 0 : 1)
1265         }
1266       '], [libc_cv_ctors_header=no])
1267     ], [dnl
1268       AC_MSG_ERROR([missing __attribute__ ((constructor)) support??])
1269     ])
1270 ])
1271 if test $libc_cv_ctors_header = no; then
1272   AC_DEFINE(NO_CTORS_DTORS_SECTIONS)
1273 fi
1274
1275 AC_CACHE_CHECK(for libunwind-support in compiler,
1276                libc_cv_cc_with_libunwind, [
1277   cat > conftest.c <<EOF
1278 int main (void) { return 0; }
1279 EOF
1280   if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static -o conftest \
1281      conftest.c -v 2>&1 >/dev/null | grep ' -lunwind ' >/dev/null; then
1282     libc_cv_cc_with_libunwind=yes
1283   else
1284     libc_cv_cc_with_libunwind=no
1285   fi
1286   rm -f conftest*])
1287 AC_SUBST(libc_cv_cc_with_libunwind)
1288 if test $libc_cv_cc_with_libunwind = yes; then
1289   AC_DEFINE(HAVE_CC_WITH_LIBUNWIND)
1290 fi
1291
1292 ASFLAGS_config=
1293 AC_CACHE_CHECK(whether --noexecstack is desirable for .S files,
1294                libc_cv_as_noexecstack, [dnl
1295 cat > conftest.c <<EOF
1296 void foo (void) { }
1297 EOF
1298 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS
1299                    -S -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD]) \
1300    && grep .note.GNU-stack conftest.s >/dev/null \
1301    && AC_TRY_COMMAND([${CC-cc} $ASFLAGS -Wa,--noexecstack
1302                       -c -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
1303 then
1304   libc_cv_as_noexecstack=yes
1305 else
1306   libc_cv_as_noexecstack=no
1307 fi
1308 rm -f conftest*])
1309 if test $libc_cv_as_noexecstack = yes; then
1310   ASFLAGS_config="$ASFLAGS_config -Wa,--noexecstack"
1311 fi
1312 AC_SUBST(ASFLAGS_config)
1313
1314 AC_CACHE_CHECK(for -z combreloc,
1315                libc_cv_z_combreloc, [dnl
1316 cat > conftest.c <<EOF
1317 extern int bar (int);
1318 extern int mumble;
1319 int foo (void) { return bar (mumble); }
1320 EOF
1321 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1322                         -fPIC -shared $no_ssp -o conftest.so conftest.c
1323                         -nostdlib -nostartfiles
1324                         -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1325 then
1326 dnl The following test is a bit weak.  We must use a tool which can test
1327 dnl cross-platform since the gcc used can be a cross compiler.  Without
1328 dnl introducing new options this is not easily doable.  Instead use a tool
1329 dnl which always is cross-platform: readelf.  To detect whether -z combreloc
1330 dnl look for a section named .rel.dyn or .rela.dyn.
1331   if $READELF -S conftest.so | grep -E '.rela?.dyn' > /dev/null; then
1332     libc_cv_z_combreloc=yes
1333   else
1334     libc_cv_z_combreloc=no
1335   fi
1336 else
1337   libc_cv_z_combreloc=no
1338 fi
1339 rm -f conftest*])
1340 if test "$libc_cv_z_combreloc" = yes; then
1341   AC_DEFINE(HAVE_Z_COMBRELOC)
1342 fi
1343 AC_SUBST(libc_cv_z_combreloc)
1344
1345 LIBC_LINKER_FEATURE([-z execstack], [-Wl,-z,execstack],
1346                     [libc_cv_z_execstack=yes], [libc_cv_z_execstack=no])
1347 AC_SUBST(libc_cv_z_execstack)
1348
1349 LIBC_LINKER_FEATURE([--no-dynamic-linker],
1350                     [-Wl,--no-dynamic-linker],
1351                     [libc_cv_no_dynamic_linker=yes],
1352                     [libc_cv_no_dynamic_linker=no])
1353 LIBC_CONFIG_VAR([have-no-dynamic-linker], [$libc_cv_no_dynamic_linker])
1354
1355 AC_CACHE_CHECK(for -static-pie, libc_cv_static_pie, [dnl
1356 LIBC_TRY_CC_OPTION([-static-pie],
1357                    [libc_cv_static_pie=yes],
1358                    [libc_cv_static_pie=no])
1359 ])
1360 LIBC_CONFIG_VAR([have-static-pie], [$libc_cv_static_pie])
1361
1362 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
1363 LIBC_TRY_CC_OPTION([-fpie], [libc_cv_fpie=yes], [libc_cv_fpie=no])
1364 ])
1365
1366 AC_SUBST(libc_cv_fpie)
1367
1368 AC_CACHE_CHECK(for --hash-style option,
1369                libc_cv_hashstyle, [dnl
1370 cat > conftest.c <<EOF
1371 int _start (void) { return 42; }
1372 EOF
1373 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS $no_ssp
1374                             -fPIC -shared -o conftest.so conftest.c
1375                             -Wl,--hash-style=both -nostdlib 1>&AS_MESSAGE_LOG_FD])
1376 then
1377   libc_cv_hashstyle=yes
1378 else
1379   libc_cv_hashstyle=no
1380 fi
1381 rm -f conftest*])
1382 AC_SUBST(libc_cv_hashstyle)
1383
1384 # The linker's default -shared behavior is good enough if it
1385 # does these things that our custom linker scripts ensure that
1386 # all allocated NOTE sections come first.
1387 if test "$use_default_link" = default; then
1388   AC_CACHE_CHECK([for sufficient default -shared layout],
1389                   libc_cv_use_default_link, [dnl
1390   libc_cv_use_default_link=no
1391   cat > conftest.s <<\EOF
1392           .section .note.a,"a",%note
1393           .balign 4
1394           .long 4,4,9
1395           .string "GNU"
1396           .string "foo"
1397           .section .note.b,"a",%note
1398           .balign 4
1399           .long 4,4,9
1400           .string "GNU"
1401           .string "bar"
1402 EOF
1403   if AC_TRY_COMMAND([dnl
1404   ${CC-cc} $ASFLAGS -shared -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD]) &&
1405        ac_try=`$READELF -S conftest.so | sed -n \
1406          ['${x;p;}
1407           s/^ *\[ *[1-9][0-9]*\]  *\([^ ][^ ]*\)  *\([^ ][^ ]*\) .*$/\2 \1/
1408           t a
1409           b
1410           : a
1411           H']`
1412   then
1413     libc_seen_a=no libc_seen_b=no
1414     set -- $ac_try
1415     while test $# -ge 2 -a "$1" = NOTE; do
1416       case "$2" in
1417       .note.a) libc_seen_a=yes ;;
1418       .note.b) libc_seen_b=yes ;;
1419       esac
1420       shift 2
1421     done
1422     case "$libc_seen_a$libc_seen_b" in
1423     yesyes)
1424       libc_cv_use_default_link=yes
1425       ;;
1426     *)
1427       echo >&AS_MESSAGE_LOG_FD "\
1428 $libc_seen_a$libc_seen_b from:
1429 $ac_try"
1430       ;;
1431     esac
1432   fi
1433   rm -f conftest*])
1434   use_default_link=$libc_cv_use_default_link
1435 fi
1436
1437 AC_CACHE_CHECK(for GLOB_DAT reloc,
1438                libc_cv_has_glob_dat, [dnl
1439 cat > conftest.c <<EOF
1440 extern int mumble;
1441 int foo (void) { return mumble; }
1442 EOF
1443 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1444                         -fPIC -shared -o conftest.so conftest.c
1445                         -nostdlib -nostartfiles $no_ssp
1446                         1>&AS_MESSAGE_LOG_FD])
1447 then
1448 dnl look for GLOB_DAT relocation.
1449   if $READELF -rW conftest.so | grep '_GLOB_DAT' > /dev/null; then
1450     libc_cv_has_glob_dat=yes
1451   else
1452     libc_cv_has_glob_dat=no
1453   fi
1454 else
1455   libc_cv_has_glob_dat=no
1456 fi
1457 rm -f conftest*])
1458 AC_SUBST(libc_cv_has_glob_dat)
1459
1460 AC_CACHE_CHECK(linker output format, libc_cv_output_format, [dnl
1461 if libc_cv_output_format=`
1462 ${CC-cc} -nostartfiles -nostdlib $no_ssp -Wl,--print-output-format 2>&AS_MESSAGE_LOG_FD`
1463 then
1464   :
1465 else
1466   libc_cv_output_format=
1467 fi
1468 test -n "$libc_cv_output_format" || libc_cv_output_format=unknown])
1469 AC_SUBST(libc_cv_output_format)
1470
1471 AC_CACHE_CHECK(for -fno-toplevel-reorder -fno-section-anchors, libc_cv_fno_toplevel_reorder, [dnl
1472 cat > conftest.c <<EOF
1473 int foo;
1474 EOF
1475 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fno-toplevel-reorder -fno-section-anchors
1476                             conftest.c 1>&AS_MESSAGE_LOG_FD])
1477 then
1478   libc_cv_fno_toplevel_reorder=yes
1479 else
1480   libc_cv_fno_toplevel_reorder=no
1481 fi
1482 rm -f conftest*])
1483 if test $libc_cv_fno_toplevel_reorder = yes; then
1484   fno_unit_at_a_time="-fno-toplevel-reorder -fno-section-anchors"
1485 else
1486   fno_unit_at_a_time=-fno-unit-at-a-time
1487 fi
1488 AC_SUBST(fno_unit_at_a_time)
1489
1490 AC_CACHE_CHECK([for -mtls-dialect=gnu2], libc_cv_mtls_dialect_gnu2,
1491 [dnl
1492 cat > conftest.c <<EOF
1493 __thread int i;
1494 void foo (void)
1495 {
1496   i = 10;
1497 }
1498 EOF
1499 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fPIC -mtls-dialect=gnu2
1500                    conftest.c 1>&AS_MESSAGE_LOG_FD])
1501 then
1502   libc_cv_mtls_dialect_gnu2=yes
1503 else
1504   libc_cv_mtls_dialect_gnu2=no
1505 fi
1506 rm -f conftest*])
1507 AC_SUBST(libc_cv_mtls_dialect_gnu2)
1508 LIBC_CONFIG_VAR([have-mtls-dialect-gnu2], [$libc_cv_mtls_dialect_gnu2])
1509
1510 AC_CACHE_CHECK(whether cc puts quotes around section names,
1511                libc_cv_have_section_quotes,
1512                [cat > conftest.c <<EOF
1513                 static const int foo
1514                 __attribute__ ((section ("bar"))) = 1;
1515 EOF
1516                 if ${CC-cc} -S conftest.c -o conftest.s; then
1517                   if grep '\.section.*"bar"' conftest.s >/dev/null; then
1518                     libc_cv_have_section_quotes=yes
1519                   else
1520                     libc_cv_have_section_quotes=no
1521                   fi
1522                 else
1523                   libc_cv_have_section_quotes=unknown
1524                 fi
1525                 rm -f conftest.{c,s}
1526                 ])
1527 if test $libc_cv_have_section_quotes = yes; then
1528   AC_DEFINE(HAVE_SECTION_QUOTES)
1529 fi
1530
1531 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
1532 cat > conftest.c <<\EOF
1533 void zero (void *x)
1534 {
1535   __builtin_memset (x, 0, 1000);
1536 }
1537 EOF
1538 dnl
1539 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | grep -F "memset" > /dev/null]);
1540 then
1541   libc_cv_gcc_builtin_memset=no
1542 else
1543   libc_cv_gcc_builtin_memset=yes
1544 fi
1545 rm -f conftest* ])
1546 if test "$libc_cv_gcc_builtin_memset" = yes ; then
1547   AC_DEFINE(HAVE_BUILTIN_MEMSET)
1548 fi
1549
1550 AC_CACHE_CHECK(for redirection of built-in functions, libc_cv_gcc_builtin_redirection, [dnl
1551 cat > conftest.c <<\EOF
1552 extern char *strstr (const char *, const char *) __asm ("my_strstr");
1553 char *foo (const char *a, const char *b)
1554 {
1555   return __builtin_strstr (a, b);
1556 }
1557 EOF
1558 dnl
1559 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | grep -F "my_strstr" > /dev/null]);
1560 then
1561   libc_cv_gcc_builtin_redirection=yes
1562 else
1563   libc_cv_gcc_builtin_redirection=no
1564 fi
1565 rm -f conftest* ])
1566 if test "$libc_cv_gcc_builtin_redirection" = no; then
1567   AC_MSG_ERROR([support for the symbol redirection needed])
1568 fi
1569
1570 dnl Determine how to disable generation of FMA instructions.
1571 AC_CACHE_CHECK([for compiler option to disable generation of FMA instructions],
1572                libc_cv_cc_nofma, [dnl
1573 libc_cv_cc_nofma=
1574 for opt in -ffp-contract=off -mno-fused-madd; do
1575   LIBC_TRY_CC_OPTION([$opt], [libc_cv_cc_nofma=$opt; break])
1576 done])
1577 AC_SUBST(libc_cv_cc_nofma)
1578
1579 if test -n "$submachine"; then
1580   AC_CACHE_CHECK([for compiler option for CPU variant],
1581                  libc_cv_cc_submachine, [dnl
1582   libc_cv_cc_submachine=no
1583   for opt in "-march=$submachine" "-mcpu=$submachine"; do
1584     LIBC_TRY_CC_OPTION([$opt], [
1585       libc_cv_cc_submachine="$opt"
1586       break], [])
1587   done])
1588   if test "x$libc_cv_cc_submachine" = xno; then
1589     AC_MSG_ERROR([${CC-cc} does not support $submachine])
1590   fi
1591 fi
1592 AC_SUBST(libc_cv_cc_submachine)
1593
1594 AC_CACHE_CHECK(if $CC accepts -fno-tree-loop-distribute-patterns with \
1595 __attribute__ ((__optimize__)), libc_cv_cc_loop_to_function, [dnl
1596 cat > conftest.c <<EOF
1597 void
1598 __attribute__ ((__optimize__ ("-fno-tree-loop-distribute-patterns")))
1599 foo (void) {}
1600 EOF
1601 libc_cv_cc_loop_to_function=no
1602 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c])
1603 then
1604   libc_cv_cc_loop_to_function=yes
1605 fi
1606 rm -f conftest*])
1607 if test $libc_cv_cc_loop_to_function = yes; then
1608   AC_DEFINE(HAVE_CC_INHIBIT_LOOP_TO_LIBCALL)
1609 fi
1610 AC_SUBST(libc_cv_cc_loop_to_function)
1611
1612 dnl Check whether we have the gd library available.
1613 AC_MSG_CHECKING(for libgd)
1614 if test "$with_gd" != "no"; then
1615   old_CFLAGS="$CFLAGS"
1616   CFLAGS="$CFLAGS $libgd_include"
1617   old_LDFLAGS="$LDFLAGS"
1618   LDFLAGS="$LDFLAGS $libgd_ldflags"
1619   old_LIBS="$LIBS"
1620   LIBS="$LIBS -lgd -lpng -lz -lm"
1621   AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1622   CFLAGS="$old_CFLAGS"
1623   LDFLAGS="$old_LDFLAGS"
1624   LIBS="$old_LIBS"
1625 else
1626   LIBGD=no
1627 fi
1628 AC_MSG_RESULT($LIBGD)
1629 AC_SUBST(LIBGD)
1630
1631 # SELinux detection
1632 if test x$with_selinux = xno ; then
1633   have_selinux=no;
1634 else
1635   # See if we have the SELinux library
1636   AC_CHECK_LIB(selinux, is_selinux_enabled,
1637                have_selinux=yes, have_selinux=no)
1638   if test x$with_selinux = xyes ; then
1639     if test x$have_selinux = xno ; then
1640       AC_MSG_ERROR([SELinux explicitly required, but SELinux library not found])
1641     fi
1642   fi
1643 fi
1644 # Check if we're building with SELinux support.
1645 if test "x$have_selinux" = xyes; then
1646   AC_DEFINE(HAVE_SELINUX, 1, [SELinux support])
1647
1648   # See if we have the libaudit library
1649   AC_CHECK_LIB(audit, audit_log_user_avc_message,
1650                have_libaudit=yes, have_libaudit=no)
1651   if test "x$have_libaudit" = xyes; then
1652     AC_DEFINE(HAVE_LIBAUDIT, 1, [SELinux libaudit support])
1653   fi
1654   AC_SUBST(have_libaudit)
1655
1656   # See if we have the libcap library
1657   AC_CHECK_LIB(cap, cap_init, have_libcap=yes, have_libcap=no)
1658   if test "x$have_libcap" = xyes; then
1659     AC_DEFINE(HAVE_LIBCAP, 1, [SELinux libcap support])
1660   fi
1661   AC_SUBST(have_libcap)
1662 fi
1663 AC_SUBST(have_selinux)
1664
1665 CPPUNDEFS=
1666 dnl Check for silly hacked compilers predefining _FORTIFY_SOURCE.
1667 dnl Since we are building the implementations of the fortified functions here,
1668 dnl having the macro defined interacts very badly.
1669 AC_CACHE_CHECK([for _FORTIFY_SOURCE predefine], libc_cv_predef_fortify_source,
1670 [AC_TRY_COMPILE([], [
1671 #ifdef _FORTIFY_SOURCE
1672 # error bogon
1673 #endif],
1674                 [libc_cv_predef_fortify_source=no],
1675                 [libc_cv_predef_fortify_source=yes])])
1676 if test $libc_cv_predef_fortify_source = yes; then
1677   CPPUNDEFS="${CPPUNDEFS:+$CPPUNDEFS }-U_FORTIFY_SOURCE"
1678 fi
1679 AC_SUBST(CPPUNDEFS)
1680
1681 # Some linkers on some architectures support __ehdr_start but with
1682 # bugs.  Make sure usage of it does not create relocations in the
1683 # output (as the linker should resolve them all for us).
1684 AC_CACHE_CHECK([whether the linker provides working __ehdr_start],
1685                libc_cv_ehdr_start, [
1686 old_CFLAGS="$CFLAGS"
1687 old_LDFLAGS="$LDFLAGS"
1688 old_LIBS="$LIBS"
1689 CFLAGS="$CFLAGS -fPIC"
1690 LDFLAGS="$LDFLAGS -nostdlib -nostartfiles -shared $no_ssp"
1691 LIBS=
1692 AC_LINK_IFELSE([AC_LANG_SOURCE([
1693 typedef struct {
1694   char foo;
1695   long val;
1696 } Ehdr;
1697 extern const Ehdr __ehdr_start __attribute__ ((visibility ("hidden")));
1698 long ehdr (void) { return __ehdr_start.val; }
1699 ])],
1700                [if $READELF -r conftest | grep -F __ehdr_start >/dev/null; then
1701                   libc_cv_ehdr_start=broken
1702                 else
1703                   libc_cv_ehdr_start=yes
1704                 fi], [libc_cv_ehdr_start=no])
1705 CFLAGS="$old_CFLAGS"
1706 LDFLAGS="$old_LDFLAGS"
1707 LIBS="$old_LIBS"
1708 ])
1709 if test "$libc_cv_ehdr_start" = yes; then
1710   AC_DEFINE([HAVE_EHDR_START])
1711 elif test "$libc_cv_ehdr_start" = broken; then
1712   AC_MSG_WARN([linker is broken -- you should upgrade])
1713 fi
1714
1715 AC_CACHE_CHECK(for __builtin_trap with no external dependencies,
1716                libc_cv_builtin_trap, [dnl
1717 libc_cv_builtin_trap=no
1718 AC_TRY_COMPILE([], [__builtin_trap ()], [
1719 libc_undefs=`$NM -u conftest.o |
1720   LC_ALL=C $AWK '$1 == "U" { print $2 | "sort -u"; next } { exit(1) }' \
1721     2>&AS_MESSAGE_LOG_FD` || {
1722   AC_MSG_ERROR([confusing output from $NM -u])
1723 }
1724 echo >&AS_MESSAGE_LOG_FD "libc_undefs='$libc_undefs'"
1725 if test -z "$libc_undefs"; then
1726   libc_cv_builtin_trap=yes
1727 fi])])
1728 if test $libc_cv_builtin_trap = yes; then
1729   AC_DEFINE([HAVE_BUILTIN_TRAP])
1730 fi
1731
1732 dnl C++ feature tests.
1733 AC_LANG_PUSH([C++])
1734
1735 AC_CACHE_CHECK([whether the C++ compiler supports thread_local],
1736                libc_cv_cxx_thread_local, [
1737 old_CXXFLAGS="$CXXFLAGS"
1738 CXXFLAGS="$CXXFLAGS -std=gnu++11"
1739 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1740 #include <thread>
1741
1742 // Compiler support.
1743 struct S
1744 {
1745   S ();
1746   ~S ();
1747 };
1748 thread_local S s;
1749 S * get () { return &s; }
1750
1751 // libstdc++ support.
1752 #ifndef _GLIBCXX_HAVE___CXA_THREAD_ATEXIT_IMPL
1753 #error __cxa_thread_atexit_impl not supported
1754 #endif
1755 ])],
1756                [libc_cv_cxx_thread_local=yes],
1757                [libc_cv_cxx_thread_local=no])
1758 CXXFLAGS="$old_CXXFLAGS"
1759 ])
1760 AC_SUBST(libc_cv_cxx_thread_local)
1761
1762 AC_LANG_POP([C++])
1763 dnl End of C++ feature tests.
1764
1765 ### End of automated tests.
1766 ### Now run sysdeps configure fragments.
1767
1768 # They also can set these variables.
1769 use_ldconfig=no
1770 ldd_rewrite_script=no
1771 libc_cv_sysconfdir=$sysconfdir
1772 libc_cv_localstatedir=$localstatedir
1773 libc_cv_gcc_unwind_find_fde=no
1774 libc_cv_idn=no
1775
1776 # Iterate over all the sysdep directories we will use, running their
1777 # configure fragments.
1778 for dir in $sysnames; do
1779   case $dir in
1780     /*) dest=$dir ;;
1781     *)  dest=$srcdir/$dir ;;
1782   esac
1783   if test -r $dest/configure; then
1784     AC_MSG_RESULT(running configure fragment for $dir)
1785     . $dest/configure
1786   fi
1787 done
1788
1789 if test x"$build_mathvec" = xnotset; then
1790   build_mathvec=no
1791 fi
1792 LIBC_CONFIG_VAR([build-mathvec], [$build_mathvec])
1793
1794 AC_SUBST(libc_extra_cflags)
1795 AC_SUBST(libc_extra_cppflags)
1796
1797 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
1798   AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
1799 fi
1800 AC_SUBST(libc_cv_gcc_unwind_find_fde)
1801
1802 # A sysdeps configure fragment can reset this if IFUNC is not actually
1803 # usable even though the assembler knows how to generate the symbol type.
1804 if test x"$libc_cv_ld_gnu_indirect_function" = xyes; then
1805   AC_DEFINE(HAVE_IFUNC)
1806 fi
1807 LIBC_CONFIG_VAR([have-ifunc], [$libc_cv_ld_gnu_indirect_function])
1808
1809 if test x"$libc_cv_gcc_indirect_function" = xyes; then
1810   AC_DEFINE(HAVE_GCC_IFUNC)
1811 fi
1812
1813 # This is far from the AC_ARG_ENABLE that sets it so that a sysdeps
1814 # configure fragment can override the value to prevent this AC_DEFINE.
1815 AC_SUBST(use_nscd)
1816 if test "x$use_nscd" != xno; then
1817   AC_DEFINE([USE_NSCD])
1818 fi
1819 if test "x$build_nscd" = xdefault; then
1820   build_nscd=$use_nscd
1821 fi
1822
1823 AC_SUBST(libc_cv_slibdir)
1824 AC_SUBST(libc_cv_rtlddir)
1825 AC_SUBST(libc_cv_complocaledir)
1826 AC_SUBST(libc_cv_sysconfdir)
1827 AC_SUBST(libc_cv_localstatedir)
1828 AC_SUBST(libc_cv_rootsbindir)
1829
1830 if test x$use_ldconfig = xyes; then
1831   AC_DEFINE(USE_LDCONFIG)
1832 fi
1833 AC_SUBST(use_ldconfig)
1834 AC_SUBST(ldd_rewrite_script)
1835
1836 AC_SUBST(static)
1837 AC_SUBST(shared)
1838
1839 AC_CACHE_CHECK([whether -fPIC is default], libc_cv_pic_default,
1840 [libc_cv_pic_default=yes
1841 cat > conftest.c <<EOF
1842 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1843 # error PIC is default.
1844 #endif
1845 EOF
1846 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1847   libc_cv_pic_default=no
1848 fi
1849 rm -f conftest.*])
1850 AC_SUBST(libc_cv_pic_default)
1851
1852 AC_CACHE_CHECK([whether -fPIE is default], libc_cv_cc_pie_default,
1853 [libc_cv_cc_pie_default=yes
1854 cat > conftest.c <<EOF
1855 #if defined __PIE__ || defined __pie__ || defined PIE || defined pie
1856 # error PIE is default.
1857 #endif
1858 EOF
1859 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1860   libc_cv_cc_pie_default=no
1861 fi
1862 rm -f conftest.*])
1863 libc_cv_pie_default=$libc_cv_cc_pie_default
1864 AC_SUBST(libc_cv_cc_pie_default)
1865 AC_SUBST(libc_cv_pie_default)
1866
1867 # Set the `multidir' variable by grabbing the variable from the compiler.
1868 # We do it once and save the result in a generated makefile.
1869 libc_cv_multidir=`${CC-cc} $CFLAGS $CPPFLAGS -print-multi-directory`
1870 AC_SUBST(libc_cv_multidir)
1871
1872 if test "$static_pie" = yes; then
1873   # The linker must support --no-dynamic-linker.
1874   if test "$libc_cv_no_dynamic_linker" != yes; then
1875     AC_MSG_ERROR([linker support for --no-dynamic-linker needed])
1876   fi
1877   # Default to PIE.
1878   libc_cv_pie_default=yes
1879   AC_DEFINE(ENABLE_STATIC_PIE)
1880 fi
1881 LIBC_CONFIG_VAR([enable-static-pie], [$static_pie])
1882
1883 AC_SUBST(profile)
1884 AC_SUBST(static_nss)
1885
1886 AC_SUBST(DEFINES)
1887
1888 dnl See sysdeps/mach/configure.ac for this variable.
1889 AC_SUBST(mach_interface_list)
1890
1891 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1892 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1893 AC_SUBST(VERSION)
1894 AC_SUBST(RELEASE)
1895
1896 AC_CONFIG_FILES([config.make Makefile])
1897 AC_CONFIG_COMMANDS([default],[[
1898 case $CONFIG_FILES in *config.make*)
1899 echo "$config_vars" >> config.make;;
1900 esac
1901 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
1902 AC_OUTPUT