sysdeps/unix/sysv/linux/sparc/sparc64/clone.S

   1 /* Copyright (C) 1997-2014 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Contributed by Richard Henderson (rth@tamu.edu).
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 /* clone() is even more special than fork() as it mucks with stacks
  20    and invokes a function in the right context after its all over.  */
  21
  22 #include <asm/errno.h>
  23 #include <asm/unistd.h>
  24 #include <tcb-offsets.h>
  25 #include <sysdep.h>
  26
  27 #define CLONE_VM        0x00000100
  28 #define CLONE_THREAD    0x00010000
  29
  30 /* int clone(int (*fn)(void *arg), void *child_stack, int flags, void *arg,
  31              pid_t *ptid, void *tls, pid_t *ctid); */
  32
  33         .register       %g2,#scratch
  34         .register       %g3,#scratch
  35
  36         .text
  37
  38 ENTRY (__clone)
  39         save    %sp, -192, %sp
  40         cfi_def_cfa_register(%fp)
  41         cfi_window_save
  42         cfi_register(%o7, %i7)
  43
  44         /* sanity check arguments */
  45         brz,pn  %i0, 99f                /* fn non-NULL? */
  46          mov    %i0, %g2
  47         brz,pn  %i1, 99f                /* child_stack non-NULL? */
  48          mov    %i2, %o0                /* clone flags */
  49
  50         /* The child_stack is the top of the stack, allocate one
  51            whole stack frame from that as this is what the kernel
  52            expects.  Also, subtract STACK_BIAS.  */
  53         sub     %i1, 192 + 0x7ff, %o1
  54         mov     %i3, %g3
  55         mov     %i2, %g4
  56
  57         mov     %i4,%o2                 /* PTID */
  58         mov     %i5,%o3                 /* TLS */
  59         ldx     [%fp+0x7ff+176],%o4     /* CTID */
  60
  61         /* Do the system call */
  62         set     __NR_clone, %g1
  63         ta      0x6d
  64         bcs,pn  %xcc, 98f
  65          nop
  66         brnz,pn %o1, __thread_start
  67          nop
  68         jmpl    %i7 + 8, %g0
  69          restore %o0, %g0, %o0
  70 99:     mov     EINVAL, %o0
  71 98:     call    HIDDEN_JUMPTARGET(__errno_location)
  72          mov    %o0, %i0
  73         st      %i0, [%o0]
  74         jmpl    %i7 + 8, %g0
  75          restore %g0,-1,%o0
  76 END(__clone)
  77
  78         .type __thread_start,@function
  79 __thread_start:
  80 #ifdef RESET_PID
  81         sethi   %hi(CLONE_THREAD), %l0
  82         andcc   %g4, %l0, %g0
  83         bne,pt  %icc, 1f
  84          andcc  %g4, CLONE_VM, %g0
  85         bne,a,pn %icc, 2f
  86          mov    -1,%o0
  87         set     __NR_getpid,%g1
  88         ta      0x6d
  89 2:      st      %o0,[%g7 + PID]
  90         st      %o0,[%g7 + TID]
  91 1:
  92 #endif
  93         mov     %g0, %fp        /* terminate backtrace */
  94         call    %g2
  95          mov    %g3,%o0
  96         call    HIDDEN_JUMPTARGET(_exit),0
  97          nop
  98
  99         .size   __thread_start, .-__thread_start
 100
 101 weak_alias (__clone, clone)