sysdeps/i386/i686/multiarch/memset.S

   1 /* Multiple versions of memset
   2    All versions must be listed in ifunc-impl-list.c.
   3    Copyright (C) 2010-2014 Free Software Foundation, Inc.
   4    Contributed by Intel Corporation.
   5    This file is part of the GNU C Library.
   6
   7    The GNU C Library is free software; you can redistribute it and/or
   8    modify it under the terms of the GNU Lesser General Public
   9    License as published by the Free Software Foundation; either
  10    version 2.1 of the License, or (at your option) any later version.
  11
  12    The GNU C Library is distributed in the hope that it will be useful,
  13    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15    Lesser General Public License for more details.
  16
  17    You should have received a copy of the GNU Lesser General Public
  18    License along with the GNU C Library; if not, see
  19    <http://www.gnu.org/licenses/>.  */
  20
  21 #include <sysdep.h>
  22 #include <init-arch.h>
  23
  24 /* Define multiple versions only for the definition in lib.  */
  25 #ifndef NOT_IN_libc
  26 # ifdef SHARED
  27         .text
  28 ENTRY(memset)
  29         .type   memset, @gnu_indirect_function
  30         pushl   %ebx
  31         cfi_adjust_cfa_offset (4)
  32         cfi_rel_offset (ebx, 0)
  33         LOAD_PIC_REG(bx)
  34         cmpl    $0, KIND_OFFSET+__cpu_features@GOTOFF(%ebx)
  35         jne     1f
  36         call    __init_cpu_features
  37 1:      leal    __memset_ia32@GOTOFF(%ebx), %eax
  38         testl   $bit_SSE2, CPUID_OFFSET+index_SSE2+__cpu_features@GOTOFF(%ebx)
  39         jz      2f
  40         leal    __memset_sse2@GOTOFF(%ebx), %eax
  41         testl   $bit_Fast_Rep_String, FEATURE_OFFSET+index_Fast_Rep_String+__cpu_features@GOTOFF(%ebx)
  42         jz      2f
  43         leal    __memset_sse2_rep@GOTOFF(%ebx), %eax
  44 2:      popl    %ebx
  45         cfi_adjust_cfa_offset (-4)
  46         cfi_restore (ebx)
  47         ret
  48 END(memset)
  49 # else
  50         .text
  51 ENTRY(memset)
  52         .type   memset, @gnu_indirect_function
  53         cmpl    $0, KIND_OFFSET+__cpu_features
  54         jne     1f
  55         call    __init_cpu_features
  56 1:      leal    __memset_ia32, %eax
  57         testl   $bit_SSE2, CPUID_OFFSET+index_SSE2+__cpu_features
  58         jz      2f
  59         leal    __memset_sse2, %eax
  60         testl   $bit_Fast_Rep_String, FEATURE_OFFSET+index_Fast_Rep_String+__cpu_features
  61         jz      2f
  62         leal    __memset_sse2_rep, %eax
  63 2:      ret
  64 END(memset)
  65 # endif
  66
  67 # undef ENTRY
  68 # define ENTRY(name) \
  69         .type __memset_ia32, @function; \
  70         .globl __memset_ia32; \
  71         .p2align 4; \
  72         __memset_ia32: cfi_startproc; \
  73         CALL_MCOUNT
  74 # undef END
  75 # define END(name) \
  76         cfi_endproc; .size __memset_ia32, .-__memset_ia32
  77
  78 # undef ENTRY_CHK
  79 # define ENTRY_CHK(name) \
  80         .type __memset_chk_ia32, @function; \
  81         .globl __memset_chk_ia32; \
  82         .p2align 4; \
  83         __memset_chk_ia32: cfi_startproc; \
  84         CALL_MCOUNT
  85 # undef END_CHK
  86 # define END_CHK(name) \
  87         cfi_endproc; .size __memset_chk_ia32, .-__memset_chk_ia32
  88
  89 # ifdef SHARED
  90 #  undef libc_hidden_builtin_def
  91 /* IFUNC doesn't work with the hidden functions in shared library since
  92    they will be called without setting up EBX needed for PLT which is
  93    used by IFUNC.  */
  94 #  define libc_hidden_builtin_def(name) \
  95         .globl __GI_memset; __GI_memset = __memset_ia32
  96 # endif
  97
  98 # undef strong_alias
  99 # define strong_alias(original, alias)
 100 #endif
 101
 102 #include "../memset.S"