sysdeps/powerpc/powerpc32/fpu/s_roundf.S

   1 /* roundf  function.  PowerPC32 version.
   2    Copyright (C) 2004-2014 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20
  21         .section        .rodata.cst8,"aM",@progbits,8
  22         .align  3
  23 .LC0:   /* 2**23 */
  24         .long 0x4b000000
  25 .LC1:   /* 0.5 */
  26         .long 0x3f000000
  27
  28 /* float [fp1] roundf  (float x [fp1])
  29    IEEE 1003.1 round function.  IEEE specifies "round to the nearest
  30    integer value, rounding halfway cases away from zero, regardless of
  31    the current rounding mode."  However PowerPC Architecture defines
  32    "Round to Nearest" as "Choose the best approximation. In case of a
  33    tie, choose the one that is even (least significant bit o).".
  34    So we can't use the PowerPC "Round to Nearest" mode. Instead we set
  35    "Round toward Zero" mode and round by adding +-0.5 before rounding
  36    to the integer value.  */
  37
  38         .section        ".text"
  39 ENTRY (__roundf )
  40         mffs    fp11            /* Save current FPU rounding mode.  */
  41 #ifdef SHARED
  42         mflr    r11
  43         cfi_register(lr,r11)
  44         SETUP_GOT_ACCESS(r9,got_label)
  45         addis   r9,r9,.LC0-got_label@ha
  46         addi    r9,r9,.LC0-got_label@l
  47         mtlr    r11
  48         cfi_same_value (lr)
  49         lfs     fp13,0(r9)
  50 #else
  51         lis     r9,.LC0@ha
  52         lfs     fp13,.LC0@l(r9)
  53 #endif
  54         fabs    fp0,fp1
  55         fsubs   fp12,fp13,fp13  /* generate 0.0  */
  56         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO23)  */
  57         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  58         bnllr-  cr7
  59         mtfsfi  7,1             /* Set rounding mode toward 0.  */
  60 #ifdef SHARED
  61         lfs     fp10,.LC1-.LC0(r9)
  62 #else
  63         lfs     fp10,.LC1@l(r9)
  64 #endif
  65         ble-    cr6,.L4
  66         fadds   fp1,fp1,fp10    /* x+= 0.5;  */
  67         fadds   fp1,fp1,fp13    /* x+= TWO23;  */
  68         fsubs   fp1,fp1,fp13    /* x-= TWO23;  */
  69         fabs    fp1,fp1         /* if (x == 0.0)  */
  70                                 /* x = 0.0; */
  71         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  72         blr
  73 .L4:
  74         fsubs   fp9,fp1,fp10    /* x+= 0.5;  */
  75         bge-    cr6,.L9         /* if (x < 0.0)  */
  76         fsubs   fp1,fp9,fp13    /* x-= TWO23;  */
  77         fadds   fp1,fp1,fp13    /* x+= TWO23;  */
  78         fnabs   fp1,fp1         /* if (x == 0.0)  */
  79                                 /* x = -0.0; */
  80 .L9:
  81         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  82         blr
  83         END (__roundf)
  84
  85 weak_alias (__roundf, roundf)
  86