sysdeps/powerpc/powerpc64/fpu/s_floor.S

   1 /* Floor function.  PowerPC64 version.
   2    Copyright (C) 2004-2014 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20 #include <math_ldbl_opt.h>
  21
  22         .section        ".toc","aw"
  23 .LC0:   /* 2**52 */
  24         .tc FD_43300000_0[TC],0x4330000000000000
  25         .section        ".text"
  26
  27 EALIGN (__floor, 4, 0)
  28         CALL_MCOUNT 0
  29         mffs    fp11            /* Save current FPU rounding mode.  */
  30         lfd     fp13,.LC0@toc(2)
  31         fabs    fp0,fp1
  32         fsub    fp12,fp13,fp13  /* generate 0.0  */
  33         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO52)  */
  34         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  35         bnllr-  cr7
  36         mtfsfi  7,3             /* Set rounding mode toward -inf.  */
  37         ble-    cr6,.L4
  38         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  39         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  40         fabs    fp1,fp1         /* if (x == 0.0)  */
  41                                 /* x = 0.0; */
  42         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  43         blr
  44 .L4:
  45         bge-    cr6,.L9         /* if (x < 0.0)  */
  46         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  47         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  48         fnabs   fp1,fp1         /* if (x == 0.0)  */
  49                                 /* x = -0.0; */
  50 .L9:
  51         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  52         blr
  53         END (__floor)
  54
  55 weak_alias (__floor, floor)
  56
  57 #ifdef NO_LONG_DOUBLE
  58 weak_alias (__floor, floorl)
  59 strong_alias (__floor, __floorl)
  60 #endif
  61 #if LONG_DOUBLE_COMPAT(libm, GLIBC_2_0)
  62 compat_symbol (libm, __floor, floorl, GLIBC_2_0)
  63 #endif