ports/sysdeps/aarch64/setjmp.S

   1 /* Copyright (C) 1997-2014 Free Software Foundation, Inc.
   2
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public License as
   7    published by the Free Software Foundation; either version 2.1 of the
   8    License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library.  If not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20 #include <jmpbuf-offsets.h>
  21
  22         /* Keep traditional entry points in with sigsetjmp(). */
  23 ENTRY (setjmp)
  24         mov     x1, #1
  25         b       1f
  26 END (setjmp)
  27
  28 ENTRY (_setjmp)
  29         mov     x1, #0
  30         b       1f
  31 END (_setjmp)
  32 libc_hidden_def (_setjmp)
  33
  34 ENTRY (__sigsetjmp)
  35
  36 1:
  37         stp     x19, x20, [x0, #JB_X19<<3]
  38         stp     x21, x22, [x0, #JB_X21<<3]
  39         stp     x23, x24, [x0, #JB_X23<<3]
  40         stp     x25, x26, [x0, #JB_X25<<3]
  41         stp     x27, x28, [x0, #JB_X27<<3]
  42         stp     x29, x30, [x0, #JB_X29<<3]
  43         stp      d8,  d9, [x0, #JB_D8<<3]
  44         stp     d10, d11, [x0, #JB_D10<<3]
  45         stp     d12, d13, [x0, #JB_D12<<3]
  46         stp     d14, d15, [x0, #JB_D14<<3]
  47         mov     x2,  sp
  48         str     x2,  [x0, #JB_SP<<3]
  49 #if defined NOT_IN_libc && defined IS_IN_rtld
  50         /* In ld.so we never save the signal mask */
  51         mov     w0, #0
  52         RET
  53 #else
  54         b       C_SYMBOL_NAME(__sigjmp_save)
  55 #endif
  56 END (__sigsetjmp)
  57 hidden_def (__sigsetjmp)