sysdeps/i386/i686/memset.S

   1 /* memset/bzero -- set memory area to CH/0
   2    Highly optimized version for ix86, x>=6.
   3    Copyright (C) 1999-2014 Free Software Foundation, Inc.
   4    This file is part of the GNU C Library.
   5    Contributed by Ulrich Drepper <drepper@cygnus.com>, 1999.
   6
   7    The GNU C Library is free software; you can redistribute it and/or
   8    modify it under the terms of the GNU Lesser General Public
   9    License as published by the Free Software Foundation; either
  10    version 2.1 of the License, or (at your option) any later version.
  11
  12    The GNU C Library is distributed in the hope that it will be useful,
  13    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15    Lesser General Public License for more details.
  16
  17    You should have received a copy of the GNU Lesser General Public
  18    License along with the GNU C Library; if not, see
  19    <http://www.gnu.org/licenses/>.  */
  20
  21 #include <sysdep.h>
  22 #include "asm-syntax.h"
  23
  24 /* BEWARE: `#ifdef memset' means that memset is redefined as `bzero' */
  25 #define BZERO_P (defined memset)
  26
  27 #define PARMS   4+4     /* space for 1 saved reg */
  28 #if BZERO_P
  29 # define DEST   PARMS
  30 # define LEN    DEST+4
  31 #else
  32 # define RTN    PARMS
  33 # define DEST   RTN
  34 # define CHR    DEST+4
  35 # define LEN    CHR+4
  36 #endif
  37
  38         .text
  39 #if defined PIC && !defined NOT_IN_libc && !BZERO_P
  40 ENTRY_CHK (__memset_chk)
  41         movl    12(%esp), %eax
  42         cmpl    %eax, 16(%esp)
  43         jb      HIDDEN_JUMPTARGET (__chk_fail)
  44 END_CHK (__memset_chk)
  45 #endif
  46 ENTRY (memset)
  47
  48         cld
  49         pushl   %edi
  50         cfi_adjust_cfa_offset (4)
  51         movl    DEST(%esp), %edx
  52         movl    LEN(%esp), %ecx
  53 #if BZERO_P
  54         xorl    %eax, %eax      /* fill with 0 */
  55 #else
  56         movzbl  CHR(%esp), %eax
  57 #endif
  58         jecxz   1f
  59         movl    %edx, %edi
  60         cfi_rel_offset (edi, 0)
  61         andl    $3, %edx
  62         jz      2f      /* aligned */
  63         jp      3f      /* misaligned at 3, store just one byte below */
  64         stosb           /* misaligned at 1 or 2, store two bytes */
  65         decl    %ecx
  66         jz      1f
  67 3:      stosb
  68         decl    %ecx
  69         jz      1f
  70         xorl    $1, %edx
  71         jnz     2f      /* was misaligned at 2 or 3, now aligned */
  72         stosb           /* was misaligned at 1, store third byte */
  73         decl    %ecx
  74 2:      movl    %ecx, %edx
  75         shrl    $2, %ecx
  76         andl    $3, %edx
  77 #if !BZERO_P
  78         imul    $0x01010101, %eax
  79 #endif
  80         rep
  81         stosl
  82         movl    %edx, %ecx
  83         rep
  84         stosb
  85
  86 1:
  87 #if !BZERO_P
  88         movl DEST(%esp), %eax   /* start address of destination is result */
  89 #endif
  90         popl    %edi
  91         cfi_adjust_cfa_offset (-4)
  92         cfi_restore (edi)
  93
  94 #if BZERO_P
  95         ret
  96 #else
  97         ret
  98 #endif
  99 END (memset)
 100 libc_hidden_builtin_def (memset)
 101
 102 #if defined PIC && !defined NOT_IN_libc && !BZERO_P
 103 strong_alias (__memset_chk, __memset_zero_constant_len_parameter)
 104         .section .gnu.warning.__memset_zero_constant_len_parameter
 105         .string "memset used with constant zero length parameter; this could be due to transposed parameters"
 106 #endif