sysdeps/powerpc/powerpc32/fpu/s_floor.S

   1 /* Floor function.  PowerPC32 version.
   2    Copyright (C) 2004-2014 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20 #include <math_ldbl_opt.h>
  21
  22         .section        .rodata.cst4,"aM",@progbits,4
  23         .align  2
  24 .LC0:   /* 2**52 */
  25         .long 0x59800000
  26
  27         .section        ".text"
  28 ENTRY (__floor)
  29         mffs    fp11            /* Save current FPU rounding mode.  */
  30 #ifdef SHARED
  31         mflr    r11
  32         cfi_register(lr,r11)
  33         SETUP_GOT_ACCESS(r9,got_label)
  34         addis   r9,r9,.LC0-got_label@ha
  35         lfs     fp13,.LC0-got_label@l(r9)
  36         mtlr    r11
  37         cfi_same_value (lr)
  38 #else
  39         lis     r9,.LC0@ha
  40         lfs     fp13,.LC0@l(r9)
  41 #endif
  42         fabs    fp0,fp1
  43         fsub    fp12,fp13,fp13  /* generate 0.0  */
  44         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO52)  */
  45         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  46         bnllr-  cr7
  47         mtfsfi  7,3             /* Set rounding mode toward -inf.  */
  48         ble-    cr6,.L4
  49         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  50         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  51         fabs    fp1,fp1         /* if (x == 0.0)  */
  52                                 /* x = 0.0; */
  53         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  54         blr
  55 .L4:
  56         bge-    cr6,.L9         /* if (x < 0.0)  */
  57         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  58         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  59         fnabs   fp1,fp1         /* if (x == 0.0)  */
  60                                 /* x = -0.0; */
  61 .L9:
  62         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  63         blr
  64         END (__floor)
  65
  66 weak_alias (__floor, floor)
  67
  68 #ifdef NO_LONG_DOUBLE
  69 weak_alias (__floor, floorl)
  70 strong_alias (__floor, __floorl)
  71 #endif
  72 #if LONG_DOUBLE_COMPAT(libm, GLIBC_2_0)
  73 compat_symbol (libm, __floor, floorl, GLIBC_2_0)
  74 #endif