sysdeps/powerpc/powerpc64/fpu/s_truncl.S

   1 /* long double trunc function.
   2    IBM extended format long double version.
   3    Copyright (C) 2004-2014 Free Software Foundation, Inc.
   4    This file is part of the GNU C Library.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 #include <sysdep.h>
  21 #include <math_ldbl_opt.h>
  22
  23         .section        ".toc","aw"
  24 .LC0:   /* 2**52 */
  25         .tc FD_43300000_0[TC],0x4330000000000000
  26 .LC1:   /* 0.5 */
  27         .tc FD_3fe00000_0[TC],0x3fe0000000000000
  28         .section        ".text"
  29
  30 /* long double [fp1,fp2] truncl (long double x [fp1,fp2])  */
  31
  32 ENTRY (__truncl)
  33         mffs    fp11            /* Save current FPU rounding mode.  */
  34         lfd     fp13,.LC0@toc(2)
  35         fabs    fp0,fp1
  36         fabs    fp9,fp2
  37         fsub    fp12,fp13,fp13  /* generate 0.0  */
  38         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO52)  */
  39         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  40         bnl-    cr7,.L2
  41         mtfsfi  7,1             /* Set rounding mode toward 0.  */
  42         ble-    cr6,.L1
  43         fneg    fp2,fp12
  44         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  45         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  46         fabs    fp1,fp1         /* if (x == 0.0) x = 0.0;  */
  47 .L0:
  48         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  49         blr
  50 .L1:
  51         fneg    fp2,fp12
  52         bge-    cr6,.L0         /* if (x < 0.0)  */
  53         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  54         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  55         fnabs   fp1,fp1         /* if (x == 0.0) x = -0.0;  */
  56         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  57         blr
  58
  59 /* The high double is > TWO52 so we need to round the low double and
  60    perhaps the high double.  In this case we have to round the low
  61    double and handle any adjustment to the high double that may be
  62    caused by rounding (up).  This is complicated by the fact that the
  63    high double may already be rounded and the low double may have the
  64    opposite sign to compensate.This gets a bit tricky so we use the
  65    following algorithm:
  66
  67    tau = floor(x_high/TWO52);
  68    x0 = x_high - tau;
  69    x1 = x_low + tau;
  70    r1 = rint(x1);
  71    y_high = x0 + r1;
  72    y_low = x0 - y_high + r1;
  73    return y;  */
  74 .L2:
  75         fcmpu   cr7,fp9,fp13    /* if (|x_low| > TWO52)  */
  76         fcmpu   cr0,fp9,fp12    /* || (|x_low| == 0.0)  */
  77         fcmpu   cr5,fp2,fp12    /* if (x_low > 0.0)  */
  78         bgelr-  cr7             /*   return x;  */
  79         beqlr-  cr0
  80         mtfsfi  7,1             /* Set rounding mode toward 0.  */
  81         fdiv    fp8,fp1,fp13    /* x_high/TWO52  */
  82
  83         bng-    cr6,.L6         /* if (x > 0.0)  */
  84         fctidz  fp0,fp8
  85         fcfid   fp8,fp0         /* tau = floor(x_high/TWO52);  */
  86         fadd    fp8,fp8,fp8     /* tau++; Make tau even  */
  87         bng     cr5,.L4         /* if (x_low > 0.0)  */
  88         fmr     fp3,fp1
  89         fmr     fp4,fp2
  90         b       .L5
  91 .L4:                            /* if (x_low < 0.0)  */
  92         fsub    fp3,fp1,fp8     /* x0 = x_high - tau;  */
  93         fadd    fp4,fp2,fp8     /* x1 = x_low + tau;  */
  94 .L5:
  95         fadd    fp5,fp4,fp13    /* r1 = r1 + TWO52;  */
  96         fsub    fp5,fp5,fp13    /* r1 = r1 - TWO52;  */
  97         b       .L9
  98 .L6:                            /* if (x < 0.0)  */
  99         fctidz  fp0,fp8
 100         fcfid   fp8,fp0         /* tau = floor(x_high/TWO52);  */
 101         fadd    fp8,fp8,fp8     /* tau++; Make tau even  */
 102         bnl     cr5,.L7         /* if (x_low < 0.0)  */
 103         fmr     fp3,fp1
 104         fmr     fp4,fp2
 105         b       .L8
 106 .L7:                            /* if (x_low > 0.0)  */
 107         fsub    fp3,fp1,fp8     /* x0 = x_high - tau;  */
 108         fadd    fp4,fp2,fp8     /* x1 = x_low + tau;  */
 109 .L8:
 110         fsub    fp5,fp4,fp13    /* r1-= TWO52;  */
 111         fadd    fp5,fp5,fp13    /* r1+= TWO52;  */
 112 .L9:
 113         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
 114         fadd    fp1,fp3,fp5     /* y_high = x0 + r1;  */
 115         fsub    fp2,fp3,fp1     /* y_low = x0 - y_high + r1;  */
 116         fadd    fp2,fp2,fp5
 117         blr
 118 END (__truncl)
 119
 120 long_double_symbol (libm, __truncl, truncl)