sysdeps/unix/sysv/linux/x86_64/vfork.S

   1 /* Copyright (C) 2001-2014 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3
   4    The GNU C Library is free software; you can redistribute it and/or
   5    modify it under the terms of the GNU Lesser General Public
   6    License as published by the Free Software Foundation; either
   7    version 2.1 of the License, or (at your option) any later version.
   8
   9    The GNU C Library is distributed in the hope that it will be useful,
  10    but WITHOUT ANY WARRANTY; without even the implied warranty of
  11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12    Lesser General Public License for more details.
  13
  14    You should have received a copy of the GNU Lesser General Public
  15    License along with the GNU C Library; if not, see
  16    <http://www.gnu.org/licenses/>.  */
  17
  18 #include <sysdep.h>
  19 #define _ERRNO_H        1
  20 #include <bits/errno.h>
  21
  22 /* Clone the calling process, but without copying the whole address space.
  23    The calling process is suspended until the new process exits or is
  24    replaced by a call to `execve'.  Return -1 for errors, 0 to the new process,
  25    and the process ID of the new process to the old process.  */
  26
  27 ENTRY (__vfork)
  28
  29         /* Pop the return PC value into RDI.  We need a register that
  30            is preserved by the syscall and that we're allowed to destroy. */
  31         popq    %rdi
  32         cfi_adjust_cfa_offset(-8)
  33         cfi_register(%rip, %rdi)
  34
  35 #ifdef SAVE_PID
  36         SAVE_PID
  37 #endif
  38
  39         /* Stuff the syscall number in RAX and enter into the kernel.  */
  40         movl    $SYS_ify (vfork), %eax
  41         syscall
  42
  43         /* Push back the return PC.  */
  44         pushq   %rdi
  45         cfi_adjust_cfa_offset(8)
  46
  47 #ifdef RESTORE_PID
  48         RESTORE_PID
  49 #endif
  50
  51         cmpl    $-4095, %eax
  52         jae SYSCALL_ERROR_LABEL         /* Branch forward if it failed.  */
  53
  54         /* Normal return.  */
  55         ret
  56
  57 PSEUDO_END (__vfork)
  58 libc_hidden_def (__vfork)
  59
  60 weak_alias (__vfork, vfork)