sysdeps/sparc/sparc32/sparcv9/fpu/s_ceil.S

   1 /* ceil function, sparc32 v9 version.
   2    Copyright (C) 2012-2014 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by David S. Miller <davem@davemloft.net>, 2012.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 #include <sysdep.h>
  21 #include <math_ldbl_opt.h>
  22
  23         /* Since changing the rounding mode is extremely expensive, we
  24            try to round up using a method that is rounding mode
  25            agnostic.
  26
  27            We add then subtract (or subtract than add if the initial
  28            value was negative) 2**23 to the value, then subtract it
  29            back out.
  30
  31            This will clear out the fractional portion of the value.
  32            One of two things will happen for non-whole initial values.
  33            Either the rounding mode will round it up, or it will be
  34            rounded down.  If the value started out whole, it will be
  35            equal after the addition and subtraction.  This means we
  36            can accurately detect with one test whether we need to add
  37            another 1.0 to round it up properly.
  38
  39            We pop constants into the FPU registers using the incoming
  40            argument stack slots, since this avoid having to use any
  41            PIC references.  We also thus avoid having to allocate a
  42            register window.
  43
  44            VIS instructions are used to facilitate the formation of
  45            easier constants, and the propagation of the sign bit.  */
  46
  47 #define TWO_FIFTYTWO    0x43300000              /* 2**52 */
  48 #define ONE_DOT_ZERO    0x3ff00000              /* 1.0 */
  49
  50 #define ZERO            %f10                    /* 0.0 */
  51 #define SIGN_BIT        %f12                    /* -0.0 */
  52
  53 ENTRY (__ceil)
  54         sethi   %hi(TWO_FIFTYTWO), %o2
  55         sllx    %o0, 32, %o0
  56         sethi   %hi(ONE_DOT_ZERO), %o3
  57         or      %o0, %o1, %o0
  58         stx     %o0, [%sp + 72]
  59         sllx    %o2, 32, %o2
  60         fzero   ZERO
  61         sllx    %o3, 32, %o3
  62
  63         ldd     [%sp + 72], %f0
  64         fnegd   ZERO, SIGN_BIT
  65
  66         stx     %o2, [%sp + 72]
  67         fabsd   %f0, %f14
  68
  69         ldd     [%sp + 72], %f16
  70         fcmpd   %fcc3, %f14, %f16
  71
  72         fmovduge %fcc3, ZERO, %f16
  73         fand    %f0, SIGN_BIT, SIGN_BIT
  74
  75         for     %f16, SIGN_BIT, %f16
  76         faddd   %f0, %f16, %f18
  77         fsubd   %f18, %f16, %f18
  78         fcmpd   %fcc2, %f18, %f0
  79         stx     %o3, [%sp + 72]
  80
  81         ldd     [%sp + 72], %f20
  82         fmovduge %fcc2, ZERO, %f20
  83         faddd   %f18, %f20, %f0
  84         fabsd   %f0, %f0
  85         retl
  86          for    %f0, SIGN_BIT, %f0
  87 END (__ceil)
  88 weak_alias (__ceil, ceil)
  89
  90 #if LONG_DOUBLE_COMPAT(libm, GLIBC_2_0)
  91 compat_symbol (libm, __ceil, ceill, GLIBC_2_0)
  92 #endif