ports/sysdeps/ia64/start.S

   1 /* Copyright (C) 1999-2014 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Written by Jes Sorensen, <Jes.Sorensen@cern.ch>, April 1999.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    In addition to the permissions in the GNU Lesser General Public
  11    License, the Free Software Foundation gives you unlimited
  12    permission to link the compiled version of this file with other
  13    programs, and to distribute those programs without any restriction
  14    coming from the use of this file. (The GNU Lesser General Public
  15    License restrictions do apply in other respects; for example, they
  16    cover modification of the file, and distribution when not linked
  17    into another program.)
  18
  19    Note that people who make modified versions of this file are not
  20    obligated to grant this special exception for their modified
  21    versions; it is their choice whether to do so. The GNU Lesser
  22    General Public License gives permission to release a modified
  23    version without this exception; this exception also makes it
  24    possible to release a modified version which carries forward this
  25    exception.
  26
  27    The GNU C Library is distributed in the hope that it will be useful,
  28    but WITHOUT ANY WARRANTY; without even the implied warranty of
  29    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  30    Lesser General Public License for more details.
  31
  32    You should have received a copy of the GNU Lesser General Public
  33    License along with the GNU C Library; if not, see
  34    <http://www.gnu.org/licenses/>.  */
  35
  36 #include <sysdep.h>
  37
  38 #include <asm/unistd.h>
  39 #include <asm/fpu.h>
  40
  41 /*
  42  * Arguments for __libc_start_main:
  43  *      out0:   main
  44  *      out1:   argc
  45  *      out2:   argv
  46  *      out3:   init
  47  *      out4:   fini
  48  *      out5:   rtld_fini
  49  *      out6:   stack_end
  50  */
  51
  52         .align 32
  53         .global _start
  54
  55         .proc _start
  56         .type _start,@function
  57 _start:
  58         .prologue
  59         .save rp, r0
  60         .body
  61         .prologue
  62         { .mlx
  63           alloc r2 = ar.pfs,0,0,7,0
  64           movl r3 = FPSR_DEFAULT
  65         }
  66         { .mlx
  67           adds out2 = 16, sp    /* get address of argc value */
  68           movl gp = @gprel(0f)
  69           ;;
  70         }
  71 0:      { .mmi
  72           ld8 out1 = [out2], 8  /* load argc and move out2 to become argv */
  73           mov.m r10 = ar.bsp    /* fetch rbs base address */
  74           mov r9 = ip
  75           ;;
  76         }
  77         { .mii
  78           mov ar.fpsr = r3
  79           sub gp = r9, gp       /* back-compute gp value */
  80           adds out6 = 16, sp    /* highest non-environment stack address */
  81           ;;
  82         }
  83         {
  84           addl r11 = @ltoff(__libc_ia64_register_backing_store_base), gp
  85           addl out0 = @ltoff(@fptr(main)), gp
  86           addl out3 = @ltoff(@fptr(__libc_csu_init)), gp
  87           ;;
  88         }
  89         { .mmi
  90           ld8 r3 = [r11]        /* pointer to __libc_ia64_register_backing_store_base */
  91           ld8 out0 = [out0]     /* pointer to `main' function descriptor */
  92           addl out4 = @ltoff(@fptr(__libc_csu_fini)), gp
  93           ;;
  94         }
  95         { .mmi
  96           ld8 out3 = [out3]     /* pointer to `init' function descriptor */
  97           ld8 out4 = [out4]     /* pointer to `fini' function descriptor */
  98           nop 0
  99         }
 100         .body
 101         { .mib
 102           st8 [r3] = r10
 103           mov out5 = ret0       /* dynamic linker destructor */
 104           br.call.sptk.few rp = __libc_start_main
 105         }
 106         { .mib
 107           break 0       /* break miserably if we ever return */
 108         }
 109         .endp _start
 110
 111 /* Define a symbol for the first piece of initialized data.  */
 112         .data
 113         .globl __data_start
 114 __data_start:
 115         .long 0
 116         .weak data_start
 117         data_start = __data_start
 118
 119         .common __libc_ia64_register_backing_store_base, 8, 8