sysdeps/sparc/sparc64/fpu/s_rintf.S

   1 /* Round float to int floating-point values, sparc64 version.
   2    Copyright (C) 2012-2014 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by David S. Miller <davem@davemloft.net>, 2012.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 #include <sysdep.h>
  21
  22         /* We pop constants into the FPU registers using the incoming
  23            argument stack slots, since this avoid having to use any PIC
  24            references.  We also thus avoid having to allocate a register
  25            window.
  26
  27            VIS instructions are used to facilitate the formation of
  28            easier constants, and the propagation of the sign bit.  */
  29
  30 #define TWO_TWENTYTHREE 0x4b000000              /* 2**23 */
  31
  32 #define ZERO            %f10                    /* 0.0 */
  33 #define SIGN_BIT        %f12                    /* -0.0 */
  34
  35 ENTRY (__rintf)
  36         sethi   %hi(TWO_TWENTYTHREE), %o2
  37         fzeros  ZERO
  38
  39         fnegs   ZERO, SIGN_BIT
  40         st      %o2, [%sp + STACK_BIAS + 128]
  41         fabss   %f1, %f14
  42
  43         ld      [%sp + STACK_BIAS + 128], %f16
  44         fcmps   %fcc3, %f14, %f16
  45
  46         fmovsuge %fcc3, ZERO, %f16
  47         fands   %f1, SIGN_BIT, SIGN_BIT
  48
  49         fors    %f16, SIGN_BIT, %f16
  50         fadds   %f1, %f16, %f5
  51         fsubs   %f5, %f16, %f0
  52         fabss   %f0, %f0
  53         retl
  54          fors   %f0, SIGN_BIT, %f0
  55 END (__rintf)
  56 weak_alias (__rintf, rintf)