ports/sysdeps/unix/sysv/linux/m68k/socket.S

   1 /* Copyright (C) 1996-2014 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3
   4    The GNU C Library is free software; you can redistribute it and/or
   5    modify it under the terms of the GNU Lesser General Public
   6    License as published by the Free Software Foundation; either
   7    version 2.1 of the License, or (at your option) any later version.
   8
   9    The GNU C Library is distributed in the hope that it will be useful,
  10    but WITHOUT ANY WARRANTY; without even the implied warranty of
  11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12    Lesser General Public License for more details.
  13
  14    You should have received a copy of the GNU Lesser General Public
  15    License along with the GNU C Library.  If not, see
  16    <http://www.gnu.org/licenses/>.  */
  17
  18 #include <sysdep-cancel.h>
  19 #include <socketcall.h>
  20
  21 #define P(a, b) P2(a, b)
  22 #define P2(a, b) a##b
  23
  24         .text
  25 /* The socket-oriented system calls are handled unusally in Linux.
  26    They are all gated through the single `socketcall' system call number.
  27    `socketcall' takes two arguments: the first is the subcode, specifying
  28    which socket function is being called; and the second is a pointer to
  29    the arguments to the specific function.
  30
  31    The .S files for the other calls just #define socket and #include this.  */
  32
  33 #ifndef __socket
  34 #ifndef NO_WEAK_ALIAS
  35 #define __socket P(__,socket)
  36 #else
  37 #define __socket socket
  38 #endif
  39 #endif
  40
  41 .globl __socket
  42 ENTRY (__socket)
  43 #ifdef NEED_CANCELLATION
  44 # if !defined CENABLE || !defined CDISABLE
  45 #  error CENABLE and/or CDISABLE is not defined
  46 # endif
  47         SINGLE_THREAD_P
  48         jne 1f
  49 #endif
  50
  51         /* Save registers.  */
  52         move.l %d2, %a0
  53         cfi_register (%d2, %a0)
  54
  55         move.l #SYS_ify (socketcall), %d0 /* System call number in %d0.  */
  56
  57         /* Use ## so `socket' is a separate token that might be #define'd.  */
  58         move.l #P (SOCKOP_,socket), %d1 /* Subcode is first arg to syscall.  */
  59         lea 4(%sp), %a1                 /* Address of args is 2nd arg.  */
  60         move.l %a1, %d2
  61
  62         /* Do the system call trap.  */
  63         trap #0
  64
  65         /* Restore registers.  */
  66         move.l %a0, %d2
  67         cfi_restore (%d2)
  68
  69         /* %d0 is < 0 if there was an error.  */
  70         tst.l %d0
  71         jmi SYSCALL_ERROR_LABEL
  72
  73         /* Successful; return the syscall's value.  */
  74         rts
  75
  76 #ifdef NEED_CANCELLATION
  77 1:      /* Enable asynchronous cancellation.  */
  78         CENABLE
  79
  80         /* Save D2.  */
  81         move.l %d2, -(%sp)
  82         cfi_adjust_cfa_offset (4)
  83         cfi_rel_offset (%d2, 0)
  84
  85         /* Save the result of CENABLE.  */
  86         move.l %d0, -(%sp)
  87         cfi_adjust_cfa_offset (4)
  88
  89         /* Use ## so `socket' is a separate token that might be #define'd.  */
  90         move.l #P (SOCKOP_,socket), %d1 /* Subcode is first arg to syscall.  */
  91         lea 4+8(%sp), %a1               /* Address of args is 2nd arg.  */
  92         move.l %a1, %d2
  93
  94         move.l #SYS_ify (socketcall), %d0 /* System call number in %d0.  */
  95         /* Do the system call trap.  */
  96         trap #0
  97
  98         /* Restore cancellation.  */
  99         move.l %d0, %d2
 100         CDISABLE
 101         addq.l #4, %sp
 102         cfi_adjust_cfa_offset (-4)
 103         move.l %d2, %d0
 104
 105         /* Restore registers.  */
 106         move.l (%sp)+, %d2
 107         cfi_adjust_cfa_offset (-4)
 108         cfi_restore (%d2)
 109
 110         /* %d0 is < 0 if there was an error.  */
 111         tst.l %d0
 112         jmi SYSCALL_ERROR_LABEL
 113
 114         /* Successful; return the syscall's value.  */
 115         rts
 116 #endif
 117
 118 PSEUDO_END (__socket)
 119
 120 #ifndef NO_WEAK_ALIAS
 121 weak_alias (__socket, socket)
 122 #endif