sysdeps/sparc/sparc64/fpu/s_lrint.S

   1 /* lrint(), sparc64 version.
   2    Copyright (C) 2012-2014 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by David S. Miller <davem@davemloft.net>, 2012.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 #include <sysdep.h>
  21
  22         /* We pop constants into the FPU registers using the incoming
  23            argument stack slots, since this avoid having to use any PIC
  24            references.  We also thus avoid having to allocate a register
  25            window.
  26
  27            VIS instructions are used to facilitate the formation of
  28            easier constants, and the propagation of the sign bit.  */
  29
  30 #define TWO_FIFTYTWO    0x43300000              /* 2**52 */
  31
  32 #define ZERO            %f10                    /* 0.0 */
  33 #define SIGN_BIT        %f12                    /* -0.0 */
  34
  35 ENTRY (__lrint)
  36         sethi   %hi(TWO_FIFTYTWO), %o2
  37         sllx    %o2, 32, %o2
  38         fzero   ZERO
  39
  40         fnegd   ZERO, SIGN_BIT
  41         stx     %o2, [%sp + STACK_BIAS + 128]
  42         fabsd   %f0, %f14
  43
  44         ldd     [%sp + STACK_BIAS + 128], %f16
  45         fcmpd   %fcc3, %f14, %f16
  46
  47         fmovduge %fcc3, ZERO, %f16
  48         fand    %f0, SIGN_BIT, SIGN_BIT
  49
  50         for     %f16, SIGN_BIT, %f16
  51         faddd   %f0, %f16, %f6
  52         fsubd   %f6, %f16, %f0
  53         fabsd   %f0, %f0
  54         for     %f0, SIGN_BIT, %f0
  55         fdtox   %f0, %f4
  56         std     %f4, [%sp + STACK_BIAS + 128]
  57         retl
  58          ldx    [%sp + STACK_BIAS + 128], %o0
  59 END (__lrint)
  60 weak_alias (__lrint, lrint)
  61
  62 strong_alias (__lrint, __llrint)
  63 weak_alias (__llrint, llrint)