sysdeps/i386/setjmp.S

   1 /* setjmp for i386.
   2    Copyright (C) 1995-2014 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20 #include <jmpbuf-offsets.h>
  21 #include <asm-syntax.h>
  22 #include <stap-probe.h>
  23
  24 #define PARMS   4               /* no space for saved regs */
  25 #define JMPBUF  PARMS
  26 #define SIGMSK  JMPBUF+4
  27
  28 ENTRY (__sigsetjmp)
  29
  30         movl JMPBUF(%esp), %eax
  31
  32         /* Save registers.  */
  33         movl %ebx, (JB_BX*4)(%eax)
  34         movl %esi, (JB_SI*4)(%eax)
  35         movl %edi, (JB_DI*4)(%eax)
  36         leal JMPBUF(%esp), %ecx /* Save SP as it will be after we return.  */
  37 #ifdef PTR_MANGLE
  38         PTR_MANGLE (%ecx)
  39 #endif
  40         movl %ecx, (JB_SP*4)(%eax)
  41         movl 0(%esp), %ecx      /* Save PC we are returning to now.  */
  42         LIBC_PROBE (setjmp, 3, 4@%eax, -4@SIGMSK(%esp), 4@%ecx)
  43 #ifdef PTR_MANGLE
  44         PTR_MANGLE (%ecx)
  45 #endif
  46         movl %ecx, (JB_PC*4)(%eax)
  47         movl %ebp, (JB_BP*4)(%eax) /* Save caller's frame pointer.  */
  48
  49 #if defined NOT_IN_libc && defined IS_IN_rtld
  50         /* In ld.so we never save the signal mask.  */
  51         xorl %eax, %eax
  52         ret
  53 #else
  54         /* Make a tail call to __sigjmp_save; it takes the same args.  */
  55         jmp __sigjmp_save
  56 #endif
  57 END (__sigsetjmp)