sysdeps/sparc/sparc64/elf/start.S

   1 /* Startup code for elf64-sparc
   2    Copyright (C) 1997, 1998, 2002, 2004, 2007, 2009
   3    Free Software Foundation, Inc.
   4    This file is part of the GNU C Library.
   5    Contributed by Richard Henderson <richard@gnu.ai.mit.edu>, 1997.
   6
   7    The GNU C Library is free software; you can redistribute it and/or
   8    modify it under the terms of the GNU Lesser General Public
   9    License as published by the Free Software Foundation; either
  10    version 2.1 of the License, or (at your option) any later version.
  11
  12    In addition to the permissions in the GNU Lesser General Public
  13    License, the Free Software Foundation gives you unlimited
  14    permission to link the compiled version of this file with other
  15    programs, and to distribute those programs without any restriction
  16    coming from the use of this file. (The GNU Lesser General Public
  17    License restrictions do apply in other respects; for example, they
  18    cover modification of the file, and distribution when not linked
  19    into another program.)
  20
  21    Note that people who make modified versions of this file are not
  22    obligated to grant this special exception for their modified
  23    versions; it is their choice whether to do so. The GNU Lesser
  24    General Public License gives permission to release a modified
  25    version without this exception; this exception also makes it
  26    possible to release a modified version which carries forward this
  27    exception.
  28
  29    The GNU C Library is distributed in the hope that it will be useful,
  30    but WITHOUT ANY WARRANTY; without even the implied warranty of
  31    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  32    Lesser General Public License for more details.
  33
  34    You should have received a copy of the GNU Lesser General Public
  35    License along with the GNU C Library; if not, write to the Free
  36    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  37    02111-1307 USA.  */
  38
  39 #include <sysdep.h>
  40
  41
  42         .section ".text"
  43         .align 4
  44 #ifdef SHARED
  45 .LLGETPC0:
  46         retl
  47          add    %o7, %l7, %l7
  48 #endif
  49         .global _start
  50         .type _start,#function
  51 _start:
  52 #ifdef SHARED
  53         sethi   %hi(_GLOBAL_OFFSET_TABLE_-4), %l7
  54         call    .LLGETPC0
  55          add    %l7, %lo(_GLOBAL_OFFSET_TABLE_+4), %l7
  56 #endif
  57
  58   /* Terminate the stack frame, and reserve space for functions to
  59      drop their arguments.  */
  60         mov     %g0, %fp
  61         sub     %sp, 6*8, %sp
  62
  63   /* Extract the arguments and environment as encoded on the stack.  The
  64      argument info starts after one register window (16 words) past the SP,
  65      plus the bias we added, plus the magic v9 STACK_BIAS.  */
  66         ldx     [%sp+STACK_BIAS+22*8], %o1
  67         add     %sp, STACK_BIAS+23*8, %o2
  68
  69   /* Load the addresses of the user entry points.  */
  70         sethi   %hi(main), %o0
  71         sethi   %hi(__libc_csu_init), %o3
  72         sethi   %hi(__libc_csu_fini), %o4
  73         or      %o0, %lo(main), %o0
  74         or      %o3, %lo(__libc_csu_init), %o3
  75         or      %o4, %lo(__libc_csu_fini), %o4
  76 #ifdef SHARED
  77         ldx     [%l7 + %o0], %o0
  78         ldx     [%l7 + %o3], %o3
  79         ldx     [%l7 + %o4], %o4
  80 #endif
  81
  82   /* When starting a binary via the dynamic linker, %g1 contains the
  83      address of the shared library termination function, which will be
  84      registered with atexit().  If we are statically linked, this will
  85      be NULL.  */
  86         mov     %g1, %o5
  87
  88   /* Let libc do the rest of the initialization, and call main.  */
  89         call    __libc_start_main
  90          nop
  91
  92   /* Die very horribly if exit returns.  */
  93         illtrap 0
  94
  95         .size _start, .-_start
  96
  97 /* Define a symbol for the first piece of initialized data.  */
  98         .data
  99         .globl  __data_start
 100 __data_start:
 101         .long   0
 102 weak_alias (__data_start, data_start)