ports/sysdeps/mips/mul_1.S

   1 /* MIPS __mpn_mul_1 -- Multiply a limb vector with a single limb and
   2 store the product in a second limb vector.
   3
   4 Copyright (C) 1995-2014 Free Software Foundation, Inc.
   5
   6 This file is part of the GNU MP Library.
   7
   8 The GNU MP Library is free software; you can redistribute it and/or modify
   9 it under the terms of the GNU Lesser General Public License as published by
  10 the Free Software Foundation; either version 2.1 of the License, or (at your
  11 option) any later version.
  12
  13 The GNU MP Library is distributed in the hope that it will be useful, but
  14 WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15 or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  16 License for more details.
  17
  18 You should have received a copy of the GNU Lesser General Public License
  19 along with the GNU MP Library.  If not, see
  20 <http://www.gnu.org/licenses/>.  */
  21
  22 #include <sysdep.h>
  23
  24 /* INPUT PARAMETERS
  25    res_ptr      $4
  26    s1_ptr       $5
  27    size         $6
  28    s2_limb      $7
  29 */
  30 #ifdef __PIC__
  31         .option pic2
  32 #endif
  33 ENTRY (__mpn_mul_1)
  34         .set    noreorder
  35 #ifdef __PIC__
  36         .cpload t9
  37 #endif
  38         .set    nomacro
  39
  40         /* warm up phase 0 */
  41         lw      $8,0($5)
  42
  43         /* warm up phase 1 */
  44         addiu   $5,$5,4
  45         multu   $8,$7
  46
  47         addiu   $6,$6,-1
  48         beq     $6,$0,L(LC0)
  49         move    $2,$0           /* zero cy2 */
  50
  51         addiu   $6,$6,-1
  52         beq     $6,$0,L(LC1)
  53         lw      $8,0($5)        /* load new s1 limb as early as possible */
  54
  55 L(Loop):        mflo    $10
  56         mfhi    $9
  57         addiu   $5,$5,4
  58         addu    $10,$10,$2      /* add old carry limb to low product limb */
  59         multu   $8,$7
  60         lw      $8,0($5)        /* load new s1 limb as early as possible */
  61         addiu   $6,$6,-1        /* decrement loop counter */
  62         sltu    $2,$10,$2       /* carry from previous addition -> $2 */
  63         sw      $10,0($4)
  64         addiu   $4,$4,4
  65         bne     $6,$0,L(Loop)   /* should be "bnel" */
  66         addu    $2,$9,$2        /* add high product limb and carry from addition */
  67
  68         /* cool down phase 1 */
  69 L(LC1): mflo    $10
  70         mfhi    $9
  71         addu    $10,$10,$2
  72         sltu    $2,$10,$2
  73         multu   $8,$7
  74         sw      $10,0($4)
  75         addiu   $4,$4,4
  76         addu    $2,$9,$2        /* add high product limb and carry from addition */
  77
  78         /* cool down phase 0 */
  79 L(LC0): mflo    $10
  80         mfhi    $9
  81         addu    $10,$10,$2
  82         sltu    $2,$10,$2
  83         sw      $10,0($4)
  84         j       $31
  85         addu    $2,$9,$2        /* add high product limb and carry from addition */
  86         END (__mpn_mul_1)