sysdeps/s390/s390-64/setjmp.S

   1 /* setjmp for 64 bit S/390, ELF version.
   2    Copyright (C) 2001-2014 Free Software Foundation, Inc.
   3    Contributed by Martin Schwidefsky (schwidefsky@de.ibm.com).
   4    This file is part of the GNU C Library.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 #include <sysdep.h>
  21 #define _ASM
  22 #define _SETJMP_H
  23 #include <bits/setjmp.h>
  24 #include <shlib-compat.h>
  25
  26 #if !defined IS_IN_rtld
  27 # if defined SHARED &&  SHLIB_COMPAT (libc, GLIBC_2_19, GLIBC_2_20)
  28         /* we need a unique name in case of symbol versioning.  */
  29 #  define __sigsetjmp __v1__sigsetjmp
  30 # endif /* if defined SHARED && SHLIB_COMPAT (libc, GLIBC_2_19, GLIBC_2_20)  */
  31 #endif /* !defined IS_IN_rtld  */
  32
  33         /* We include the BSD entry points here as well but we make
  34            them weak.  */
  35 ENTRY (setjmp)
  36         .weak C_SYMBOL_NAME (setjmp)
  37         lghi   %r3,1                /* Second argument of one.  */
  38         j      .Linternal_sigsetjmp /* Branch relativ to __sigsetjmp.  */
  39 END (setjmp)
  40
  41         /* Binary compatibility entry point.  */
  42 ENTRY(_setjmp)
  43         .weak  C_SYMBOL_NAME (_setjmp)
  44         slgr   %r3,%r3              /* Second argument of zero.  */
  45         j      .Linternal_sigsetjmp /* Branch relativ to __sigsetjmp.  */
  46 END (_setjmp)
  47 libc_hidden_def (_setjmp)
  48
  49 ENTRY(__setjmp)
  50         slgr   %r3,%r3              /* Second argument of zero.  */
  51         j      .Linternal_sigsetjmp /* Branch relativ to __sigsetjmp.  */
  52 END (__setjmp)
  53
  54 ENTRY(__sigsetjmp)
  55 .Linternal_sigsetjmp:
  56 #ifdef PTR_MANGLE
  57         stmg   %r6,%r13,0(%r2)      /* Store registers in jmp_buf.  */
  58         lgr    %r4,%r14
  59         lgr    %r5,%r15
  60         PTR_MANGLE (%r4, %r1)
  61         PTR_MANGLE2 (%r5, %r1)
  62         stmg   %r4,%r5,64(%r2)
  63 #else
  64         stmg   %r6,%r15,0(%r2)      /* Store registers in jmp_buf.  */
  65 #endif
  66         std    %f8,80(%r2)
  67         std    %f9,88(%r2)
  68         std    %f10,96(%r2)
  69         std    %f11,104(%r2)
  70         std    %f12,112(%r2)
  71         std    %f13,120(%r2)
  72         std    %f14,128(%r2)
  73         std    %f15,136(%r2)
  74 #ifdef IS_IN_rtld
  75         /* In ld.so we never save the signal mask.  */
  76         lghi   %r2,0
  77         br     %r14
  78 #elif defined PIC
  79         jg     __sigjmp_save@PLT    /* Branch to PLT of __sigsetjmp.  */
  80 #else
  81         jg     __sigjmp_save
  82 #endif
  83 END (__sigsetjmp)
  84
  85 #if !defined IS_IN_rtld
  86 # if defined SHARED &&  SHLIB_COMPAT (libc, GLIBC_2_19, GLIBC_2_20)
  87 /* In glibc release 2.19 new versions of setjmp-functions were introduced,
  88    but were reverted before 2.20. Thus both versions are the same function.  */
  89
  90 #  undef __sigsetjmp
  91
  92 weak_alias (setjmp, __v1setjmp);
  93 weak_alias (setjmp, __v2setjmp);
  94 versioned_symbol (libc, __v1setjmp, setjmp, GLIBC_2_0);
  95 compat_symbol (libc, __v2setjmp, setjmp, GLIBC_2_19);
  96
  97 weak_alias (_setjmp, __v1_setjmp);
  98 weak_alias (_setjmp, __v2_setjmp);
  99 versioned_symbol (libc, __v1_setjmp, _setjmp, GLIBC_2_0);
 100 compat_symbol (libc, __v2_setjmp, _setjmp, GLIBC_2_19);
 101
 102 strong_alias (__v1__sigsetjmp, __v2__sigsetjmp);
 103 versioned_symbol (libc, __v1__sigsetjmp, __sigsetjmp, GLIBC_2_0);
 104 compat_symbol (libc, __v2__sigsetjmp, __sigsetjmp, GLIBC_2_19);
 105 # endif /* if defined SHARED && SHLIB_COMPAT (libc, GLIBC_2_19, GLIBC_2_20)  */
 106 #endif /* if !defined IS_IN_rtld  */