sysdeps/ia64/fpu/s_significandf.S

   1 .file "significandf.s"
   2
   3
   4 // Copyright (c) 2000 - 2003, Intel Corporation
   5 // All rights reserved.
   6 //
   7 //
   8 // Redistribution and use in source and binary forms, with or without
   9 // modification, are permitted provided that the following conditions are
  10 // met:
  11 //
  12 // * Redistributions of source code must retain the above copyright
  13 // notice, this list of conditions and the following disclaimer.
  14 //
  15 // * Redistributions in binary form must reproduce the above copyright
  16 // notice, this list of conditions and the following disclaimer in the
  17 // documentation and/or other materials provided with the distribution.
  18 //
  19 // * The name of Intel Corporation may not be used to endorse or promote
  20 // products derived from this software without specific prior written
  21 // permission.
  22
  23 // THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  24 // "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  25 // LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  26 // A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL INTEL OR ITS
  27 // CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
  28 // EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
  29 // PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
  30 // PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY
  31 // OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY OR TORT (INCLUDING
  32 // NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
  33 // SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  34 //
  35 // Intel Corporation is the author of this code, and requests that all
  36 // problem reports or change requests be submitted to it directly at
  37 // http://www.intel.com/software/products/opensource/libraries/num.htm.
  38 //
  39 // History
  40 //==============================================================
  41 // 02/02/00 Initial version
  42 // 02/03/00 Modified to improve speed
  43 // 05/31/00 Fixed bug when x a double-extended denormal
  44 // 05/20/02 Cleaned up namespace and sf0 syntax
  45 // 02/10/03 Reordered header: .section, .global, .proc, .align
  46 //
  47 // API
  48 //==============================================================
  49 // float significandf(float x)
  50 // Overview of operation
  51 //==============================================================
  52 // If x = sig * 2**n with 1 <= sig < 2
  53 // significandf returns sig
  54 //
  55 // predicate registers used:
  56 // p6, p7
  57 //
  58 // floating-point registers used:
  59 // f8, f9, f10
  60
  61 .section .text
  62 GLOBAL_LIBM_ENTRY(significandf)
  63
  64 // qnan snan inf norm     unorm 0 -+
  65 // 1    1    1   0        0     1 11
  66
  67 // f10 gets f8(sign) with f1(exp,significand)
  68 { .mfi
  69       nop.m 999
  70       fmerge.s       f10 = f8,f1
  71       nop.i 999
  72 }
  73 { .mfi
  74       nop.m 999
  75       fnorm.s0          f9  = f8
  76       nop.i 999 ;;
  77 }
  78
  79 // Test for denormal input
  80 { .mfi
  81       nop.m 999
  82       fclass.m.unc   p7,p0 = f8, 0x0b
  83       nop.i 999 ;;
  84 }
  85
  86 // p6 = TRUE ==> x is not (nan,inf,0)
  87 //               return sign(f8) exp(f1) significand(f8)
  88 // else          x is (nan,inf,0)
  89 //               return sign(f8) exp(f8) significand(f8), normalized.
  90 { .mfi
  91       nop.m 999
  92       fclass.m.unc   p0,p6 = f8, 0xe7
  93       nop.i 999 ;;
  94 }
  95
  96 { .mmb
  97       nop.m 999
  98       nop.m 999
  99 (p7)  br.cond.spnt SIGNIFICAND_DENORM ;; // Branch if x denormal
 100 }
 101
 102 { .mfi
 103       nop.m 999
 104 (p6)  fmerge.se      f8 = f10,f8
 105       nop.i 999 ;;
 106 }
 107
 108 { .mfb
 109       nop.m 999
 110       fnorm.s.s0        f8 = f8
 111       br.ret.sptk    b0 ;;
 112 }
 113
 114 SIGNIFICAND_DENORM:
 115 // Here if x denorm
 116 { .mfi
 117       nop.m 999
 118       fmerge.se      f8 = f10,f9
 119       nop.i 999 ;;
 120 }
 121
 122 // Check if fnorm(x) still denormal, means x double-extended denormal
 123 { .mfi
 124       nop.m 999
 125       fclass.m.unc   p7,p0 = f9, 0x0b
 126       nop.i 999 ;;
 127 }
 128
 129 // This will be the final result unless x double-extended denormal
 130 { .mfi
 131       nop.m 999
 132       fnorm.s.s0        f8 = f8
 133       nop.i 999 ;;
 134 }
 135
 136 // If x double-extended denorm, then significand ok, but must merge in
 137 //    correct signexp
 138 { .mfi
 139       nop.m 999
 140 (p7)  fmerge.se      f8 = f10,f8
 141       nop.i 999 ;;
 142 }
 143
 144 // Final normalization if x double-extended denorm
 145 { .mfb
 146       nop.m 999
 147 (p7)  fnorm.s.s0        f8 = f8
 148       br.ret.sptk    b0 ;;
 149 }
 150
 151 GLOBAL_LIBM_END(significandf)