sysdeps/unix/sysv/linux/s390/s390-32/syscall.S

   1 /* Copyright (C) 2000-2014 Free Software Foundation, Inc.
   2    Contributed by Martin Schwidefsky (schwidefsky@de.ibm.com).
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20
  21 /* Please consult the file sysdeps/unix/sysv/linux/s390/sysdep.h for
  22    more information about the value -4095 used below.*/
  23
  24 ENTRY (syscall)
  25         /* Save registers and setup stack.  */
  26         stm     %r6,%r15,24(%r15)  /* save registers */
  27         cfi_offset (%r15, -36)
  28         cfi_offset (%r14, -40)
  29         cfi_offset (%r13, -44)
  30         cfi_offset (%r12, -48)
  31         cfi_offset (%r11, -52)
  32         cfi_offset (%r10, -56)
  33         cfi_offset (%r9, -60)
  34         cfi_offset (%r8, -64)
  35         cfi_offset (%r7, -68)
  36         cfi_offset (%r6, -72)
  37         lr      %r1,%r15
  38         l       %r0,4(0,%r15)      /* load eos */
  39         ahi     %r15,-96           /* buy stack space */
  40         cfi_adjust_cfa_offset (96)
  41         st      %r1,0(0,%r15)      /* store back chain */
  42         st      %r0,4(0,%r15)      /* store eos */
  43
  44         lr     %r1,%r2             /* move syscall number */
  45         lr     %r2,%r3             /* first parameter  */
  46         lr     %r3,%r4             /* second parameter */
  47         lr     %r4,%r5             /* third parameter  */
  48         lr     %r5,%r6             /* fourth parameter */
  49         l      %r6,192(%r15)       /* fifth parameter  */
  50         l      %r7,196(%r15)       /* sixth parameter  */
  51
  52         basr   %r8,0
  53 0:      cl     %r1,4f-0b(%r8)      /* svc number < 256? */
  54         jl     2f
  55 1:      svc    0
  56         j      3f
  57 2:      ex     %r1,1b-0b(%r8)      /* lsb of R1 is subsituted as SVC number */
  58 3:      l      %r15,0(%r15)        /* load back chain */
  59         cfi_adjust_cfa_offset (-96)
  60         lm     %r6,15,24(%r15)     /* load registers */
  61
  62         lhi    %r0,-4095
  63         clr    %r2,%r0             /* check R2 for error */
  64         jnl    SYSCALL_ERROR_LABEL
  65         br     %r14                /* return to caller */
  66 4:      .long  256
  67 PSEUDO_END (syscall)