sysdeps/sparc/sparc64/fpu/multiarch/s_rint-vis3.S

   1 /* Round float to int floating-point values, sparc64 vis3 version.
   2    Copyright (C) 2012-2014 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by David S. Miller <davem@davemloft.net>, 2012.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 #include <sysdep.h>
  21
  22         /* VIS instructions are used to facilitate the formation of
  23            easier constants, and the propagation of the sign bit.  */
  24
  25 #define TWO_FIFTYTWO    0x43300000              /* 2**52 */
  26
  27 #define ZERO            %f10                    /* 0.0 */
  28 #define SIGN_BIT        %f12                    /* -0.0 */
  29
  30 ENTRY (__rint_vis3)
  31         sethi   %hi(TWO_FIFTYTWO), %o2
  32         sllx    %o2, 32, %o2
  33         fzero   ZERO
  34
  35         fnegd   ZERO, SIGN_BIT
  36         movxtod %o2, %f16
  37         fabsd   %f0, %f14
  38
  39         fcmpd   %fcc3, %f14, %f16
  40
  41         fmovduge %fcc3, ZERO, %f16
  42         fand    %f0, SIGN_BIT, SIGN_BIT
  43
  44         for     %f16, SIGN_BIT, %f16
  45         faddd   %f0, %f16, %f6
  46         fsubd   %f6, %f16, %f0
  47         fabsd   %f0, %f0
  48         retl
  49          for    %f0, SIGN_BIT, %f0
  50 END (__rint_vis3)