ports/sysdeps/arm/armv6/strrchr.S

   1 /* strrchr -- find the last occurence of C in a nul-terminated string
   2    Copyright (C) 2013-2014 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library.  If not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20
  21         .syntax unified
  22         .text
  23
  24 ENTRY (strrchr)
  25         @ r0 = start of string
  26         @ r1 = character to match
  27         @ returns NULL for no match, or a pointer to the match
  28
  29         mov     r3, r0
  30         mov     r0, #0
  31         uxtb    r1, r1
  32
  33         @ Loop a few times until we're aligned.
  34         tst     r3, #7
  35         beq     2f
  36 1:      sfi_breg r3, \
  37         ldrb    r2, [\B], #1
  38         cmp     r2, r1                  @ Find the character
  39         it      eq
  40         subeq   r0, r3, #1
  41         cmp     r2, #0                  @ Find EOS
  42         it      eq
  43         bxeq    lr
  44         tst     r3, #7                  @ Find the aligment point
  45         bne     1b
  46
  47         @ So now we're aligned.  Now we actually need a stack frame.
  48 2:      push    { r4, r5, r6, r7 }
  49         cfi_adjust_cfa_offset (16)
  50         cfi_rel_offset (r4, 0)
  51         cfi_rel_offset (r5, 4)
  52         cfi_rel_offset (r6, 8)
  53         cfi_rel_offset (r7, 12)
  54
  55         orr     r1, r1, r1, lsl #8      @ Replicate C to all bytes
  56 #ifdef ARCH_HAS_T2
  57         movw    ip, #0x0101
  58         movt    ip, #0x0101
  59 #else
  60         ldr     ip, =0x01010101
  61 #endif
  62         orr     r1, r1, r1, lsl #16
  63         mov     r2, #0                  @ No found bits yet
  64
  65         @ Loop searching for EOS and C, 8 bytes at a time.
  66         @ Any time we find a match in a word, we copy the address of
  67         @ the word to r0, and the found bits to r2.
  68 3:      sfi_breg r3, \
  69         ldrd    r4, r5, [\B], #8
  70         @ Subtracting (unsigned saturating) from 1 means result of 1 for
  71         @ any byte that was originally zero and 0 otherwise.  Therefore
  72         @ we consider the lsb of each byte the "found" bit.
  73         uqsub8  r6, ip, r4              @ Find EOS
  74         uqsub8  r7, ip, r5
  75         eor     r4, r4, r1              @ Convert C bytes to 0
  76         eor     r5, r5, r1
  77         uqsub8  r4, ip, r4              @ Find C
  78         uqsub8  r5, ip, r5
  79         cmp     r6, #0                  @ Found EOS, first word
  80         bne     4f
  81         cmp     r4, #0                  @ Handle C, first word
  82         itt     ne
  83         subne   r0, r3, #8
  84         movne   r2, r4
  85         cmp     r7, #0                  @ Found EOS, second word
  86         bne     5f
  87         cmp     r5, #0                  @ Handle C, second word
  88         itt     ne
  89         subne   r0, r3, #4
  90         movne   r2, r5
  91         b       3b
  92
  93         @ Found EOS in second word; fold to first word.
  94 5:      add     r3, r3, #4              @ Dec pointer to 2nd word, with below
  95         mov     r4, r5                  @ Overwrite first word C found
  96         mov     r6, r7                  @ Overwrite first word EOS found
  97
  98         @ Found EOS.  Zap found C after EOS.
  99 4:      sub     r3, r3, #8              @ Decrement pointer to first word
 100 #ifdef __ARMEB__
 101         @ Byte swap to be congruent with LE, which is easier from here on.
 102         rev     r6, r6                  @ Byte swap found EOS,
 103         rev     r4, r4                  @ ... this found C
 104         rev     r2, r2                  @ ... prev found C
 105 #endif
 106         sub     r7, r6, #1              @ Toggle EOS lsb and below
 107         eor     r6, r6, r7              @ All bits below and including lsb
 108         ands    r4, r4, r6              @ Zap C above EOS
 109         itt     ne
 110         movne   r2, r4                  @ Copy to result, if still non-zero
 111         movne   r0, r3
 112
 113         pop     { r4, r5, r6, r7 }
 114         cfi_adjust_cfa_offset (-16)
 115         cfi_restore (r4)
 116         cfi_restore (r5)
 117         cfi_restore (r6)
 118         cfi_restore (r7)
 119
 120         @ Adjust the result pointer if we found a word containing C.
 121         cmp     r2, #0
 122         clz     r2, r2                  @ Find the bit offset of the last C
 123         itt     ne
 124         rsbne   r2, r2, #32             @ Convert to a count from the right
 125         addne   r0, r0, r2, lsr #3      @ Convert to byte offset and add.
 126         bx      lr
 127
 128 END (strrchr)
 129
 130 weak_alias (strrchr, rindex)
 131 libc_hidden_builtin_def (strrchr)