sysdeps/powerpc/powerpc64/power7/fpu/s_isnan.S

   1 /* isnan().  PowerPC64/POWER7 version.
   2    Copyright (C) 2010-2014 Free Software Foundation, Inc.
   3    Contributed by Luis Machado <luisgpm@br.ibm.com>.
   4    This file is part of the GNU C Library.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 #include <sysdep.h>
  21 #include <math_ldbl_opt.h>
  22
  23 /* int __isnan(x)  */
  24         .section    ".toc","aw"
  25 .LC0:   /* 1.0 */
  26         .tc         FD_ONE[TC],0x3ff0000000000000
  27         .section    ".text"
  28         .type       __isnan, @function
  29         .machine    power7
  30 EALIGN (__isnan, 4, 0)
  31         CALL_MCOUNT 0
  32         lfd     fp0,.LC0@toc(r2)
  33         ftdiv   cr7,fp1,fp0
  34         li      r3,0
  35         bflr    30            /* If not NaN, finish.  */
  36
  37         stfd    fp1,-16(r1)   /* Transfer FP to GPR's.  */
  38         ori     2,2,0         /* Force a new dispatch group.  */
  39         ld      r4,-16(r1)    /* Load FP into GPR.  */
  40         lis     r0,0x7ff0
  41         sldi    r0,r0,32      /* const long r0 0x7ff00000 00000000.  */
  42         clrldi  r4,r4,1       /* x = fabs(x)  */
  43         cmpd    cr7,r4,r0     /* if (fabs(x) <= inf)  */
  44         blelr   cr7           /* LE means not NaN.  */
  45         li      r3,1          /* else return 1  */
  46         blr
  47         END (__isnan)
  48
  49 hidden_def (__isnan)
  50 weak_alias (__isnan, isnan)
  51
  52 /* It turns out that the 'double' version will also always work for
  53    single-precision.  */
  54 strong_alias (__isnan, __isnanf)
  55 hidden_def (__isnanf)
  56 weak_alias (__isnanf, isnanf)
  57
  58 #ifdef NO_LONG_DOUBLE
  59 strong_alias (__isnan, __isnanl)
  60 weak_alias (__isnan, isnanl)
  61 #endif
  62
  63 #ifndef IS_IN_libm
  64 # if LONG_DOUBLE_COMPAT(libc, GLIBC_2_0)
  65 compat_symbol (libc, __isnan, __isnanl, GLIBC_2_0);
  66 compat_symbol (libc, isnan, isnanl, GLIBC_2_0);
  67 # endif
  68 #endif