sysdeps/unix/sysv/linux/i386/setcontext.S

   1 /* Install given context.
   2    Copyright (C) 2001, 2002, 2003, 2005 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Ulrich Drepper <drepper@redhat.com>, 2001.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, write to the Free
  18    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  19    02111-1307 USA.  */
  20
  21 #include <sysdep.h>
  22
  23 #include "ucontext_i.h"
  24
  25
  26 ENTRY(__setcontext)
  27         /* Load address of the context data structure.  */
  28         movl    4(%esp), %eax
  29
  30         /* Get the current signal mask.  Note that we preserve EBX in case
  31            the system call fails and we return from the function with an
  32            error.  */
  33         pushl   %ebx
  34         cfi_adjust_cfa_offset (4)
  35         xorl    %edx, %edx
  36         leal    oSIGMASK(%eax), %ecx
  37         movl    $SIG_SETMASK, %ebx
  38         cfi_rel_offset (ebx, 0)
  39         movl    $__NR_sigprocmask, %eax
  40         ENTER_KERNEL
  41         popl    %ebx
  42         cfi_adjust_cfa_offset (-4)
  43         cfi_restore (ebx)
  44         cmpl    $-4095, %eax            /* Check %eax for error.  */
  45         jae     SYSCALL_ERROR_LABEL     /* Jump to error handler if error.  */
  46
  47         /* EAX was modified, reload it.  */
  48         movl    4(%esp), %eax
  49
  50         /* Restore the floating-point context.  Not the registers, only the
  51            rest.  */
  52         movl    oFPREGS(%eax), %ecx
  53         fldenv  (%ecx)
  54
  55         /* Restore the FS segment register.  We don't touch the GS register
  56            since it is used for threads.  */
  57         movl    oFS(%eax), %ecx
  58         movw    %cx, %fs
  59
  60         /* Fetch the address to return to.  */
  61         movl    oEIP(%eax), %ecx
  62
  63         /* Load the new stack pointer.  */
  64         movl    oESP(%eax), %esp
  65
  66         /* Push the return address on the new stack so we can return there.  */
  67         pushl   %ecx
  68
  69         /* Load the values of all the 32-bit registers (except ESP).
  70            Since we are loading from EAX, it must be last.  */
  71         movl    oEDI(%eax), %edi
  72         movl    oESI(%eax), %esi
  73         movl    oEBP(%eax), %ebp
  74         movl    oEBX(%eax), %ebx
  75         movl    oEDX(%eax), %edx
  76         movl    oECX(%eax), %ecx
  77         movl    oEAX(%eax), %eax
  78
  79         /* The following 'ret' will pop the address of the code and jump
  80            to it.  */
  81
  82 L(pseudo_end):
  83         ret
  84 PSEUDO_END(__setcontext)
  85
  86 weak_alias(__setcontext, setcontext)