sysdeps/s390/multiarch/wcscat-vx.S

   1 /* Vector optimized 32/64 bit S/390 version of wcscat.
   2    Copyright (C) 2015 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #if defined HAVE_S390_VX_ASM_SUPPORT && IS_IN (libc)
  20
  21 # include "sysdep.h"
  22 # include "asm-syntax.h"
  23
  24         .text
  25
  26 /* wchar_t * wcscat (wchar_t *dest, const wchar_t *src)
  27    Concatenate two strings.
  28
  29    Register usage:
  30    -r0=saved dest pointer for return
  31    -r1=tmp
  32    -r2=dest
  33    -r3=src
  34    -r4=tmp
  35    -r5=current_len
  36    -v16=part of src
  37    -v17=index of zero
  38    -v18=part of src
  39 */
  40 ENTRY(__wcscat_vx)
  41         .machine "z13"
  42         .machinemode "zarch_nohighgprs"
  43
  44         vlbb    %v16,0(%r2),6   /* Load s until next 4k-byte boundary.  */
  45         lcbb    %r1,0(%r2),6    /* Get bytes to 4k-byte boundary or 16.  */
  46
  47         /* __wcslen_c can handle non 4byte aligned pointers,
  48            but __wcscpy_c not. Thus if either src or dest is
  49            not 4byte aligned, use __wcscat_c.  */
  50         tmll    %r2,3           /* Test if s is 4-byte aligned?   */
  51         jne     .Lfallback      /* And use common-code variant if not.  */
  52         tmll    %r3,3           /* Test if src is 4-byte aligned?   */
  53         jne     .Lfallback      /* And use common-code variant if not.  */
  54
  55         lgr     %r0,%r2         /* Save destination pointer for return.  */
  56
  57         /* WCSLEN
  58            r1 = loaded bytes (tmp)
  59            r4 = zero byte index (tmp)
  60            r2 = dst
  61         */
  62
  63         vfenezf %v16,%v16,%v16  /* Find element not equal with zero search.  */
  64         vlgvb   %r5,%v16,7      /* Load zero index or 16 if not found.  */
  65         clrjl   %r5,%r1,.Llen_end /* Found zero within loaded bytes, end.  */
  66
  67         /* Align s to 16 byte.  */
  68         risbgn  %r1,%r2,60,128+63,0 /* %r3 = bits 60-63 of %r2 'and' 15.  */
  69         lghi    %r5,16          /* current_len = 16.  */
  70         slr     %r5,%r1         /* Compute bytes to 16bytes boundary.  */
  71
  72         /* Find zero in 16byte aligned loop.  */
  73 .Llen_loop:
  74         vl      %v16,0(%r5,%r2) /* Load s.  */
  75         vfenezfs %v16,%v16,%v16 /* Find element not equal with zero search.  */
  76         je      .Llen_found     /* Jump away if zero was found.  */
  77         vl      %v16,16(%r5,%r2)
  78         vfenezfs %v16,%v16,%v16
  79         je      .Llen_found16
  80         vl      %v16,32(%r5,%r2)
  81         vfenezfs %v16,%v16,%v16
  82         je      .Llen_found32
  83         vl      %v16,48(%r5,%r2)
  84         vfenezfs %v16,%v16,%v16
  85         je      .Llen_found48
  86
  87         aghi    %r5,64
  88         j       .Llen_loop      /* No zero -> loop.  */
  89
  90 .Llen_found48:
  91         aghi    %r5,16
  92 .Llen_found32:
  93         aghi    %r5,16
  94 .Llen_found16:
  95         aghi    %r5,16
  96 .Llen_found:
  97         vlgvb   %r4,%v16,7      /* Load byte index of zero.  */
  98         algr    %r5,%r4
  99
 100 .Llen_end:
 101         /* WCSCPY
 102            %r1 = loaded bytes (tmp)
 103            %r4 = zero byte index (tmp)
 104            %r3 = curr src pointer
 105            %r2 = curr dst pointer
 106          */
 107         la      %r2,0(%r5,%r2)  /* strcpy at end of dst-string.   */
 108
 109         vlbb    %v16,0(%r3),6   /* Load s until next 4k-byte boundary.  */
 110         lcbb    %r1,0(%r3),6    /* Get bytes to 4k-byte boundary or 16.  */
 111
 112         vfenezf %v17,%v16,%v16  /* Find element not equal with zero search.  */
 113         vlgvb   %r5,%v17,7      /* Load zero index or 16 if not found.  */
 114         clrjl   %r5,%r1,.Lcpy_found_align /* If found zero within loaded bytes,
 115                                              copy bytes before and return.  */
 116
 117         /* Align s to 16 byte.  */
 118         risbgn  %r4,%r3,60,128+63,0 /* %r3 = bits 60-63 of %r2 'and' 15.  */
 119         lghi    %r5,15          /* current_len = 15.  */
 120         slr     %r5,%r4         /* Compute highest index to 16byte boundary.  */
 121
 122         vstl    %v16,%r5,0(%r2) /* Copy loaded characters - no zero.  */
 123         ahi     %r5,1           /* Start loop at next character.  */
 124
 125         /* Find zero in 16byte aligned loop.  */
 126 .Lcpy_loop:
 127         vl      %v16,0(%r5,%r3) /* Load s.  */
 128         vfenezfs %v17,%v16,%v16 /* Find element not equal with zero search.  */
 129         je      .Lcpy_found_v16_0 /* Jump away if zero was found.  */
 130         vl      %v18,16(%r5,%r3) /* Load next part of s.  */
 131         vst     %v16,0(%r5,%r2) /* Save previous part without zero to dst.  */
 132         vfenezfs %v17,%v18,%v18
 133         je      .Lcpy_found_v18_16
 134         vl      %v16,32(%r5,%r3)
 135         vst     %v18,16(%r5,%r2)
 136         vfenezfs %v17,%v16,%v16
 137         je      .Lcpy_found_v16_32
 138         vl      %v18,48(%r5,%r3)
 139         vst     %v16,32(%r5,%r2)
 140         vfenezfs %v17,%v18,%v18
 141         je      .Lcpy_found_v18_48
 142         vst     %v18,48(%r5,%r2)
 143
 144         aghi    %r5,64
 145         j       .Lcpy_loop      /* No zero -> loop.  */
 146
 147 .Lcpy_found_v16_32:
 148         aghi    %r5,32
 149 .Lcpy_found_v16_0:
 150         la      %r4,0(%r5,%r2)
 151         vlgvb   %r1,%v17,7      /* Load byte index of zero.  */
 152         aghi    %r1,3           /* Also copy remaining bytes of zero.  */
 153         vstl    %v16,%r1,0(%r4) /* Copy characters including zero.  */
 154         lgr     %r2,%r0         /* Load saved dest-ptr.  */
 155         br      %r14
 156
 157 .Lcpy_found_v18_48:
 158         aghi    %r5,32
 159 .Lcpy_found_v18_16:
 160         la      %r4,16(%r5,%r2)
 161         vlgvb   %r1,%v17,7      /* Load byte index of zero.  */
 162         aghi    %r1,3           /* Also copy remaining bytes of zero.  */
 163         vstl    %v18,%r1,0(%r4) /* Copy characters including zero.  */
 164         lgr     %r2,%r0         /* Load saved dest-ptr.  */
 165         br      %r14
 166
 167 .Lcpy_found_align:
 168         aghi    %r5,3           /* Also copy remaining bytes of found zero.  */
 169         vstl    %v16,%r5,0(%r2) /* Copy characters including zero.  */
 170         lgr     %r2,%r0         /* Load saved dest-ptr.  */
 171         br      %r14
 172 .Lfallback:
 173         jg      __wcscat_c
 174 END(__wcscat_vx)
 175 #endif /* HAVE_S390_VX_ASM_SUPPORT && IS_IN (libc) */