sysdeps/unix/sysv/linux/s390/s390-32/clone.S

   1 /* Copyright (C) 2000-2014 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Contributed by Martin Schwidefsky (schwidefsky@de.ibm.com).
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 /* clone is even more special than fork as it mucks with stacks
  20    and invokes a function in the right context after its all over.  */
  21
  22 #include <sysdep.h>
  23 #include <tls.h>
  24 #define _ERRNO_H        1
  25 #include <bits/errno.h>
  26
  27 /* int __clone(int (*fn)(void *arg), void *child_stack, int flags, void *arg,
  28                pid_t *parent_tid, void *tls, pid_t *child_tid);  */
  29 /* sys_clone  (void *child_stack, unsigned long flags,
  30                pid_t *parent_tid, pid_t *child_tid, void *tls);  */
  31
  32         .text
  33 ENTRY(__clone)
  34         st      %r6,24(%r15)            /* store %r6 to save area */
  35         cfi_offset (%r6, -72)
  36         lr      %r0,%r5                 /* move *arg out of the way */
  37         ltr     %r1,%r2                 /* check fn and move to %r1 */
  38         jz      error                   /* no NULL function pointers */
  39         ltr     %r2,%r3                 /* check child_stack and move to %r2 */
  40         jz      error                   /* no NULL stack pointers */
  41         lr      %r3,%r4                 /* move flags to %r3 */
  42         lr      %r4,%r6                 /* move parent_tid to %r4 */
  43         l       %r5,100(%r15)           /* load child_tid from stack */
  44         l       %r6,96(%r15)            /* load tls from stack */
  45         svc     SYS_ify(clone)
  46         ltr     %r2,%r2                 /* check return code */
  47         jz      thread_start
  48         l       %r6,24(%r15)            /* restore %r6 */
  49         jm      SYSCALL_ERROR_LABEL
  50         br      %r14
  51 error:
  52         lhi     %r2,-EINVAL
  53         j       SYSCALL_ERROR_LABEL
  54 PSEUDO_END (__clone)
  55
  56 thread_start:
  57 #ifdef RESET_PID
  58         tmh     %r3,1           /* CLONE_THREAD == 0x00010000 */
  59         jne     1f
  60         lhi     %r2,-1
  61         tml     %r3,256         /* CLONE_VM == 0x00000100 */
  62         jne     2f
  63         svc     SYS_ify(getpid)
  64 2:      ear     %r3,%a0
  65         st      %r2,PID(%r3)
  66         st      %r2,TID(%r3)
  67 1:
  68 #endif
  69         /* fn is in gpr 1, arg in gpr 0 */
  70         lr      %r2,%r0         /* set first parameter to void *arg */
  71         ahi     %r15,-96        /* make room on the stack for the save area */
  72         xc      0(4,%r15),0(%r15)
  73         basr    %r14,%r1        /* jump to fn */
  74         DO_CALL (exit, 1)
  75 weak_alias (__clone, clone)