sysdeps/sparc/sparc32/sparcv9/fpu/s_floorf.S

   1 /* Float floor function, sparc32 v9 version.
   2    Copyright (C) 2012-2014 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by David S. Miller <davem@davemloft.net>, 2012.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 #include <sysdep.h>
  21
  22         /* Since changing the rounding mode is extremely expensive, we
  23            try to round up using a method that is rounding mode
  24            agnostic.
  25
  26            We add then subtract (or subtract than add if the initial
  27            value was negative) 2**23 to the value, then subtract it
  28            back out.
  29
  30            This will clear out the fractional portion of the value.
  31            One of two things will happen for non-whole initial values.
  32            Either the rounding mode will round it up, or it will be
  33            rounded down.  If the value started out whole, it will be
  34            equal after the addition and subtraction.  This means we
  35            can accurately detect with one test whether we need to add
  36            another 1.0 to round it up properly.
  37
  38            We pop constants into the FPU registers using the incoming
  39            argument stack slots, since this avoid having to use any
  40            PIC references.  We also thus avoid having to allocate a
  41            register window.
  42
  43            VIS instructions are used to facilitate the formation of
  44            easier constants, and the propagation of the sign bit.  */
  45
  46 #define TWO_TWENTYTHREE 0x4b000000              /* 2**23 */
  47 #define ONE_DOT_ZERO    0x3f800000              /* 1.0 */
  48
  49 #define ZERO            %f10                    /* 0.0 */
  50 #define SIGN_BIT        %f12                    /* -0.0 */
  51
  52 ENTRY (__floorf)
  53         st      %o0, [%sp + 68]
  54         sethi   %hi(TWO_TWENTYTHREE), %o2
  55         sethi   %hi(ONE_DOT_ZERO), %o3
  56         fzeros  ZERO
  57
  58         ld      [%sp + 68], %f0
  59         fnegs   ZERO, SIGN_BIT
  60
  61         st      %o2, [%sp + 68]
  62         fabss   %f0, %f14
  63
  64         ld      [%sp + 68], %f16
  65         fcmps   %fcc3, %f14, %f16
  66
  67         fmovsuge %fcc3, ZERO, %f16
  68         fands   %f0, SIGN_BIT, SIGN_BIT
  69
  70         fors    %f16, SIGN_BIT, %f16
  71         fadds   %f0, %f16, %f1
  72         fsubs   %f1, %f16, %f1
  73         fcmps   %fcc2, %f1, %f0
  74         st      %o3, [%sp + 68]
  75
  76         ld      [%sp + 68], %f9
  77         fmovsule %fcc2, ZERO, %f9
  78         fsubs   %f1, %f9, %f0
  79         fabss   %f0, %f0
  80         retl
  81          fors   %f0, SIGN_BIT, %f0
  82 END (__floorf)
  83 weak_alias (__floorf, floorf)