sysdeps/powerpc/powerpc64/fpu/s_round.S

   1 /* round function.  PowerPC64 version.
   2    Copyright (C) 2004-2014 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20 #include <math_ldbl_opt.h>
  21
  22         .section        ".toc","aw"
  23 .LC0:   /* 2**52 */
  24         .tc FD_43300000_0[TC],0x4330000000000000
  25 .LC1:   /* 0.5 */
  26         .tc FD_3fe00000_0[TC],0x3fe0000000000000
  27         .section        ".text"
  28
  29 /* double [fp1] round (double x [fp1])
  30    IEEE 1003.1 round function.  IEEE specifies "round to the nearest
  31    integer value, rounding halfway cases away from zero, regardless of
  32    the current rounding mode."  However PowerPC Architecture defines
  33    "Round to Nearest" as "Choose the best approximation. In case of a
  34    tie, choose the one that is even (least significant bit o).".
  35    So we can't use the PowerPC "Round to Nearest" mode. Instead we set
  36    "Round toward Zero" mode and round by adding +-0.5 before rounding
  37    to the integer value.  */
  38
  39 EALIGN (__round, 4, 0)
  40         CALL_MCOUNT 0
  41         mffs    fp11            /* Save current FPU rounding mode.  */
  42         lfd     fp13,.LC0@toc(2)
  43         fabs    fp0,fp1
  44         fsub    fp12,fp13,fp13  /* generate 0.0  */
  45         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO52)  */
  46         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  47         bnllr-  cr7
  48         mtfsfi  7,1             /* Set rounding mode toward 0.  */
  49         lfd     fp10,.LC1@toc(2)
  50         ble-    cr6,.L4
  51         fadd    fp1,fp1,fp10    /* x+= 0.5;  */
  52         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  53         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  54         fabs    fp1,fp1         /* if (x == 0.0)  */
  55                                 /* x = 0.0; */
  56         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  57         blr
  58 .L4:
  59         fsub    fp9,fp1,fp10    /* x+= 0.5;  */
  60         bge-    cr6,.L9         /* if (x < 0.0)  */
  61         fsub    fp1,fp9,fp13    /* x-= TWO52;  */
  62         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  63         fnabs   fp1,fp1         /* if (x == 0.0)  */
  64                                 /* x = -0.0; */
  65 .L9:
  66         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  67         blr
  68         END (__round)
  69
  70 weak_alias (__round, round)
  71
  72 #ifdef NO_LONG_DOUBLE
  73 weak_alias (__round, roundl)
  74 strong_alias (__round, __roundl)
  75 #endif
  76 #if LONG_DOUBLE_COMPAT(libm, GLIBC_2_1)
  77 compat_symbol (libm, __round, roundl, GLIBC_2_1)
  78 #endif