sysdeps/s390/multiarch/wcschrnul-vx.S

   1 /* Vector optimized 32/64 bit S/390 version of wcschrnul.
   2    Copyright (C) 2015 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #if defined HAVE_S390_VX_ASM_SUPPORT && IS_IN (libc)
  20
  21 # include "sysdep.h"
  22 # include "asm-syntax.h"
  23
  24         .text
  25
  26 /* wchar_t* wcschrnul (const wchar_t *s, wchar_t c)
  27    Returns pointer to first c or to \0 if c not found.
  28
  29    Register usage:
  30    -r1=tmp
  31    -r2=s and return pointer
  32    -r3=c
  33    -r4=tmp
  34    -r5=current_len
  35    -v16=part of s
  36    -v18=vector with c replicated in every byte
  37 */
  38 ENTRY(__wcschrnul_vx)
  39         .machine "z13"
  40         .machinemode "zarch_nohighgprs"
  41
  42         vlbb    %v16,0(%r2),6   /* Load s until next 4k-byte boundary.  */
  43         lcbb    %r1,0(%r2),6    /* Get bytes to 4k-byte boundary or 16.  */
  44
  45         tmll    %r2,3           /* Test if s is 4-byte aligned?   */
  46         jne     .Lfallback      /* And use common-code variant if not.  */
  47
  48         lghi    %r5,0           /* current_len = 0.  */
  49
  50         vlvgf   %v18,%r3,0      /* Generate vector which elements are all c.  */
  51         vrepf   %v18,%v18,0
  52
  53         vfeezfs %v16,%v16,%v18  /* Find element equal with zero search.  */
  54         vlgvb   %r4,%v16,7      /* Load byte index of character or zero.  */
  55         clrjl   %r4,%r1,.Lfound /* Return if c/zero is in loaded bytes.  */
  56
  57         /* Align s to 16 byte.  */
  58         risbgn  %r4,%r2,60,128+63,0 /* %r3 = bits 60-63 of %r2 'and' 15.  */
  59         lghi    %r5,16          /* current_len = 16.  */
  60         slr     %r5,%r4         /* Compute bytes to 16bytes boundary.  */
  61
  62         /* Find c/zero in 16byte aligned loop */
  63 .Lloop:
  64         vl      %v16,0(%r5,%r2) /* Load s.  */
  65         vfeezfs %v16,%v16,%v18  /* Find element equal with zero search.  */
  66         jno     .Lfound         /* Found c/zero (cc=0|1|2).  */
  67         vl      %v16,16(%r5,%r2)
  68         vfeezfs %v16,%v16,%v18
  69         jno     .Lfound16
  70         vl      %v16,32(%r5,%r2)
  71         vfeezfs %v16,%v16,%v18
  72         jno     .Lfound32
  73         vl      %v16,48(%r5,%r2)
  74         vfeezfs %v16,%v16,%v18
  75         jno     .Lfound48
  76
  77         aghi    %r5,64
  78         j       .Lloop          /* No character and no zero -> loop.  */
  79
  80         /* Found character or zero */
  81 .Lfound48:
  82         aghi    %r5,16
  83 .Lfound32:
  84         aghi    %r5,16
  85 .Lfound16:
  86         aghi    %r5,16
  87 .Lfound:
  88         vlgvb   %r1,%v16,7      /* Load byte index of character.  */
  89         algr    %r5,%r1
  90         la      %r2,0(%r5,%r2)  /* Return pointer to character.  */
  91
  92 .Lend:
  93         br      %r14
  94 .Lfallback:
  95         jg      __wcschrnul_c
  96 END(__wcschrnul_vx)
  97 #endif /* HAVE_S390_VX_ASM_SUPPORT && IS_IN (libc) */