sysdeps/i386/i686/multiarch/strlen.S

   1 /* Multiple versions of strlen
   2    All versions must be listed in ifunc-impl-list.c.
   3    Copyright (C) 2009-2014 Free Software Foundation, Inc.
   4    Contributed by Intel Corporation.
   5    This file is part of the GNU C Library.
   6
   7    The GNU C Library is free software; you can redistribute it and/or
   8    modify it under the terms of the GNU Lesser General Public
   9    License as published by the Free Software Foundation; either
  10    version 2.1 of the License, or (at your option) any later version.
  11
  12    The GNU C Library is distributed in the hope that it will be useful,
  13    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15    Lesser General Public License for more details.
  16
  17    You should have received a copy of the GNU Lesser General Public
  18    License along with the GNU C Library; if not, see
  19    <http://www.gnu.org/licenses/>.  */
  20
  21 #include <sysdep.h>
  22 #include <init-arch.h>
  23
  24 /* Define multiple versions only for the definition in libc and for the
  25    DSO.  In static binaries, we need strlen before the initialization
  26    happened.  */
  27 #if defined SHARED && !defined NOT_IN_libc
  28         .text
  29 ENTRY(strlen)
  30         .type   strlen, @gnu_indirect_function
  31         pushl   %ebx
  32         cfi_adjust_cfa_offset (4)
  33         cfi_rel_offset (ebx, 0)
  34         LOAD_PIC_REG(bx)
  35         cmpl    $0, KIND_OFFSET+__cpu_features@GOTOFF(%ebx)
  36         jne     1f
  37         call    __init_cpu_features
  38 1:      leal    __strlen_ia32@GOTOFF(%ebx), %eax
  39         testl   $bit_SSE2, CPUID_OFFSET+index_SSE2+__cpu_features@GOTOFF(%ebx)
  40         jz      2f
  41         leal    __strlen_sse2_bsf@GOTOFF(%ebx), %eax
  42         testl   $bit_Slow_BSF, FEATURE_OFFSET+index_Slow_BSF+__cpu_features@GOTOFF(%ebx)
  43         jz      2f
  44         leal    __strlen_sse2@GOTOFF(%ebx), %eax
  45 2:      popl    %ebx
  46         cfi_adjust_cfa_offset (-4);
  47         cfi_restore (ebx)
  48         ret
  49 END(strlen)
  50
  51 # undef ENTRY
  52 # define ENTRY(name) \
  53         .type __strlen_ia32, @function; \
  54         .globl __strlen_ia32; \
  55         .p2align 4; \
  56         __strlen_ia32: cfi_startproc; \
  57         CALL_MCOUNT
  58 # undef END
  59 # define END(name) \
  60         cfi_endproc; .size __strlen_ia32, .-__strlen_ia32
  61 # undef libc_hidden_builtin_def
  62 /* IFUNC doesn't work with the hidden functions in shared library since
  63    they will be called without setting up EBX needed for PLT which is
  64    used by IFUNC.  */
  65 # define libc_hidden_builtin_def(name) \
  66         .globl __GI_strlen; __GI_strlen = __strlen_ia32
  67 #endif
  68
  69 #include "../../i586/strlen.S"