sysdeps/powerpc/powerpc32/fpu/s_nearbyintf.S

   1 /* Round to int floating-point values.  PowerPC32 version.
   2    Copyright (C) 2011-2014 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Adhemerval Zanella <azanella@br.ibm.com>, 2011
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 /* This has been coded in assembler because GCC makes such a mess of it
  21    when it's coded in C.  */
  22
  23 #include <sysdep.h>
  24
  25
  26 /* float [fp1] nearbyintf(float [fp1] x) */
  27
  28         .section        .rodata.cst4,"aM",@progbits,4
  29         .align  2
  30 .LC0:
  31         .long 0x4B000000        /* TWO23: 2**23 */
  32
  33         .section        ".text"
  34 ENTRY (__nearbyintf)
  35 #ifdef SHARED
  36         mflr    r11
  37         cfi_register(lr,r11)
  38         bcl     20,31,1f
  39 1:      mflr    r9
  40         addis   r9,r9,.LC0-1b@ha
  41         lfs     fp13,.LC0-1b@l(r9)
  42         mtlr    r11
  43         cfi_same_value (lr)
  44 #else
  45         lis     r9,.LC0@ha
  46         lfs     fp13,.LC0@l(r9)
  47 #endif
  48         fabs    fp0,fp1
  49         fsub    fp12,fp13,fp13          /* generate 0.0  */
  50         fcmpu   cr7,fp0,fp13            /* if (fabs(x) > TWO23 */
  51         bgelr   cr7
  52         fcmpu   cr7,fp1,fp12            /* if (x > 0.0 */
  53         ble     cr7,L(lessthanzero)
  54         mtfsb0  4*cr7+lt                /* Disable FE_INEXACT exception */
  55         fadds   fp0,fp1,fp13            /* x += TWO23 */
  56         fsubs   fp1,fp0,fp13            /* x -= TWO23 */
  57         mtfsb0  4*cr1+eq                /* Clear any FE_INEXACT exception */
  58         blr
  59 L(lessthanzero):
  60         bgelr   cr7
  61         mtfsb0  4*cr7+lt                /* Disable FE_INEXACT exception */
  62         fsubs   fp0,fp13,fp1            /* x -= TWO23 */
  63         fsubs   fp0,fp0,fp13            /* x += TWO23 */
  64         fneg    fp1,fp0                 /* if (x == 0.0) */
  65         mtfsb0  4*cr1+eq                /* Clear any FE_INEXACT exception */
  66         blr
  67 END (__nearbyintf)
  68
  69 weak_alias (__nearbyintf, nearbyintf)