ports/sysdeps/unix/sysv/linux/aarch64/getcontext.S

   1 /* Save current context.
   2
   3    Copyright (C) 2009-2014 Free Software Foundation, Inc.
   4
   5    This file is part of the GNU C Library.
   6
   7    The GNU C Library is free software; you can redistribute it and/or
   8    modify it under the terms of the GNU Lesser General Public License as
   9    published by the Free Software Foundation; either version 2.1 of the
  10    License, or (at your option) any later version.
  11
  12    The GNU C Library is distributed in the hope that it will be useful,
  13    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15    Lesser General Public License for more details.
  16
  17    You should have received a copy of the GNU Lesser General Public
  18    License along with the GNU C Library; if not, see
  19    <http://www.gnu.org/licenses/>.  */
  20
  21 #include <sysdep.h>
  22 #include "ucontext_i.h"
  23 #include "ucontext-internal.h"
  24
  25 /* int getcontext (ucontext_t *ucp)
  26
  27    Returns 0 on success -1 and errno on failure.
  28  */
  29
  30         .text
  31
  32 ENTRY(__getcontext)
  33         /* The saved context will return to the getcontext() call point
  34            with a return value of 0 */
  35         str     xzr,      [x0, oX0 +  0 * SZREG]
  36
  37         stp     x18, x19, [x0, oX0 + 18 * SZREG]
  38         stp     x20, x21, [x0, oX0 + 20 * SZREG]
  39         stp     x22, x23, [x0, oX0 + 22 * SZREG]
  40         stp     x24, x25, [x0, oX0 + 24 * SZREG]
  41         stp     x26, x27, [x0, oX0 + 26 * SZREG]
  42         stp     x28, x29, [x0, oX0 + 28 * SZREG]
  43         str     x30,      [x0, oX0 + 30 * SZREG]
  44
  45         /* Place LR into the saved PC, this will ensure that when
  46            switching to this saved context with setcontext() control
  47            will pass back to the caller of getcontext(), we have
  48            already arrange to return the appropriate return value in x0
  49            above.  */
  50         str     x30, [x0, oPC]
  51
  52         /* Save the current SP */
  53         mov     x2, sp
  54         str     x2, [x0, oSP]
  55
  56         /* Initialize the pstate.  */
  57         str     xzr, [x0, oPSTATE]
  58
  59         /* Figure out where to place the first context extension
  60            block.  */
  61         add     x2, x0, #oEXTENSION
  62
  63         /* Write the context extension fpsimd header.  */
  64         mov     w3, #(FPSIMD_MAGIC & 0xffff)
  65         movk    w3, #(FPSIMD_MAGIC >> 16), lsl #16
  66         str     w3, [x2, #oHEAD + oMAGIC]
  67         mov     w3, #FPSIMD_CONTEXT_SIZE
  68         str     w3, [x2, #oHEAD + oSIZE]
  69
  70         /* Fill in the FP SIMD context.  */
  71         add     x3, x2, #oV0 + 8 * SZVREG
  72         stp      d8,  d9, [x3], # 2 * SZVREG
  73         stp     d10, d11, [x3], # 2 * SZVREG
  74         stp     d12, d13, [x3], # 2 * SZVREG
  75         stp     d14, d15, [x3], # 2 * SZVREG
  76
  77         add     x3, x2, oFPSR
  78
  79         mrs     x4, fpsr
  80         str     w4, [x3]
  81
  82         mrs     x4, fpcr
  83         str     w4, [x3, oFPCR - oFPSR]
  84
  85         /* Write the termination context extension header.  */
  86         add     x2, x2, #FPSIMD_CONTEXT_SIZE
  87
  88         str     xzr, [x2, #oHEAD + oMAGIC]
  89         str     xzr, [x2, #oHEAD + oSIZE]
  90
  91         /* Grab the signal mask */
  92         /* rt_sigprocmask (SIG_BLOCK, NULL, &ucp->uc_sigmask, _NSIG8) */
  93         add     x2, x0, #UCONTEXT_SIGMASK
  94         mov     x0, SIG_BLOCK
  95         mov     x1, 0
  96         mov     x3, _NSIG8
  97         mov     x8, SYS_ify (rt_sigprocmask)
  98         svc     0
  99         cbnz    x0, 1f
 100
 101         /* Return 0 for success */
 102         mov     x0, 0
 103         RET
 104 1:
 105         b       C_SYMBOL_NAME(__syscall_error)
 106
 107         PSEUDO_END (__getcontext)
 108 weak_alias (__getcontext, getcontext)