sysdeps/s390/s390-32/sub_n.S

   1 /* __mpn_sub_n -- Add two limb vectors of the same length > 0 and store
   2    sum in a third limb vector.
   3    Copyright (C) 2000-2014 Free Software Foundation, Inc.
   4    Contributed by Martin Schwidefsky (schwidefsky@de.ibm.com).
   5    This file is part of the GNU MP Library.
   6
   7    The GNU MP Library is free software; you can redistribute it and/or modify
   8    it under the terms of the GNU Lesser General Public License as published by
   9    the Free Software Foundation; either version 2.1 of the License, or (at your
  10    option) any later version.
  11
  12    The GNU MP Library is distributed in the hope that it will be useful, but
  13    WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  14    or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  15    License for more details.
  16
  17    You should have received a copy of the GNU Lesser General Public License
  18    along with the GNU MP Library; see the file COPYING.LIB.  If not,
  19    see <http://www.gnu.org/licenses/>.  */
  20
  21 /*
  22   INPUT PARAMETERS
  23   res_ptr       %r2
  24   s1_ptr        %r3
  25   s2_ptr        %r4
  26   size          %r5
  27 */
  28
  29 #include "sysdep.h"
  30 #include "asm-syntax.h"
  31
  32 ENTRY(__mpn_sub_n)
  33         st     %r6,24(%r15)   # save register 6
  34         cfi_offset (%r6, -72)
  35         sr     %r1,%r1
  36         lhi    %r0,1          # cannot use ahi to add carry, use slr
  37 .L0:    l      %r6,0(%r1,%r3) # .L0 -> no carry from last sub
  38         sl     %r6,0(%r1,%r4)
  39         st     %r6,0(%r1,%r2)
  40         la     %r1,4(0,%r1)
  41         brc    4,.L3
  42 .L1:    brct   %r5,.L0
  43         slr    %r2,%r2        # no last carry to return
  44         j      .Lexit
  45 .L2:    l      %r6,0(%r1,%r3) # .L2 -> carry from last sub
  46         sl     %r6,0(%r1,%r4)
  47         brc    4,.L4
  48         slr    %r6,%r0        # no carry yet, add carry from last sub
  49         st     %r6,0(%r1,%r2)
  50         la     %r1,4(0,%r1)
  51         brc    11,.L1         # new carry ?
  52 .L3:    brct   %r5,.L2
  53         lr     %r2,%r0        # return last carry
  54         j      .Lexit
  55 .L4:    slr    %r6,%r0        # already a carry, add carry from last sub
  56         st     %r6,0(%r1,%r2)
  57         la     %r1,4(0,%r1)
  58         brct   %r5,.L2
  59         lr     %r2,%r0        # return last carry
  60 .Lexit: l      %r6,24(%r15)   # restore register 6
  61         br     %r14
  62 END(__mpn_sub_n)