sysdeps/powerpc/powerpc32/fpu/s_truncf.S

   1 /* truncf function.  PowerPC32 version.
   2    Copyright (C) 2004-2016 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20
  21         .section        .rodata.cst4,"aM",@progbits,4
  22         .align  2
  23 .LC0:   /* 2**23 */
  24         .long 0x4b000000
  25
  26 /* float [fp1] truncf (float x [fp1])
  27    IEEE 1003.1 trunc function.  IEEE specifies "trunc to the integer
  28    value, in floating format, nearest to but no larger in magnitude
  29    then the argument."
  30    We set "round toward Zero" mode and trunc by adding +-2**23 then
  31    subtracting +-2**23.  */
  32
  33         .section        ".text"
  34 ENTRY (__truncf)
  35 #ifdef SHARED
  36         mflr    r11
  37         cfi_register(lr,r11)
  38         SETUP_GOT_ACCESS(r9,got_label)
  39         addis   r9,r9,.LC0-got_label@ha
  40         lfs     fp13,.LC0-got_label@l(r9)
  41         mtlr    r11
  42         cfi_same_value (lr)
  43 #else
  44         lis     r9,.LC0@ha
  45         lfs     fp13,.LC0@l(r9)
  46 #endif
  47         fabs    fp0,fp1
  48         fsubs   fp12,fp13,fp13  /* generate 0.0  */
  49         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO23)  */
  50         mffs    fp11            /* Save current FPU rounding mode and
  51                                    "inexact" state.  */
  52         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  53         bnl-    cr7,.L10
  54         mtfsfi  7,1             /* Set rounding toward 0 mode.  */
  55         ble-    cr6,.L4
  56         fadds   fp1,fp1,fp13    /* x+= TWO23;  */
  57         fsubs   fp1,fp1,fp13    /* x-= TWO23;  */
  58         fabs    fp1,fp1         /* if (x == 0.0)  */
  59                                 /* x = 0.0; */
  60         mtfsf   0xff,fp11       /* Restore previous rounding mode and
  61                                    "inexact" state.  */
  62         blr
  63 .L4:
  64         bge-    cr6,.L9         /* if (x < 0.0)  */
  65         fsubs   fp1,fp1,fp13    /* x-= TWO23;  */
  66         fadds   fp1,fp1,fp13    /* x+= TWO23;  */
  67         fnabs   fp1,fp1         /* if (x == 0.0)  */
  68                                 /* x = -0.0; */
  69 .L9:
  70         mtfsf   0xff,fp11       /* Restore previous rounding mode and
  71                                    "inexact" state.  */
  72         blr
  73 .L10:
  74         /* Ensure sNaN input is converted to qNaN.  */
  75         fcmpu   cr7,fp1,fp1
  76         beqlr   cr7
  77         fadds   fp1,fp1,fp1
  78         blr
  79         END (__truncf)
  80
  81 weak_alias (__truncf, truncf)
  82