sysdeps/powerpc/powerpc32/power7/fpu/s_isinf.S

   1 /* isinf().  PowerPC32/POWER7 version.
   2    Copyright (C) 2010-2014 Free Software Foundation, Inc.
   3    Contributed by Luis Machado <luisgpm@br.ibm.com>.
   4    This file is part of the GNU C Library.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 #include <sysdep.h>
  21 #include <math_ldbl_opt.h>
  22
  23 /* int __isinf(x)  */
  24         .section    .rodata.cst8,"aM",@progbits,8
  25         .align 3
  26 .LC0:   /* 1.0 */
  27         .quad       0x3ff0000000000000
  28
  29         .section    ".text"
  30         .type       __isinf, @function
  31         .machine    power7
  32 ENTRY (__isinf)
  33 #ifdef SHARED
  34         mflr    r11
  35         cfi_register(lr,r11)
  36
  37         SETUP_GOT_ACCESS(r9,got_label)
  38         addis   r9,r9,.LC0-got_label@ha
  39         lfd     fp0,.LC0-got_label@l(r9)
  40
  41         mtlr    r11
  42         cfi_same_value (lr)
  43 #else
  44         lis     r9,.LC0@ha
  45         lfd     fp0,.LC0@l(r9)
  46 #endif
  47         ftdiv   cr7,fp1,fp0
  48         li      r3,0
  49         bflr    29            /* If not INF, return.  */
  50
  51         /* Either we have +INF or -INF.  */
  52
  53         stwu    r1,-16(r1)    /* Allocate stack space.  */
  54         stfd    fp1,8(r1)     /* Transfer FP to GPR's.  */
  55         ori     2,2,0         /* Force a new dispatch group.  */
  56         lhz     r4,8+HISHORT(r1) /* Fetch the upper 16 bits of the FP value
  57                                     (biased exponent and sign bit).  */
  58         addi    r1,r1,16      /* Reset the stack pointer.  */
  59         cmpwi   cr7,r4,0x7ff0 /* r4 == 0x7ff0?  */
  60         li      r3,1
  61         beqlr   cr7           /* EQ means INF, otherwise -INF.  */
  62         li      r3,-1
  63         blr
  64         END (__isinf)
  65
  66 hidden_def (__isinf)
  67 weak_alias (__isinf, isinf)
  68
  69 /* It turns out that the 'double' version will also always work for
  70    single-precision.  */
  71 strong_alias (__isinf, __isinff)
  72 hidden_def (__isinff)
  73 weak_alias (__isinff, isinff)
  74
  75 #ifdef NO_LONG_DOUBLE
  76 strong_alias (__isinf, __isinfl)
  77 weak_alias (__isinf, isinfl)
  78 #endif
  79
  80 #ifndef IS_IN_libm
  81 # if LONG_DOUBLE_COMPAT(libc, GLIBC_2_0)
  82 compat_symbol (libc, __isinf, __isinfl, GLIBC_2_0);
  83 compat_symbol (libc, isinf, isinfl, GLIBC_2_0);
  84 # endif
  85 #endif