sysdeps/powerpc/powerpc32/fpu/s_trunc.S

   1 /* trunc function.  PowerPC32 version.
   2    Copyright (C) 2004-2016 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20 #include <math_ldbl_opt.h>
  21
  22         .section        .rodata.cst4,"aM",@progbits,4
  23         .align  2
  24 .LC0:   /* 2**52 */
  25         .long 0x59800000
  26
  27 /* double [fp1] trunc (double x [fp1])
  28    IEEE 1003.1 trunc function.  IEEE specifies "trunc to the integer
  29    value, in floating format, nearest to but no larger in magnitude
  30    then the argument."
  31    We set "round toward Zero" mode and trunc by adding +-2**52 then
  32    subtracting +-2**52.  */
  33
  34         .section        ".text"
  35 ENTRY (__trunc)
  36 #ifdef SHARED
  37         mflr    r11
  38         cfi_register(lr,r11)
  39         SETUP_GOT_ACCESS(r9,got_label)
  40         addis   r9,r9,.LC0-got_label@ha
  41         lfs     fp13,.LC0-got_label@l(r9)
  42         mtlr    r11
  43         cfi_same_value (lr)
  44 #else
  45         lis     r9,.LC0@ha
  46         lfs     fp13,.LC0@l(r9)
  47 #endif
  48         fabs    fp0,fp1
  49         fsub    fp12,fp13,fp13  /* generate 0.0  */
  50         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO52)  */
  51         mffs    fp11            /* Save current FPU rounding mode and
  52                                    "inexact" state.  */
  53         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  54         bnl-    cr7,.L10
  55         mtfsfi  7,1             /* Set rounding toward 0 mode.  */
  56         ble-    cr6,.L4
  57         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  58         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  59         fabs    fp1,fp1         /* if (x == 0.0)  */
  60                                 /* x = 0.0; */
  61         mtfsf   0xff,fp11       /* Restore previous rounding mode and
  62                                    "inexact" state.  */
  63         blr
  64 .L4:
  65         bge-    cr6,.L9         /* if (x < 0.0)  */
  66         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  67         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  68         fnabs   fp1,fp1         /* if (x == 0.0)  */
  69                                 /* x = -0.0; */
  70 .L9:
  71         mtfsf   0xff,fp11       /* Restore previous rounding mode and
  72                                    "inexact" state.  */
  73         blr
  74 .L10:
  75         /* Ensure sNaN input is converted to qNaN.  */
  76         fcmpu   cr7,fp1,fp1
  77         beqlr   cr7
  78         fadd    fp1,fp1,fp1
  79         blr
  80         END (__trunc)
  81
  82 weak_alias (__trunc, trunc)
  83
  84 #ifdef NO_LONG_DOUBLE
  85 weak_alias (__trunc, truncl)
  86 strong_alias (__trunc, __truncl)
  87 #endif
  88 #if LONG_DOUBLE_COMPAT(libm, GLIBC_2_1)
  89 compat_symbol (libm, __trunc, truncl, GLIBC_2_1)
  90 #endif