ports/sysdeps/unix/sysv/linux/m68k/clone.S

   1 /* Copyright (C) 1996-2014 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Contributed by Andreas Schwab (schwab@issan.informatik.uni-dortmund.de)
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library.  If not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 /* clone() is even more special than fork() as it mucks with stacks
  20    and invokes a function in the right context after its all over.  */
  21
  22 #include <sysdep.h>
  23 #define _ERRNO_H        1
  24 #include <bits/errno.h>
  25 #ifdef RESET_PID
  26 #include <tls.h>
  27 #endif
  28
  29 #define CLONE_VM      0x00000100
  30 #define CLONE_THREAD  0x00010000
  31
  32 /* int clone(int (*fn)(void *arg), void *child_stack, int flags, void *arg,
  33              void *parent_tidptr, void *tls, void *child_tidptr) */
  34
  35         .text
  36 ENTRY (__clone)
  37
  38         /* Sanity check arguments.  */
  39         movel   #-EINVAL, %d0
  40         movel   4(%sp), %a0             /* no NULL function pointers */
  41         tstl    %a0
  42         jeq     SYSCALL_ERROR_LABEL
  43         movel   8(%sp), %a1             /* no NULL stack pointers */
  44         tstl    %a1
  45         jeq     SYSCALL_ERROR_LABEL
  46
  47         /* Allocate space and copy the argument onto the new stack.  */
  48         movel   16(%sp), -(%a1)
  49
  50         /* Do the system call */
  51         movel   12+0(%sp), %d1          /* get flags */
  52         movel   %d3, -(%a1)             /* save %d3 and get parent_tidptr */
  53         movel   %d3, -(%sp)
  54         cfi_adjust_cfa_offset (4)
  55         cfi_rel_offset (%d3, 0)
  56         movel   20+4(%sp), %d3
  57         movel   %d4, -(%a1)             /* save %d4 and get child_tidptr */
  58         movel   %d4, -(%sp)
  59         cfi_adjust_cfa_offset (4)
  60         cfi_rel_offset (%d4, 0)
  61         movel   28+8(%sp), %d4
  62         movel   %d5, -(%a1)             /* save %d5 and get tls */
  63         movel   %d5, -(%sp)
  64         cfi_adjust_cfa_offset (4)
  65         cfi_rel_offset (%d5, 0)
  66         movel   24+12(%sp), %d5
  67         /* save %d2 and get stack pointer */
  68 #ifdef __mcoldfire__
  69         movel   %d2, -(%a1)
  70         movel   %d2, -(%sp)
  71         cfi_adjust_cfa_offset (4)
  72         cfi_rel_offset (%d2, 0)
  73         movel   %a1, %d2
  74 #else
  75         exg     %d2, %a1                /* save %d2 and get stack pointer */
  76         cfi_register (%d2, %a1)
  77 #endif
  78         movel   #SYS_ify (clone), %d0
  79
  80         /* End FDE now, because in the child the unwind info will be
  81            wrong.  */
  82         cfi_endproc
  83
  84         trap    #0
  85 #ifdef __mcoldfire__
  86         movel   (%sp)+, %d2
  87 #else
  88         exg     %d2, %a1                /* restore %d2 */
  89 #endif
  90         movel   (%sp)+, %d5             /* restore %d5, %d4 and %d3 */
  91         movel   (%sp)+, %d4
  92         movel   (%sp)+, %d3
  93
  94         tstl    %d0
  95         jmi     SYSCALL_ERROR_LABEL
  96         jeq     thread_start
  97
  98         rts
  99
 100 thread_start:
 101         cfi_startproc
 102         cfi_undefined (pc)      /* Mark end of stack */
 103         subl    %fp, %fp        /* terminate the stack frame */
 104 #ifdef RESET_PID
 105         /* Check and see if we need to reset the PID.  */
 106         movel   %d1, %a1
 107         andl    #CLONE_THREAD, %d1
 108         jne     donepid
 109         movel   %a1, %d1
 110         movel   #-1, %d0
 111         andl    #CLONE_VM, %d1
 112         jne     gotpid
 113         movel   #SYS_ify (getpid), %d0
 114         trap    #0
 115 gotpid:
 116         movel   %a0, -(%sp)
 117         movel   %d0, -(%sp)
 118         bsrl    __m68k_read_tp@PLTPC
 119         movel   (%sp)+, %d0
 120         movel   %d0, PID_OFFSET(%a0)
 121         movel   %d0, TID_OFFSET(%a0)
 122         movel   (%sp)+, %a0
 123 donepid:
 124 #endif
 125         jsr     (%a0)
 126         movel   %d0, %d1
 127         movel   #SYS_ify (exit), %d0
 128         trap    #0
 129         cfi_endproc
 130
 131         cfi_startproc
 132 PSEUDO_END (__clone)
 133
 134 weak_alias (__clone, clone)