sysdeps/sparc/sparc64/fpu/multiarch/s_ceil-vis3.S

   1 /* ceil function, sparc64 vis3 version.
   2    Copyright (C) 2012-2014 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by David S. Miller <davem@davemloft.net>, 2012.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 #include <sysdep.h>
  21
  22         /* 'siam' (Set Interval Arithmetic Mode) is used to quickly override
  23            the rounding mode during this routine.
  24
  25            We add then subtract (or subtract than add if the initial
  26            value was negative) 2**23 to the value, then subtract it
  27            back out.
  28
  29            This will clear out the fractional portion of the value and,
  30            with suitable 'siam' initiated rouding mode settings, round
  31            the final result in the proper direction.
  32
  33            We also use VIS3 moves to avoid using the stack to transfer
  34            values between float and integer registers.  */
  35
  36 #define TWO_FIFTYTWO    0x43300000              /* 2**52 */
  37
  38 #define ZERO            %f10                    /* 0.0 */
  39 #define SIGN_BIT        %f12                    /* -0.0 */
  40
  41 ENTRY (__ceil_vis3)
  42         sethi   %hi(TWO_FIFTYTWO), %o2
  43         fzero   ZERO
  44         sllx    %o2, 32, %o2
  45         fnegd   ZERO, SIGN_BIT
  46         movxtod %o2, %f16
  47         fabsd   %f0, %f14
  48         fcmpd   %fcc3, %f14, %f16
  49         fmovduge %fcc3, ZERO, %f16
  50         fand    %f0, SIGN_BIT, SIGN_BIT
  51         for     %f16, SIGN_BIT, %f16
  52         siam    (1 << 2) | 2
  53         faddd   %f0, %f16, %f18
  54         siam    (1 << 2) | 0
  55         fsubd   %f18, %f16, %f18
  56         siam    (0 << 2)
  57         retl
  58          for    %f18, SIGN_BIT, %f0
  59 END (__ceil_vis3)