sysdeps/powerpc/powerpc64/fpu/s_rintf.S

   1 /* Round float to int floating-point values.  PowerPC64 version.
   2    Copyright (C) 2004-2014 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20
  21         .section        ".toc","aw"
  22         .p2align 3
  23 .LC0:   /* 2**23 */
  24         .long 0x4b000000
  25         .long 0x0
  26         .section        ".text"
  27
  28 EALIGN (__rintf, 4, 0)
  29         CALL_MCOUNT 0
  30         lfs     fp13,.LC0@toc(2)
  31         fabs    fp0,fp1
  32         fsubs   fp12,fp13,fp13  /* generate 0.0  */
  33         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO23)  */
  34         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  35         bnllr   cr7
  36         bng     cr6,.L4
  37         fadds   fp1,fp1,fp13    /* x+= TWO23;  */
  38         fsubs   fp1,fp1,fp13    /* x-= TWO23;  */
  39         fabs    fp1,fp1         /* if (x == 0.0)  */
  40         blr                     /* x = 0.0; */
  41 .L4:
  42         bnllr   cr6             /* if (x < 0.0)  */
  43         fsubs   fp1,fp1,fp13    /* x-= TWO23;  */
  44         fadds   fp1,fp1,fp13    /* x+= TWO23;  */
  45         fnabs   fp1,fp1         /* if (x == 0.0)  */
  46         blr                     /* x = -0.0; */
  47         END (__rintf)
  48
  49 weak_alias (__rintf, rintf)
  50