sysdeps/i386/setjmp.S

   1 /* setjmp for i386.
   2    Copyright (C) 1995, 1996, 1997 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Library General Public License as
   7    published by the Free Software Foundation; either version 2 of the
   8    License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Library General Public License for more details.
  14
  15    You should have received a copy of the GNU Library General Public
  16    License along with the GNU C Library; see the file COPYING.LIB.  If not,
  17    write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  18    Boston, MA 02111-1307, USA.  */
  19
  20 #include <sysdep.h>
  21 #define _ASM
  22 #include <bits/setjmp.h>
  23 #include <asm-syntax.h>
  24
  25         /* Binary compatibility entry point.  */
  26 ENTRY (__setjmp)
  27         popl %eax               /* Pop return address.  */
  28         popl %ecx               /* Pop jmp_buf.  */
  29         pushl $0                /* Push zero argument.  */
  30         pushl %ecx              /* Push jmp_buf.  */
  31         pushl %eax              /* Push back return address.  */
  32
  33 ENTRY (__sigsetjmp)
  34         movl 4(%esp), %eax      /* User's jmp_buf in %eax.  */
  35         /* Save registers.  */
  36         movl %ebx, (JB_BX*4)(%eax)
  37         movl %esi, (JB_SI*4)(%eax)
  38         movl %edi, (JB_DI*4)(%eax)
  39         movl %ebp, (JB_BP*4)(%eax)
  40         leal 4(%esp), %ecx      /* Save SP as it will be after we return.  */
  41         movl %ecx, (JB_SP*4)(%eax)
  42         movl 0(%esp), %ecx      /* Save PC we are returning to now.  */
  43         movl %ecx, (JB_PC*4)(%eax)
  44
  45         /* Make a tail call to __sigjmp_save; it takes the same args.  */
  46 #ifdef  PIC
  47         /* We cannot use the PLT, because it requires that %ebx be set, but
  48            we can't save and restore our caller's value.  Instead, we do an
  49            indirect jump through the GOT, using for the temporary register
  50            %ecx, which is call-clobbered.  */
  51         call L(here)
  52 L(here):
  53         popl %ecx
  54         addl $_GLOBAL_OFFSET_TABLE_+[.-L(here)], %ecx
  55         movl C_SYMBOL_NAME(__sigjmp_save@GOT)(%ecx), %ecx
  56         jmp *%ecx
  57 #else
  58         jmp __sigjmp_save
  59 #endif
  60 END (__sigsetjmp)