sysdeps/unix/sysv/linux/s390/s390-32/getcontext.S

   1 /* Copyright (C) 2001-2014 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Contributed by Martin Schwidefsky (schwidefsky@de.ibm.com).
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20 #include <features.h>
  21
  22 #include "ucontext_i.h"
  23
  24 /*  __getcontext (const ucontext_t *ucp)
  25
  26   Saves the machine context in UCP such that when it is activated,
  27   it appears as if __getcontext() returned again.
  28
  29   This implementation is intended to be used for *synchronous* context
  30   switches only.  Therefore, it does not have to save anything
  31   other than the PRESERVED state.  */
  32
  33 ENTRY(__getcontext)
  34         lr      %r1,%r2
  35
  36         /* sigprocmask (SIG_BLOCK, NULL, &sc->sc_mask).  */
  37         la      %r2,SIG_BLOCK
  38         slr     %r3,%r3
  39         la      %r4,SC_MASK(%r1)
  40         lhi     %r5,_NSIG8
  41         svc     SYS_ify(rt_sigprocmask)
  42
  43         /* Store fpu context.  */
  44         stfpc   SC_FPC(%r1)
  45         std     %f0,SC_FPRS(%r1)
  46         std     %f1,SC_FPRS+8(%r1)
  47         std     %f2,SC_FPRS+16(%r1)
  48         std     %f3,SC_FPRS+24(%r1)
  49         std     %f4,SC_FPRS+32(%r1)
  50         std     %f5,SC_FPRS+40(%r1)
  51         std     %f6,SC_FPRS+48(%r1)
  52         std     %f7,SC_FPRS+56(%r1)
  53         std     %f8,SC_FPRS+64(%r1)
  54         std     %f9,SC_FPRS+72(%r1)
  55         std     %f10,SC_FPRS+80(%r1)
  56         std     %f11,SC_FPRS+88(%r1)
  57         std     %f12,SC_FPRS+96(%r1)
  58         std     %f13,SC_FPRS+104(%r1)
  59         std     %f14,SC_FPRS+112(%r1)
  60         std     %f15,SC_FPRS+120(%r1)
  61
  62         /* Set __getcontext return value to 0.  */
  63         slr     %r2,%r2
  64
  65         /* Store access registers.  */
  66         stam    %a0,%a15,SC_ACRS(%r1)
  67
  68         /* Store general purpose registers.  */
  69         stm     %r0,%r15,SC_GPRS(%r1)
  70
  71         /* Return.  */
  72         br      %r14
  73 END(__getcontext)
  74
  75 weak_alias (__getcontext, getcontext)