sysdeps/s390/s390-32/addmul_1.S

   1 /* S390 __mpn_addmul_1 -- Multiply a limb vector with a limb and add
   2    the result to a second limb vector.
   3    Copyright (C) 2000-2014 Free Software Foundation, Inc.
   4    Contributed by Martin Schwidefsky (schwidefsky@de.ibm.com).
   5    This file is part of the GNU MP Library.
   6
   7    The GNU MP Library is free software; you can redistribute it and/or modify
   8    it under the terms of the GNU Lesser General Public License as published by
   9    the Free Software Foundation; either version 2.1 of the License, or (at your
  10    option) any later version.
  11
  12    The GNU MP Library is distributed in the hope that it will be useful, but
  13    WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  14    or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  15    License for more details.
  16
  17    You should have received a copy of the GNU Lesser General Public License
  18    along with the GNU MP Library; see the file COPYING.LIB.  If not,
  19    see <http://www.gnu.org/licenses/>.  */
  20
  21 /*
  22    INPUT PARAMETERS
  23    res_ptr      %r2
  24    s1_ptr       %r3
  25    sizeP        %r4
  26    s2_limb      %r5
  27 */
  28
  29 #include "sysdep.h"
  30 #include "asm-syntax.h"
  31
  32         .text
  33 ENTRY(__mpn_addmul_1)
  34         st     %r6,24(%r15)
  35         cfi_offset (%r6, -72)
  36         slr    %r6,%r6            # cy_limb = 0
  37 .L0:    icm    %r1,15,0(%r3)      # get s1_ptr[i]
  38         mr     %r0,%r5            # umul_ppmm(prod_high,prod_low,s1_ptr[j],s2_limb)
  39         jnm    .L1
  40         alr    %r0,%r5
  41 .L1:    ltr    %r5,%r5
  42         jnm    .L2
  43         al     %r0,0(%r3)
  44 .L2:    alr    %r1,%r6            # prod_low += cy_limb
  45         lr     %r6,%r0            # cy_limb = prod_high
  46         brc    12,.L3
  47         ahi    %r6,1              #           + (prod_low < cy_limb)
  48 .L3:    al     %r1,0(%r2)         # prod_low += res_ptr[i]
  49         brc    12,.L4
  50         ahi    %r6,1              # cy_limb++
  51 .L4:    st     %r1,0(%r2)
  52         la     %r2,4(0,%r2)
  53         la     %r3,4(0,%r3)
  54         brct   %r4,.L0
  55         lr     %r2,%r6            # return cy_limb
  56         l      %r6,24(%r15)
  57 .Lexit: br     %r14
  58 END(__mpn_addmul_1)