sysdeps/powerpc/powerpc32/fpu/s_floorf.S

   1 /* float Floor function.  PowerPC32 version.
   2    Copyright (C) 2004-2016 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20
  21         .section        .rodata.cst4,"aM",@progbits,4
  22         .align  2
  23 .LC0:   /* 2**23 */
  24         .long 0x4b000000
  25
  26         .section        ".text"
  27 ENTRY (__floorf)
  28 #ifdef SHARED
  29         mflr    r11
  30         cfi_register(lr,r11)
  31         SETUP_GOT_ACCESS(r9,got_label)
  32         addis   r9,r9,.LC0-got_label@ha
  33         lfs     fp13,.LC0-got_label@l(r9)
  34         mtlr    r11
  35         cfi_same_value (lr)
  36 #else
  37         lis     r9,.LC0@ha
  38         lfs     fp13,.LC0@l(r9)
  39 #endif
  40         fabs    fp0,fp1
  41         fsubs   fp12,fp13,fp13  /* generate 0.0  */
  42         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO23)  */
  43         mffs    fp11            /* Save current FPU rounding mode and
  44                                    "inexact" state.  */
  45         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  46         bnl-    cr7,.L10
  47         mtfsfi  7,3             /* Set rounding mode toward -inf.  */
  48         ble-    cr6,.L4
  49         fadds   fp1,fp1,fp13    /* x+= TWO23;  */
  50         fsubs   fp1,fp1,fp13    /* x-= TWO23;  */
  51         fabs    fp1,fp1         /* if (x == 0.0)  */
  52                                 /* x = 0.0; */
  53         mtfsf   0xff,fp11       /* Restore previous rounding mode and
  54                                    "inexact" state.  */
  55         blr
  56 .L4:
  57         bge-    cr6,.L9         /* if (x < 0.0)  */
  58         fsubs   fp1,fp1,fp13    /* x-= TWO23;  */
  59         fadds   fp1,fp1,fp13    /* x+= TWO23;  */
  60         fnabs   fp1,fp1         /* if (x == 0.0)  */
  61                                 /* x = -0.0; */
  62 .L9:
  63         mtfsf   0xff,fp11       /* Restore previous rounding mode and
  64                                    "inexact" state.  */
  65         blr
  66 .L10:
  67         /* Ensure sNaN input is converted to qNaN.  */
  68         fcmpu   cr7,fp1,fp1
  69         beqlr   cr7
  70         fadds   fp1,fp1,fp1
  71         blr
  72         END (__floorf)
  73
  74 weak_alias (__floorf, floorf)
  75