sysdeps/powerpc/powerpc64/fpu/s_truncf.S

   1 /* truncf function.  PowerPC64 version.
   2    Copyright (C) 2004-2014 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20
  21         .section        ".toc","aw"
  22         .p2align 3
  23 .LC0:   /* 2**23 */
  24         .long 0x4b000000
  25         .long 0x0
  26         .section        ".text"
  27
  28 /* float [fp1] truncf (float x [fp1])
  29    IEEE 1003.1 trunc function.  IEEE specifies "trunc to the integer
  30    value, in floating format, nearest to but no larger in magnitude
  31    then the argument."
  32    We set "round toward Zero" mode and trunc by adding +-2**23 then
  33    subtracting +-2**23.  */
  34
  35 EALIGN (__truncf, 4, 0)
  36         CALL_MCOUNT 0
  37         mffs    fp11            /* Save current FPU rounding mode.  */
  38         lfs     fp13,.LC0@toc(2)
  39         fabs    fp0,fp1
  40         fsubs   fp12,fp13,fp13  /* generate 0.0  */
  41         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO23)  */
  42         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  43         bnllr-  cr7
  44         mtfsfi  7,1             /* Set rounding toward 0 mode.  */
  45         ble-    cr6,.L4
  46         fadds   fp1,fp1,fp13    /* x+= TWO23;  */
  47         fsubs   fp1,fp1,fp13    /* x-= TWO23;  */
  48         fabs    fp1,fp1         /* if (x == 0.0)  */
  49                                 /* x = 0.0; */
  50         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  51         blr
  52 .L4:
  53         bge-    cr6,.L9         /* if (x < 0.0)  */
  54         fsubs   fp1,fp1,fp13    /* x-= TWO23;  */
  55         fadds   fp1,fp1,fp13    /* x+= TWO23;  */
  56         fnabs   fp1,fp1         /* if (x == 0.0)  */
  57                                 /* x = -0.0; */
  58 .L9:
  59         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  60         blr
  61         END (__truncf)
  62
  63 weak_alias (__truncf, truncf)
  64